Excel CHOOSE λειτουργία

Περιγραφή

Σύνταξη και Επιχειρήματα

Χρήση και παραδείγματα

• Ex1 - Βασική χρήση: χρήση CHOOSE να λειτουργεί μόνο για να επιλέξει τιμή από το όρισμα λίστας
• Ex2 - Επιστροφή διαφορετικών αποτελεσμάτων βάσει πολλαπλών συνθηκών
• Ex3 - Επιστροφή διαφορετικών υπολογισμένων αποτελεσμάτων με βάση τις συνθήκες
• Ex4 - Επιλέξτε τυχαία από τη λίστα
• Ex5 - Συνδυάστε CHOOSE και VLOOKUP λειτουργεί για να επιστρέψει την τιμή στην αριστερή στήλη
• Ex6 - Επιστροφή καθημερινή ή μήνα με βάση τη δεδομένη ημερομηνία
• Ex7 - Επιστροφή στην επόμενη ημέρα εργασίας / σαββατοκύριακου με βάση σήμερα

---

Περιγραφή

Η CHOOSE Η συνάρτηση επιστρέφει μια τιμή από τη λίστα του ορίσματος τιμής βάσει του δεδομένου αριθμού ευρετηρίου. Για παράδειγμα, CHOOSE(3,”Apple”,”Peach”,”Orange”) επιστρέφει πορτοκαλί, ο αριθμός ευρετηρίου είναι 3 και το πορτοκαλί είναι η τρίτη τιμή μετά τον αριθμό ευρετηρίου στη συνάρτηση.

σύνταξη και Επιχειρήματα

Σύνταξη τύπου

CHOOSE(index_num, value1, [value2], …)

Επιχειρήματα

Index_num: Απαιτείται. Μια αριθμητική τιμή από 1-254 έως έμμεση ποια τιμή ορίσματος θα επιλεγεί. εάν το index_num είναι εκτός κλίμακας μεταξύ 1-254, CHOOSE επιστρέφει το #VALUE! τιμή σφάλματος. Εάν το index_num είναι μια δεκαδική τιμή, θα στρογγυλοποιηθεί προς τα κάτω σε έναν ακέραιο αριθμό πριν χρησιμοποιηθεί ο τύπος. Value1: Απαιτείται. Η πρώτη τιμή στον τύπο που μπορεί να επιλεγεί. Value2: Προαιρετικός. Η δεύτερη και έως και 254η τιμή από την οποία θα επιλέξετε.

Value1, value2… Μπορεί να είναι αριθμοί, κείμενα, τύποι, αναφορές κελιού ή καθορισμένο όνομα.

επιστροφή Αξία

Η CHOOSE Η συνάρτηση επιστρέφει μια τιμή από μια λίστα με βάση τη δεδομένη θέση.

Χρήση και παραδείγματα

Σε αυτό το μέρος, παραθέτω μερικά απλά αλλά αντιπροσωπευτικά παραδείγματα για να εξηγήσω τη χρήση του CHOOSE λειτουργία.

Ex1 - Βασική χρήση: χρήση CHOOSE να λειτουργεί μόνο για να επιλέξει τιμή από το όρισμα λίστας

Φόρμουλα 1:

=CHOOSE(3,"a","b","c","d")

Return: c, που είναι το τρίτο όρισμα μετά το index_num του 3 στο CHOOSE λειτουργία.

Σημείωση: χρησιμοποιώντας διπλά εισαγωγικά που περιβάλλουν την τιμή εάν είναι κείμενο.

Φόρμουλα 2:

=CHOOSE(2,A1,A2,A3,A4)

Επιστροφή: Kate, η τιμή του A2. Δεδομένου ότι το index_num είναι 2 και το A2 είναι η δεύτερη τιμή στο CHOOSE λειτουργία.

Φόρμουλα 3:

=CHOOSE(4,8,9,7,6)

Return: 6, το όρισμα της 4ης λίστας στη συνάρτηση.

---

Ex2 - Επιστροφή διαφορετικών αποτελεσμάτων βάσει πολλαπλών συνθηκών

Ας υποθέσουμε ότι έχετε μια λίστα αποκλίσεων για κάθε προϊόν που έπρεπε να επισημανθεί με βάση τις συνθήκες όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης.

