Πώς να επισημαίνετε αυτόματα μηνύματα ηλεκτρονικού ταχυδρομείου βάσει συγκεκριμένου συνημμένου στο Outlook;

Κατά τη λήψη ορισμένων μηνυμάτων ηλεκτρονικού ταχυδρομείου με συγκεκριμένο σημαντικό συνημμένο, ίσως χρειαστεί να τα επισημάνετε, έτσι ώστε να μπορείτε να τα βρείτε γρήγορα και εύκολα για ροή. Σε αυτό το άρθρο, θα μιλήσω για έναν εύκολο τρόπο αυτόματης επισήμανσης των μηνυμάτων ηλεκτρονικού ταχυδρομείου που επισυνάπτονται με συγκεκριμένα ονόματα.

Αυτόματη επισήμανση μηνυμάτων ηλεκτρονικού ταχυδρομείου βάσει συγκεκριμένου συνημμένου με κωδικό VBA

Αυτόματη επισήμανση μηνυμάτων ηλεκτρονικού ταχυδρομείου βάσει συγκεκριμένου συνημμένου με κωδικό VBA

Για να επισημάνετε αυτόματα τα μηνύματα ηλεκτρονικού ταχυδρομείου που περιέχουν το συγκεκριμένο συνημμένο, εφαρμόστε τον ακόλουθο κώδικα VBA:

1. Εκκινήστε το Outlook και, στη συνέχεια, κρατήστε πατημένο το ALT + F11 για να ανοίξετε το Microsoft Visual Basic για εφαρμογές παράθυρο.

2. Στην Microsoft Visual Basic για εφαρμογές παράθυρο, κάντε διπλό κλικ Αυτό το OutlookSession από το Έργο1 (VbaProject.OTM) παράθυρο για να ανοίξετε μια νέα λειτουργία και, στη συνέχεια, αντιγράψτε και επικολλήστε τον ακόλουθο κώδικα στην κενή μονάδα.

Κωδικός VBA: Αυτόματη επισήμανση των μηνυμάτων ηλεκτρονικού ταχυδρομείου βάσει συγκεκριμένου συνημμένου:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"  'Add the file extension as you need
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then 'Change the text of the attachment name
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

Note: Στον παραπάνω κώδικα, μπορείτε να αλλάξετε την επέκταση αρχείου και το όνομα του αρχείου συνημμένου ανάλογα με τις ανάγκες σας.

3. Στη συνέχεια, αποθηκεύστε τον κώδικα και επανεκκινήστε το Outlook για να τεθεί σε ισχύ ο κώδικας, τώρα, όταν λαμβάνετε τα μηνύματα ηλεκτρονικού ταχυδρομείου στα οποία τα ονόματα των συνημμένων περιέχουν το καθορισμένο κείμενο, το Outlook θα επισημάνει αυτόματα αυτό το μήνυμα ηλεκτρονικού ταχυδρομείου για παρακολούθηση, δείτε το στιγμιότυπο οθόνης: