Η Συνάρτηση Excel VLOOKUP είναι ένα ισχυρό εργαλείο που σας βοηθά να αναζητήσετε μια καθορισμένη τιμή αντιστοιχίζοντας στην πρώτη στήλη ενός πίνακα ή μιας περιοχής κατακόρυφα και στη συνέχεια να επιστρέψετε μια αντίστοιχη τιμή από μια άλλη στήλη στην ίδια σειρά. Αν και το VLOOKUP είναι απίστευτα χρήσιμο, μερικές φορές μπορεί να είναι δύσκολο να το κατανοήσουν οι αρχάριοι. Αυτό το σεμινάριο στοχεύει να σας βοηθήσει να κατακτήσετε το VLOOKUP παρέχοντας βήμα προς βήμα επεξήγηση των επιχειρημάτων, χρήσιμα παραδείγματα και λύσεις σε κοινά λάθη μπορεί να συναντήσετε όταν χρησιμοποιείτε τη συνάρτηση VLOOKUP.

• Βήμα προς βήμα επεξήγηση των επιχειρημάτων
• Σύνταξη και επιχειρήματα
• Παραδείγματα VLOOKUP
  Ακριβής αντιστοίχιση έναντι κατά προσέγγιση αντιστοίχισης   |   Vlookup με πολλαπλές προϋποθέσεις
• VLOOKUP Συνήθη σφάλματα και λύσεις
  #Δ/Υ σφάλμα   |   #VALUE σφάλμα   |   Σφάλμα #REF   |   Λανθασμένη τιμή

Παραδείγματα VLOOKUP .xlsx Σφάλματα VLOOKUP .xlsx

Σχετικά Βίντεο

Βήμα προς βήμα επεξήγηση των επιχειρημάτων

Όπως φαίνεται στο παραπάνω στιγμιότυπο οθόνης, η συνάρτηση VLOOKUP χρησιμοποιείται για την εύρεση ενός email με βάση έναν δεδομένο αριθμό ταυτότητας. Θα δώσω τώρα μια λεπτομερή εξήγηση του τρόπου χρήσης του VLOOKUP σε αυτό το παράδειγμα, αναλύοντας κάθε όρισμα βήμα προς βήμα.

Βήμα 1: Ξεκινήστε τη λειτουργία VLOOKUP

Επιλέξτε ένα κελί (H6 σε αυτήν την περίπτωση) για να εξάγετε το αποτέλεσμα και, στη συνέχεια, ξεκινήστε τη συνάρτηση VLOOKUP πληκτρολογώντας το ακόλουθο περιεχόμενο στο Φόρμουλα μπαρ.

