Πώς μπορώ να λάβω τη διεύθυνση email του αποστολέα από ένα ή περισσότερα email στο Outlook;

Προσπαθήσατε ποτέ να εξαγάγετε τη διεύθυνση email από το πεδίο "Από" ενός ή περισσότερων ληφθέντων email στο Outlook; Αυτό το άρθρο παρέχει έναν κώδικα VBA για να σας βοηθήσει να χειριστείτε αυτήν την εργασία.

Λάβετε τη διεύθυνση email του αποστολέα από ένα ή περισσότερα email στο Outlook

Εκτελέστε τον ακόλουθο κώδικα VBA για να εξαγάγετε τη διεύθυνση email από το πεδίο "Από" ενός ή περισσότερων ληφθέντων email στο Outlook.

1. Ανοίξτε έναν φάκελο email, επιλέξτε ένα μήνυμα email από το οποίο θέλετε να λάβετε τη διεύθυνση email του αποστολέα. Πάτα το άλλος + F11 για να ανοίξετε το Microsoft Visual Basic για εφαρμογές παράθυρο.

Συμβουλές: Για να επιλέξετε πολλά email, κρατήστε πατημένο το Ctrl πληκτρολογήστε και μετά επιλέξτε τα email ένα προς ένα.

2. Στο Microsoft Visual Basic για εφαρμογές παράθυρο, κάντε κλικ στην επιλογή Κύριο θέμα > Μονάδα μέτρησης, στη συνέχεια αντιγράψτε τον ακόλουθο κώδικα VBA στο παράθυρο Module (code).

Κώδικας VBA: εξάγετε τη διεύθυνση email του αποστολέα από ένα ή περισσότερα email στο Outlook

Sub GetSmtpAddressOfSelectionEmail()
  Dim xExplorer As Explorer
  Dim xSelection As Selection
  Dim xItem As Object
  Dim xMail As MailItem
  Dim xAddress As String
  Dim xFldObj As Object
  Dim FilePath As String
  Dim xFSO As Scripting.FileSystemObject
  On Error Resume Next
  Set xExplorer = Application.ActiveExplorer
  Set xSelection = xExplorer.Selection
  For Each xItem In xSelection
    If xItem.Class = olMail Then
      Set xMail = xItem
      xAddress = xAddress & VBA.vbCrLf & "  " & GetSmtpAddress(xMail)
    End If
  Next
  If MsgBox("Sender SMTP Address is: " & xAddress & vbCrLf & vbCrLf & "Do you want to export the address list to a txt file? ", vbYesNo, "Kutools for Outlook") = vbYes Then
    Set xFldObj = CreateObject("Shell.Application").BrowseforFolder(0, "Select a Folder", 0, 16)
    Set xFSO = New Scripting.FileSystemObject
    If xFldObj Is Nothing Then Exit Sub
    FilePath = xFldObj.Items.Item.Path & "\Address.txt"
    Close #1
    Open FilePath For Output As #1
    Print #1, "Sender SMTP Address is: " & xAddress
    Close #1
    Set xFSO = Nothing
    Set xFldObj = Nothing
    MsgBox "Address list has been exported to：" & FilePath, vbOKOnly + vbInformation, "Kutools for Outlook"
  End If
End Sub
Function GetSmtpAddress(Mail As MailItem)
  Dim xNameSpace As Outlook.NameSpace
  Dim xEntryID As String
  Dim xAddressEntry As AddressEntry
  Dim PR_SENT_REPRESENTING_ENTRYID As String
  Dim PR_SMTP_ADDRESS As String
  Dim xExchangeUser As exchangeUser
  On Error Resume Next
  GetSmtpAddress = ""
  Set xNameSpace = Application.Session
  If Mail.sender.Type <> "EX" Then
    GetSmtpAddress = Mail.sender.Address
  Else
    PR_SENT_REPRESENTING_ENTRYID = "http://schemas.microsoft.com/mapi/proptag/0x00410102"
    xEntryID = Mail.PropertyAccessor.BinaryToString(Mail.PropertyAccessor.GetProperty(PR_SENT_REPRESENTING_ENTRYID))
    Set xAddressEntry = xNameSpace.GetAddressEntryFromID(xEntryID)
    If xAddressEntry Is Nothing Then Exit Function
    If xAddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Or xAddressEntry.AddressEntryUserType = olExchangeRemoteUserAddressEntry Then
      Set xExchangeUser = xAddressEntry.GetExchangeUser()
      If xExchangeUser Is Nothing Then Exit Function
      GetSmtpAddress = xExchangeUser.PrimarySmtpAddress
    Else
      PR_SMTP_ADDRESS = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
      GetSmtpAddress = xAddressEntry.PropertyAccessor.GetProperty(PR_SMTP_ADDRESS)
    End If
  End If
End Function

3. κλικ Εργαλεία > αναφορέςκαι μετά ελέγξτε το Χρόνος εκτέλεσης δέσμης ενεργειών Microsoft στο πλαίσιο Αναφορές – Έργο1 κουτί διαλόγου.

4. Πάτα το F5 κλειδί για την εκτέλεση του κώδικα. Μετά ένα Kutools για το Outlook Εμφανίζεται το παράθυρο διαλόγου, όπου παρατίθενται όλες οι διευθύνσεις email του αποστολέα των επιλεγμένων email.

Συμβουλές:

Εάν πρέπει να εξαγάγετε τη λίστα διευθύνσεων σε αρχείο txt, κάντε κλικ στο Ναι κουμπί.

Ή κάντε κλικ στο Οχι για να τερματίσετε τη διαδικασία.

5. Αφού κάνετε κλικ στο Ναι κουμπί, α Αναζήτηση φακέλου εμφανίζεται το παράθυρο διαλόγου. Επιλέξτε ένα φάκελο για να αποθηκεύσετε το αρχείο και κάντε κλικ στο OK κουμπί.

6. Τέλος, α Kutools για το Outlook Θα εμφανιστεί το παράθυρο διαλόγου, που θα σας λέει τη διαδρομή του εξαγόμενου αρχείου. Κάντε κλικ OK να το κλείσει.

7. Μεταβείτε στο φάκελο όπου είναι αποθηκευμένο το εξαγόμενο αρχείο και ανοίξτε το αρχείο .txt με το όνομα Διεύθυνση για να δείτε τις διευθύνσεις email του αποστολέα των επιλεγμένων email.