Συνήθως, μπορείτε να χρησιμοποιήσετε τη λειτουργία IF για να χειριστείτε, αλλά εδώ σας παρουσιάζω πώς να χρησιμοποιήσετε το CHOOSE Λειτουργία για την εύκολη επίλυση αυτού του προβλήματος

Φόρμουλα:

=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")

Εξηγώ:

(B7>0)+(B7>1)+(B7>5): το index_num, B7 είναι 2, το οποίο είναι μεγαλύτερο από 0 και 1 αλλά μικρότερο από 5, οπότε έχουμε το ενδιάμεσο αποτέλεσμα:

=CHOOSE(True+Ture+False,"Top","Middle","Bottom")

Όπως γνωρίζουμε, True = 1, False = 0, έτσι ο τύπος μπορεί να θεωρηθεί ως:

=CHOOSE(1+1+0,"Top","Middle","Bottom")

τότε

=CHOOSE(2,"Top","Middle","Bottom")

Αποτέλεσμα: Μέση

---

Ex3 - Επιστροφή διαφορετικών υπολογισμένων αποτελεσμάτων με βάση τις συνθήκες

Ας υποθέσουμε ότι πρέπει να υπολογίσετε τις εκπτώσεις για κάθε προϊόν με βάση το ποσό και την τιμή, όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης:

Φόρμουλα:

=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

Εξηγώ:

(B8>0)+(B8>100)+(B8>200)+(B8>300): index_number, B8 είναι 102, το οποίο είναι μεγαλύτερο από 100 αλλά λιγότερο από 201, οπότε σε αυτό το μέρος, επιστρέφει το αποτέλεσμα που εμφανίζεται ως:

=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

τότε

=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: οι τιμές από τις οποίες θα επιλέξουμε, η έκπτωση ισούται με την τιμή * ποσό * ποσοστό έκπτωσης, αφού εδώ το index_num είναι 2, επιλέγει B8 * C8 * 0.2

Επιστροφές: 102 * 2 * 0.2 = 40.8

---

Ex4 - Επιλέξτε τυχαία από τη λίστα

Στο Excel, μερικές φορές, ίσως χρειαστεί να επιλέξετε τυχαία μια τιμή από μια δεδομένη λίστα, το CHOOSE η λειτουργία μπορεί να λύσει αυτήν την εργασία.

Επιλέξτε τυχαία μία τιμή από μια λίστα:

Φόρμουλα:

=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)

Εξηγώ:

RANDBETWEEN(1,5): index_num, λάβετε τυχαία αριθμό από 1 έως 5

$D$2,$D$3,$D$4,$D$5,$D$6: τη λίστα τιμών από τις οποίες μπορείτε να επιλέξετε

---

Ex5 - Συνδυάστε CHOOSE και VLOOKUP λειτουργεί για να επιστρέψει την τιμή στην αριστερή στήλη

Γενικά, χρησιμοποιούμε τη συνάρτηση VLOOKUP =VLOOKUP (value, table, col_index, [range_lookup]) για να επιστρέψετε μια τιμή με βάση μια δεδομένη τιμή από ένα εύρος πίνακα. Αλλά με το VLOOKUP συνάρτηση, θα επιστρέψει μια τιμή σφάλματος ενώ η στήλη επιστροφής βρίσκεται στα αριστερά της στήλης αναζήτησης όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης:

Σε αυτήν την περίπτωση, μπορείτε να συνδυάσετε το CHOOSE Λειτουργία με λειτουργία VLOOKUP για την επίλυση του προβλήματος.

Φόρμουλα:

=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)

Εξηγώ:

CHOOSE({1,2},B1:B7,A1:A7): ως όρισμα table_range στη συνάρτηση VLOOKUP. {1,2} σημαίνει την εμφάνιση 1 ή 2 ως όρισμα index_num με βάση το όρισμα col_num στη συνάρτηση VLOOKUP. Εδώ, η συνάρτηση col_num στο VLOOKUP είναι 2, έτσι το CHOOSE εμφάνιση λειτουργίας ως CHOOSE(2, B1:B7,A1:A7), σημαίνει να επιλέξετε τιμή από A1: A7.

---

Ex6 - Επιστροφή καθημερινή ή μήνα με βάση τη δεδομένη ημερομηνία

