Πώς να διατηρήσετε την κατηγορία κατά την απάντηση ή την προώθηση email στο Outlook;

Κανονικά, όταν απαντάτε ή προωθείτε ένα email που έχω κατηγοριοποιήσει, η κατηγορία θα αφαιρείται αυτόματα στο απεσταλμένο email. Εάν θέλετε να διατηρήσετε την κατηγορία των εξερχόμενων μηνυμάτων ηλεκτρονικού ταχυδρομείου κατά την απάντηση ή την προώθηση, αυτό το άρθρο θα εισαγάγει μια μέθοδο αντιμετώπισης.

Διατηρήστε την κατηγορία κατά την απάντηση ή την προώθηση email με κωδικό VBA

Διατηρήστε την κατηγορία κατά την απάντηση ή την προώθηση email με κωδικό VBA

1. Κρατήστε πατημένο το ALT + F11 για να ανοίξετε το Microsoft Visual Basic για εφαρμογές παράθυρο.

2. Στην Microsoft Visual Basic για εφαρμογές παράθυρο, κάντε διπλό κλικ Αυτό το OutlookSession από το Έργο1 (VbaProject.OTM) παράθυρο για να ανοίξετε τη λειτουργία και, στη συνέχεια, αντιγράψτε και επικολλήστε τον ακόλουθο κώδικα στην κενή μονάδα.

Κωδικός VBA: Διατήρηση κατηγορίας κατά την απάντηση ή την προώθηση email:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

Απάντηση κατηγορίας doc keep 1

3. Στη συνέχεια, αποθηκεύστε και κλείστε αυτό το παράθυρο κώδικα, κλείστε και επανεκκινήστε το Outlook, τώρα, όταν απαντάτε ή προωθείτε ένα μήνυμα ηλεκτρονικού ταχυδρομείου με κατηγορία, η κατηγορία θα διατηρηθεί στο εξερχόμενο μήνυμα στο Απεσταλμένα στοιχεία, δείτε το στιγμιότυπο οθόνης:

Απάντηση κατηγορίας doc keep 2