=VLOOKUP(

Βήμα 2: Καθορίστε την τιμή αναζήτησης

Πρώτα, καθορίστε την τιμή αναζήτησης (που είναι αυτό που αναζητάτε) στη συνάρτηση VLOOKUP. Εδώ, αναφέρομαι στο κελί G6 που περιέχει έναν συγκεκριμένο αριθμό ID 1005.

=VLOOKUP(G6

Βήμα 3: Καθορίστε τον πίνακα πίνακα

Στη συνέχεια, καθορίστε μια περιοχή κελιών που περιέχουν τόσο την τιμή που αναζητάτε όσο και την τιμή που θέλετε να επιστρέψετε. Σε αυτήν την περίπτωση, επιλέγω την περιοχή B6:E12. Ο τύπος εμφανίζεται τώρα ως εξής:

=VLOOKUP(G6,B6:E12

=VLOOKUP(G6,$B$6:$E$12

Βήμα 4: Καθορίστε τη στήλη από την οποία θέλετε να επιστρέψετε μια τιμή

Στη συνέχεια, καθορίστε τη στήλη από την οποία θέλετε να επιστρέψετε μια τιμή.

Σε αυτό το παράδειγμα, καθώς πρέπει να επιστρέψω το email με βάση έναν αριθμό αναγνωριστικού, εδώ εισάγω έναν αριθμό 4 για να πω στο VLOOKUP να επιστρέψει μια τιμή από την τέταρτη στήλη του εύρους δεδομένων.

=VLOOKUP(G6,B6:E12,4

Βήμα 5: Βρείτε μια κατά προσέγγιση ή μια ακριβή αντιστοίχιση

Τέλος, καθορίστε αν ψάχνετε για μια κατά προσέγγιση αντιστοίχιση ή μια ακριβή αντιστοίχιση.

• Για να βρείτε ένα ακριβής αντιστοίχιση, πρέπει να χρησιμοποιήσετε ΨΕΥΔΗΣ ως τελευταίο επιχείρημα.
• Για να βρείτε ένα κατά προσέγγιση ταίριασμα, Χρησιμοποιήστε ΑΛΗΘΙΝΗ ως τελευταίο επιχείρημα, ή απλώς αφήστε το κενό.

Σε αυτό το παράδειγμα, χρησιμοποιώ FALSE για ακριβή αντιστοίχιση. Ο τύπος τώρα μοιάζει με αυτό:

=VLOOKUP(G6,B6:E12,4,FALSE

Πατήστε το πλήκτρο Enter για να λάβετε το αποτέλεσμα

Εξηγώντας κάθε όρισμα ένα προς ένα στο παραπάνω παράδειγμα, η σύνταξη και τα ορίσματα της συνάρτησης VLOOKUP είναι πλέον πολύ πιο εύκολα κατανοητά.

Σύνταξη και επιχειρήματα

=VLOOKUP (lookup_value, table_array, col_index, [range_lookup])

• Αναζήτηση_τιμής (απαιτείται): Η τιμή (πραγματική τιμή ή αναφορά κελιού) που αναζητάτε. Θυμηθείτε ότι αυτή η τιμή πρέπει να βρίσκεται στην πρώτη στήλη του πίνακα_πίνακα.
• Πίνακας_συστοιχίας (απαιτείται): Μια περιοχή κελιών περιέχει τόσο τη στήλη της τιμής αναζήτησης όσο και τη στήλη της τιμής επιστροφής.
• Col_index (απαιτείται): Ένας ακέραιος αριθμός αντιπροσωπεύει τον αριθμό της στήλης που περιέχει την τιμή επιστροφής. Ξεκινά με τον αριθμό 1 για την αριστερή στήλη του πίνακα_πίνακα.
• Εύρος_αναζήτησης (προαιρετικό): Μια λογική τιμή που καθορίζει εάν θέλετε το VLOOKUP να βρει μια κατά προσέγγιση αντιστοίχιση ή μια ακριβή αντιστοίχιση.
  • Κατά προσέγγιση αντιστοίχιση - Ορίστε αυτό το όρισμα σε ΑΛΗΘΙΝΗ, 1 ή αφήστε το κενό.
    σημαντικό: Για να βρείτε μια κατά προσέγγιση αντιστοίχιση, οι τιμές στην πρώτη στήλη του πίνακα_πίνακα πρέπει να ταξινομηθούν σε αύξουσα σειρά σε περίπτωση που το VLOOKUP επιστρέψει λάθος αποτέλεσμα.
  • Ακριβής αντιστοίχιση - Ορίστε αυτό το όρισμα σε ΨΕΥΔΗΣ or 0.

Παραδείγματα

Αυτή η ενότητα παρουσιάζει μερικά παραδείγματα που θα σας βοηθήσουν να κατανοήσετε περισσότερο τη λειτουργία VLOOKUP.

Παράδειγμα 1: Ακριβής αντιστοίχιση έναντι κατά προσέγγιση αντιστοίχισης στο VLOOKUP

Εάν έχετε σύγχυση σχετικά με την ακριβή αντιστοίχιση και την κατά προσέγγιση αντιστοίχιση όταν χρησιμοποιείτε το VLOOKUP, αυτή η ενότητα μπορεί να σας βοηθήσει να ξεκαθαρίσετε αυτήν τη σύγχυση.

Ακριβής αντιστοίχιση στο VLOOKUP

Σε αυτό το παράδειγμα, θα βρω τα αντίστοιχα ονόματα με βάση τις βαθμολογίες που αναφέρονται στην περιοχή E6:E8, οπότε εισάγω τον ακόλουθο τύπο στο κελί F6 και σύρω τη λαβή Αυτόματης Συμπλήρωσης προς τα κάτω στο F8. Σε αυτόν τον τύπο, το τελευταίο όρισμα ορίζεται ως ΨΕΥΔΗΣ για να εκτελέσετε μια ακριβή αναζήτηση αντιστοίχισης.

=VLOOKUP(E6,$B$6:$C$12,2,FALSE)

Ωστόσο, καθώς η βαθμολογία 98 δεν υπάρχει στην πρώτη στήλη του εύρους δεδομένων, το VLOOKUP επιστρέφει #N/A αποτέλεσμα σφάλματος.

Κατά προσέγγιση αντιστοιχία στο VLOOKUP

Εξακολουθείτε να χρησιμοποιείτε το παραπάνω παράδειγμα, εάν αλλάξετε το τελευταίο όρισμα σε ΑΛΗΘΙΝΗ, το VLOOKUP θα εκτελέσει μια κατά προσέγγιση αναζήτηση αντιστοίχισης. Εάν δεν βρεθεί αντιστοίχιση, θα βρει την επόμενη μεγαλύτερη τιμή που είναι μικρότερη από την τιμή αναζήτησης και θα επιστρέψει το αντίστοιχο αποτέλεσμα.

=VLOOKUP(E6,$B$6:$C$12,2,TRUE)

Δεδομένου ότι η βαθμολογία 98 δεν υπάρχει, το VLOOKUP βρίσκει την επόμενη μεγαλύτερη τιμή που είναι μικρότερη από 98, που είναι 95, και επιστρέφει το όνομα της βαθμολογίας 95 ως το πλησιέστερο αποτέλεσμα.

Παράδειγμα 2: Χρησιμοποιήστε το VLOOKUP με πολλά κριτήρια

Αυτή η ενότητα δείχνει πώς να χρησιμοποιήσετε το VLOOKUP με πολλαπλές συνθήκες στο Excel. Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, εάν προσπαθείτε να εντοπίσετε έναν μισθό με βάση ένα παρεχόμενο όνομα (στο κελί H5) και το τμήμα (στο κελί H6), ακολουθήστε τα παρακάτω βήματα για να το ολοκληρώσετε.

Βήμα 1: Προσθέστε μια βοηθητική στήλη για να συνδέσετε τις τιμές από τις στήλες αναζήτησης

Σε αυτήν την περίπτωση, πρέπει να δημιουργήσουμε μια βοηθητική στήλη για να συνδέσουμε τις τιμές από το Όνομα στήλη και το Τμήμα στήλη.

1. Προσθέστε μια βοηθητική στήλη στα αριστερά του εύρους δεδομένων σας και δώστε μια κεφαλίδα σε αυτήν τη στήλη. Δείτε στιγμιότυπο οθόνης:
   
   
2. Σε αυτήν τη βοηθητική στήλη, επιλέξτε το πρώτο κελί κάτω από την κεφαλίδα, εισαγάγετε τον ακόλουθο τύπο στο Γραμμή τύπων, και πατήστε εισάγετε.
   

   =C6&" "&D6

   
   Notes: Σε αυτόν τον τύπο, χρησιμοποιούμε ένα συμπλεκτικό σύμβολο (&) για να ενώσουμε το κείμενο σε δύο στήλες για να δημιουργήσουμε ένα ενιαίο κομμάτι κειμένου.

   • C6 είναι το πρώτο όνομα του Όνομα στήλη για ένταξη, D6 είναι το πρώτο τμήμα του Τμήμα στήλη για ένταξη.
   • Οι τιμές αυτών των δύο κελιών συνδέονται με ένα διάστημα μεταξύ τους.
3. Επιλέξτε αυτό το κελί αποτελέσματος και, στη συνέχεια, σύρετε το Λαβή αυτόματης συμπλήρωσης κάτω για να εφαρμόσετε αυτόν τον τύπο σε άλλα κελιά της ίδιας στήλης.
   
   

Βήμα 2: Εφαρμόστε τη συνάρτηση VLOOKUP με τα δεδομένα που δίνονται

Επιλέξτε ένα κελί όπου θέλετε να εξάγετε το αποτέλεσμα (εδώ επιλέγω I7), εισαγάγετε τον ακόλουθο τύπο στο Γραμμή τύπων, και στη συνέχεια πατήστε εισάγετε.

=VLOOKUP(I5& " "&I6,B6:F12,5,FALSE)

Αποτέλεσμα

Συνήθη σφάλματα και λύσεις VLOOKUP

Αυτή η ενότητα παραθέτει τα κοινά σφάλματα που μπορεί να συναντήσετε όταν χρησιμοποιείτε το VLOOKUP και παρέχει τις λύσεις για τη διόρθωσή τους.

#Δ/Υ επιστράφηκε σφάλμα

Το πιο συνηθισμένο σφάλμα με το VLOOKUP είναι το σφάλμα #N/A, που σημαίνει ότι το Excel δεν μπορούσε να βρει την τιμή που αναζητούσατε. Ακολουθούν ορισμένοι λόγοι για τους οποίους το VLOOKUP μπορεί να επιστρέψει σφάλμα #Δ/Υ.

Λόγος 1: Η τιμή αναζήτησης δεν βρίσκεται στην πρώτη στήλη του πίνακα_πίνακας

Ένας από τους περιορισμούς του Excel VLOOKUP είναι ότι σας επιτρέπει να κοιτάτε μόνο από αριστερά προς τα δεξιά. Επομένως, οι τιμές αναζήτησης πρέπει να βρίσκονται στην πρώτη στήλη του πίνακα_πίνακα.

Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, θέλω να επιστρέψω ένα όνομα με βάση τον συγκεκριμένο τίτλο εργασίας. Εδώ η τιμή αναζήτησης (διευθυντής πωλήσεων) βρίσκεται στη δεύτερη στήλη του πίνακα_πίνακα και η τιμή επιστροφής βρίσκεται στα αριστερά της στήλης αναζήτησης, επομένως το VLOOKUP επιστρέφει σφάλμα #N/A.

Λύσεις

Μπορείτε να εφαρμόσετε οποιαδήποτε από τις παρακάτω λύσεις για να διορθώσετε αυτό το σφάλμα.

• Αναδιάταξη των στηλών
  
  Μπορείτε να αναδιατάξετε τις στήλες για να τοποθετήσετε τη στήλη αναζήτησης στην πρώτη στήλη του πίνακα_πίνακας.
• Χρησιμοποιήστε τις συναρτήσεις INDEX και MATCH μαζί
  
  Εδώ χρησιμοποιούμε τις συναρτήσεις INDEX και MATCH μαζί ως εναλλακτική λύση στο VLOOKUP για να λύσουμε αυτό το πρόβλημα.

  =INDEX(B6:B12,MATCH(F6,C6:C12,0))

  
• Χρησιμοποιήστε τη συνάρτηση XLOOKUP (διαθέσιμη σε Excel 365, Excel 2021 και νεότερες εκδόσεις)
  

  =XLOOKUP(F6,C6:C12,B6:B12)

Λόγος 2: Η τιμή αναζήτησης δεν βρέθηκε στη στήλη αναζήτησης (ακριβής αντιστοίχιση)

Ένας από τους πιο συνηθισμένους λόγους για τους οποίους το VLOOKUP επιστρέφει σφάλμα #N/A είναι επειδή δεν βρέθηκε η τιμή που αναζητάτε.

Όπως φαίνεται στο παρακάτω παράδειγμα, θα βρούμε το όνομα με βάση τη δεδομένη βαθμολογία 98 στο Ε6. Ωστόσο, αυτή η βαθμολογία δεν υπάρχει στην πρώτη στήλη του εύρους δεδομένων, επομένως το VLOOKUP επιστρέφει #N/A αποτέλεσμα σφάλματος.

Λύσεις

Για να διορθώσετε αυτό το σφάλμα, μπορείτε να δοκιμάσετε μία από τις παρακάτω λύσεις.

• Εάν θέλετε το VLOOKUP να αναζητά την επόμενη μεγαλύτερη τιμή που είναι μικρότερη από την τιμή αναζήτησης, αλλάξτε το τελευταίο όρισμα ΨΕΥΔΗΣ (ακριβής αντιστοίχιση) σε ΑΛΗΘΙΝΗ (κατά προσέγγιση αντιστοιχία). Για περισσότερες πληροφορίες, δείτε Παράδειγμα 1: Ακριβής αντιστοίχιση έναντι κατά προσέγγιση αντιστοίχισης χρησιμοποιώντας το VLOOKUP.
• Για να αποφύγετε την αλλαγή του τελευταίου ορίσματος και να λάβετε μια υπενθύμιση σε περίπτωση που δεν βρεθεί η τιμή αναζήτησης, μπορείτε να συμπεριλάβετε τη συνάρτηση VLOOKUP στη συνάρτηση IFERROR:
  

  =IFERROR(VLOOKUP(E8,$B$6:$C$12,2,FALSE),"Not found")

Λόγος 3: Η τιμή αναζήτησης είναι μικρότερη από τη μικρότερη τιμή στη στήλη αναζήτησης (κατά προσέγγιση αντιστοίχιση)

Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, εκτελείτε μια κατά προσέγγιση αναζήτηση αντιστοίχισης. Η τιμή που αναζητάτε (ο αριθμός αναγνωριστικού 1001 σε αυτήν την περίπτωση) είναι μικρότερη από τη μικρότερη τιμή 1002 στη στήλη αναζήτησης, επομένως, το VLOOKUP επιστρέφει σφάλμα #N/A.

Λύσεις

Εδώ είναι δύο λύσεις για εσάς.

• Βεβαιωθείτε ότι η τιμή αναζήτησης είναι μεγαλύτερη ή ίση με τη μικρότερη τιμή στη στήλη αναζήτησης.
• Εάν θέλετε το Excel να σας υπενθυμίζει ότι η τιμή αναζήτησης δεν βρέθηκε, απλώς τοποθετήστε τη συνάρτηση VLOOKUP στη συνάρτηση IFERROR ως εξής:
  

  =IFERROR(VLOOKUP(G6,B6:E12,4,TRUE),"Not found")

Λόγος 4: Οι αριθμοί μορφοποιούνται ως κείμενο

Όπως μπορείτε να δείτε στο παρακάτω στιγμιότυπο οθόνης, το αποτέλεσμα σφάλματος #N/A σε αυτό το παράδειγμα οφείλεται σε αναντιστοιχία τύπου δεδομένων μεταξύ του κελιού αναζήτησης (G6) και της στήλης αναζήτησης (B6:B12) του αρχικού πίνακα. Εδώ η τιμή στο G6 είναι ένας αριθμός και οι τιμές στην περιοχή B6:B12 είναι αριθμοί που έχουν μορφοποιηθεί ως κείμενο.

Λύσεις

Για να λύσετε αυτό το πρόβλημα, πρέπει να μετατρέψετε την τιμή αναζήτησης σε αριθμό. Εδώ είναι δύο μέθοδοι για εσάς.

• Εφαρμόστε τη δυνατότητα Μετατροπή σε αριθμό
  
  Κάντε κλικ στο κελί που θέλετε να μετατρέψετε το κείμενο σε αριθμό, επιλέξτε αυτό το κουμπί  δίπλα στο κελί και μετά επιλέξτε Μετατροπή σε αριθμό.
  
• Εφαρμόστε ένα εύχρηστο εργαλείο για ομαδική μετατροπή μεταξύ κειμένου και αριθμού
  
  Η Μετατροπή μεταξύ κειμένου και αριθμού χαρακτηριστικό του Kutools για Excel σας βοηθά να μετατρέψετε εύκολα μια σειρά κελιών από κείμενο σε αριθμό και αντίστροφα. Αποκτήστε μια δωρεάν δοκιμή 30 ημερών με πλήρεις δυνατότητες τώρα!
  

Λόγος 5: Ο πίνακας_πίνακας δεν είναι σταθερός όταν σύρετε τον τύπο VLOOKUP σε άλλα κελιά

Όπως φαίνεται στο στιγμιότυπο οθόνης παρακάτω, υπάρχουν δύο τιμές αναζήτησης στο E6 και στο E7. Αφού λάβετε το πρώτο αποτέλεσμα στο F6, σύρετε τον τύπο VLOOKUP από το κελί F6 στο F7, επιστρέφεται ένα αποτέλεσμα σφάλματος #N/A. Αυτό συμβαίνει επειδή οι αναφορές κελιών (B6:C12) είναι σχετικές από προεπιλογή και προσαρμόζονται καθώς μετακινείστε προς τα κάτω στις σειρές. Ο πίνακας πίνακα έχει μετακινηθεί προς τα κάτω στο B7:C13, το οποίο δεν περιέχει πλέον τη βαθμολογία αναζήτησης 73.

Λύση

Πρέπει να κλειδώσετε τον πίνακα πίνακα για να τον διατηρήσετε σταθερό προσθέτοντας a $ υπογράψετε πριν από τις γραμμές και τις στήλες στις αναφορές κελιών. Για να μάθετε περισσότερα σχετικά με την απόλυτη αναφορά στο Excel, ρίξτε μια ματιά σε αυτό το σεμινάριο: Απόλυτη αναφορά στο Excel (τρόπος δημιουργίας και χρήσης).

Επιστράφηκε σφάλμα #VALUE

Οι ακόλουθες συνθήκες ενδέχεται να αναγκάσουν το VLOOKUP να επιστρέψει το αποτέλεσμα σφάλματος #VALUE.

Λόγος 1: Η τιμή αναζήτησης υπερβαίνει τους 255 χαρακτήρες

Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, η τιμή αναζήτησης στο κελί H4 υπερβαίνει τους 255 χαρακτήρες, επομένως το VLOOKUP επιστρέφει ένα αποτέλεσμα σφάλματος #VALUE.

Λύσεις

Για να αντιμετωπίσετε αυτόν τον περιορισμό, μπορείτε να εφαρμόσετε μια διαφορετική συνάρτηση αναζήτησης που μπορεί να χειριστεί μεγαλύτερες συμβολοσειρές. Δοκιμάστε έναν από τους παρακάτω τύπους.

• ΕΥΡΕΤΗΣ και ΑΓΩΝΑΣ:
  

  =INDEX(E5:E11, MATCH(TRUE, INDEX(B5:B11=H4, 0), 0))

  
• Λειτουργία XLOOKUP (διαθέσιμο σε Excel 365, Excel 2021 και νεότερες εκδόσεις):
  

  =XLOOKUP(H4,B5:B11,E5:E11)

Λόγος 2: Το όρισμα col_index είναι μικρότερο από 1

Το ευρετήριο στήλης καθορίζει τον αριθμό στήλης στον πίνακα πίνακα που περιέχει την τιμή που θέλετε να επιστρέψετε. Αυτό το όρισμα πρέπει να είναι ένας θετικός αριθμός που αντιστοιχεί σε μια έγκυρη στήλη στον πίνακα πίνακα.

Εάν εισαγάγετε ένα ευρετήριο στήλης που είναι μικρότερο από 1 (δηλαδή, μηδέν ή αρνητικό), το VLOOKUP δεν θα μπορεί να εντοπίσει τη στήλη στον πίνακα πίνακα.

Λύση

Για να διορθώσετε αυτό το ζήτημα, βεβαιωθείτε ότι το όρισμα ευρετηρίου στήλης στον τύπο VLOOKUP είναι ένας θετικός αριθμός που αντιστοιχεί σε μια έγκυρη στήλη στον πίνακα πίνακα.

Το σφάλμα #REF επιστρέφεται

Αυτή η ενότητα παραθέτει έναν λόγο για τον οποίο το VLOOKUP επιστρέφει το σφάλμα #REF και παρέχει λύσεις σε αυτό το πρόβλημα.

Αιτία: Το όρισμα col_index είναι μεγαλύτερο από τον αριθμό των στηλών

Όπως μπορείτε να δείτε στο παρακάτω στιγμιότυπο οθόνης, ο πίνακας έχει μόνο 4 στήλες. Ωστόσο, το ευρετήριο στήλης που καθορίσατε στον τύπο VLOOKUP είναι 5, το οποίο είναι μεγαλύτερο από τον αριθμό των στηλών στον πίνακα πίνακα. Ως αποτέλεσμα, το VLOOKUP δεν θα μπορεί να εντοπίσει τη στήλη και τελικά θα επιστρέψει ένα σφάλμα #REF.

Λύσεις

• Καθορίστε τον σωστό αριθμό στήλης
  Βεβαιωθείτε ότι το όρισμα ευρετηρίου στήλης στον τύπο VLOOKUP είναι ένας αριθμός που αντιστοιχεί σε μια έγκυρη στήλη στον πίνακα πίνακα.
• Λάβετε αυτόματα τον αριθμό της στήλης με βάση την καθορισμένη κεφαλίδα στήλης
  Εάν ο πίνακας περιέχει πολλές στήλες, ενδέχεται να έχετε πρόβλημα να προσδιορίσετε τον σωστό αριθμό ευρετηρίου στήλης. Εδώ, μπορείτε να ενσωματώσετε τη συνάρτηση MATCH στη συνάρτηση VLOOKUP για να βρείτε τη θέση της στήλης με βάση μια συγκεκριμένη κεφαλίδα στήλης.

  =VLOOKUP(G6,B6:E12,MATCH("Email",B5:E5,0),FALSE)

  Note: Στον παραπάνω τύπο, το MATCH("Email",B5:E5, 0) η συνάρτηση χρησιμοποιείται για να πάρει τον αριθμό στήλης του "Ηλεκτρονική Διεύθυνση (Email)στήλη " στο εύρος ημερομηνιών B6:E12. Εδώ το αποτέλεσμα είναι 4, το οποίο χρησιμοποιείται ως col_index στη συνάρτηση VLOOKUP.

Επιστρέφεται λανθασμένη τιμή

Εάν διαπιστώσετε ότι το VLOOKUP δεν επιστρέφει το σωστό αποτέλεσμα, μπορεί να οφείλεται στους ακόλουθους λόγους

Λόγος 1: Η στήλη αναζήτησης δεν ταξινομείται με αύξουσα σειρά

Εάν έχετε ορίσει το τελευταίο όρισμα σε ΑΛΗΘΙΝΗ (Ή το άφησε άδειο) για μια κατά προσέγγιση αντιστοίχιση και η στήλη αναζήτησης δεν είναι ταξινομημένη με αύξουσα σειρά, η τιμή που προκύπτει μπορεί να είναι λανθασμένη.

Λύση

Η ταξινόμηση της στήλης αναζήτησης σε αύξουσα σειρά μπορεί να σας βοηθήσει να λύσετε αυτό το πρόβλημα. Για να το κάνετε αυτό, ακολουθήστε τα παρακάτω βήματα:

1. Επιλέξτε τα κελιά δεδομένων στη στήλη αναζήτησης, μεταβείτε στο ημερομηνία κάντε κλικ στην καρτέλα Ταξινόμηση μικρότερο σε μεγαλύτερο στο Ταξινόμηση & φίλτρο ομάδα.
2. Στο Προειδοποίηση ταξινόμησης πλαίσιο διαλόγου, επιλέξτε το Αναπτύξτε την επιλογή επιλογή και πατήστε OK.

Λόγος 2: Εισάγεται ή αφαιρείται στήλη

Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, η τιμή που ήθελα αρχικά να επιστρέψω βρίσκεται στην τέταρτη στήλη του πίνακα πίνακα, επομένως καθορίζω τον αριθμό col_index ως 4. Καθώς εισάγεται μια νέα στήλη, η στήλη αποτελέσματος γίνεται η πέμπτη στήλη του πίνακα πίνακας, αναγκάζοντας το VLOOKUP να επιστρέψει το αποτέλεσμα από λάθος στήλη.

Λύσεις

Εδώ είναι δύο λύσεις για εσάς.

• Μπορείτε να αλλάξετε με μη αυτόματο τρόπο τον αριθμό ευρετηρίου της στήλης ώστε να ταιριάζει με τη θέση της στήλης επιστροφής. Ο τύπος εδώ πρέπει να αλλάξει σε:

  =VLOOKUP(H6,B6:F12,5,FALSE)

• Εάν θέλετε πάντα να επιστρέφετε το αποτέλεσμα από μια συγκεκριμένη στήλη, όπως η στήλη Email σε αυτό το παράδειγμα. Ο παρακάτω τύπος μπορεί να βοηθήσει στην αυτόματη αντιστοίχιση του ευρετηρίου στήλης με βάση τη δεδομένη κεφαλίδα στήλης, ανεξάρτητα από το εάν οι στήλες έχουν εισαχθεί ή αφαιρεθεί από τον πίνακα πίνακα.

  =VLOOKUP(H6,B6:F12,MATCH("Email",B5:E5,0),FALSE)

Άλλες σημειώσεις λειτουργίας

• Το VLOOKUP αναζητά μόνο τιμή από αριστερά προς τα δεξιά.
  Η τιμή αναζήτησης βρίσκεται στην αριστερή στήλη και η τιμή του αποτελέσματος πρέπει να βρίσκεται σε οποιαδήποτε στήλη στα δεξιά της στήλης αναζήτησης.
• Εάν αφήσετε το τελευταίο όρισμα κενό, το VLOOKUP χρησιμοποιεί κατά προσέγγιση αντιστοίχιση από προεπιλογή.
• Το VLOOKUP εκτελεί αναζήτηση χωρίς διάκριση πεζών-κεφαλαίων.
• Για πολλαπλές αντιστοιχίσεις, το VLOOKUP επιστρέφει μόνο την πρώτη αντιστοίχιση που βρίσκει στον πίνακα πίνακα, με βάση τη σειρά των σειρών στον πίνακα πίνακα.

Σχετικά άρθρα