Με την CHOOSE συνάρτηση, μπορείτε επίσης να επιστρέψετε τη σχετική εργάσιμη ημέρα και μήνα με βάση μια δεδομένη ημερομηνία

Τύπος 1: επιστροφή την ημέρα της εβδομάδας με ημερομηνία

=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")

Εξηγώ:

WEEKDAY(): το όρισμα index_num, για να λάβετε τον αριθμό της εργάσιμης ημέρας της δεδομένης ημερομηνίας, για παράδειγμα, η WEEKDAY (A5) επιστρέφει 6, τότε το όρισμα index_num είναι 6.

"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": ορίσματα λίστας τιμών, ξεκινήστε με "Κυριακή" επειδή ο αριθμός "1" της εβδομάδας δείχνει "Κυριακή".

Τύπος 2: επιστροφή μήνα κατά ημερομηνία

=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Εξηγώ:

MONTH(): index_num όρισμα, το οποίο λαμβάνει τον αριθμό μήνα από τη δεδομένη ημερομηνία, για παράδειγμα, MONTH (A5) επιστρέφει 3.

---

Ex7 - Επιστροφή στην επόμενη ημέρα εργασίας / σαββατοκύριακου με βάση σήμερα

Στην καθημερινή εργασία, μπορεί να θέλετε να υπολογίσετε την επόμενη εργάσιμη ημέρα ή το Σαββατοκύριακο με βάση σήμερα. Εδώ CHOOSE Η λειτουργία μπορεί επίσης να σας κάνει μια χάρη.

Για παράδειγμα, σήμερα είναι 12/20/2018, Πέμπτη, τώρα πρέπει να λάβετε την επόμενη εργάσιμη ημέρα και σαββατοκύριακο.

Τύπος 1: πάρτε την ημερομηνία του σήμερα

=TODAY()

Αποτέλεσμα: 12/20/2018

Τύπος 2: λάβετε τον αριθμό της ημέρας της εβδομάδας σήμερα

=WEEKDAY(TODAY())

Αποτέλεσμα: 5 (ενώ σήμερα είναι 12/20/2018)

Η λίστα αριθμών της εβδομάδας, όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης:

Τύπος 3: πάρτε την επόμενη εργάσιμη ημέρα

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Εξηγώ:

Today(): επιστρέψτε την τρέχουσα ημερομηνία

WEEKDAY(TODAY()): index_num όρισμα στο CHOOSE συνάρτηση, λάβετε τον αριθμό της ημέρας της εβδομάδας σήμερα, για παράδειγμα, η Κυριακή είναι 1, η Δευτέρα είναι 2…

1,1,1,1,1,3,2: όρισμα τιμής στη λίστα CHOOSE λειτουργία. Για παράδειγμα, εάν η ημέρα της εβδομάδας (σήμερα ()) επιστρέψει 1 (Κυριακή), επιλέγει 1 από τη λίστα τιμών, τότε ολόκληρος ο τύπος αλλάζει σε = Σήμερα () + 1, που σημαίνει να προσθέσετε 1 ημέρα για επιστροφή την επόμενη Δευτέρα. Εάν η ημέρα της εβδομάδας (σήμερα ()) επιστρέψει 6 (Παρασκευή), επιλέγει 3 από τη λίστα τιμών, επειδή η Παρασκευή απέχει 3 ημέρες από την επόμενη Δευτέρα.

Αποτέλεσμα (ενώ σήμερα είναι 12/20/2018):

=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)

= 12/20/2018 + 1

= 12/21/2018

Τύπος 4: πάρτε την επόμενη μέρα του Σαββατοκύριακου

=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)

Εξηγώ:

6,5,4,3,2,1,1: όρισμα τιμής στη λίστα CHOOSE λειτουργία. Για παράδειγμα, εάν η ημέρα της εβδομάδας (σήμερα ()) επιστρέψει 1 (Κυριακή), επιλέγει 6 από τη λίστα τιμών, τότε ολόκληρος ο τύπος αλλάζει σε = Σήμερα () + 6, που σημαίνει να προσθέσετε 6 ημέρες και να επιστρέψετε το επόμενο Σάββατο.

Αποτέλεσμα:

=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)

= 12/20/2018 + 2

= 12/22/2018

---

Δείγμα αρχείου