Μετάβαση στο κύριο περιεχόμενο

Mastering Nested IF statements στο Excel – Ένας βήμα προς βήμα οδηγός

Στο Excel, ενώ η συνάρτηση IF είναι απαραίτητη για βασικές λογικές δοκιμές, πολύπλοκες συνθήκες απαιτούν συχνά ένθετες δηλώσεις IF για βελτιωμένη επεξεργασία δεδομένων. Σε αυτόν τον περιεκτικό οδηγό, θα καλύψουμε λεπτομερώς τα βασικά στοιχεία του ένθετου IF, από τη σύνταξη έως τις πρακτικές εφαρμογές, συμπεριλαμβανομένων των συνδυασμών ένθετων IF με συνθήκες AND/OR. Επιπλέον, θα μοιραστούμε τον τρόπο βελτίωσης της αναγνωσιμότητας των ένθετων λειτουργιών IF, καθώς και μερικές συμβουλές σχετικά με το ένθετο IF, και θα εξερευνήσουμε ισχυρές εναλλακτικές λύσεις όπως το VLOOKUP, το IFS και άλλα, για να κάνουμε τις πολύπλοκες λογικές λειτουργίες πιο εύχρηστες και πιο αποτελεσματικές.

Συνάρτηση Excel IF έναντι ένθετων δηλώσεων IF

Η συνάρτηση IF και οι ένθετες δηλώσεις IF στο Excel εξυπηρετούν παρόμοιους σκοπούς, αλλά διαφέρουν σημαντικά ως προς την πολυπλοκότητα και την εφαρμογή τους.

ΕΑΝ Λειτουργία: Η συνάρτηση IF ελέγχει μια συνθήκη και επιστρέφει μια τιμή εάν η συνθήκη είναι αληθής και μια άλλη τιμή εάν είναι ψευδής.
  • Η Σύνταξη είναι:
    =IF (logical_test, [value_if_true], [value_if_false])
  • Περιορισμός: Μπορεί να χειριστεί μόνο μία συνθήκη τη φορά, καθιστώντας την λιγότερο κατάλληλη για πιο σύνθετα σενάρια λήψης αποφάσεων που απαιτούν την αξιολόγηση πολλαπλών κριτηρίων.
Ένθετες δηλώσεις IF: Οι ένθετες συναρτήσεις IF, δηλαδή μια συνάρτηση IF μέσα σε μια άλλη, σας επιτρέπουν να δοκιμάσετε πολλά κριτήρια και αυξάνουν τον αριθμό των πιθανών αποτελεσμάτων.
  • Η Σύνταξη είναι:
    =IF( condition1, value_if_true1, IF( condition2, value_if_true2, value_if_false2 ))
  • Περίπλοκο: Μπορεί να χειριστεί πολλαπλές συνθήκες, αλλά μπορεί να γίνει πολύπλοκο και δυσανάγνωστο με πάρα πολλά στρώματα ένθεσης.

Χρήση ένθετων IF

Αυτή η ενότητα παρουσιάζει τη βασική χρήση των ένθετων εντολών IF στο Excel, συμπεριλαμβανομένης της σύνταξης, των πρακτικών παραδειγμάτων και του τρόπου χρήσης τους με συνθήκες AND ή OR.

Σύνταξη ένθετων IF

Η κατανόηση της σύνταξης μιας συνάρτησης είναι το θεμέλιο για τη σωστή και αποτελεσματική εφαρμογή της στο Excel. Ας ξεκινήσουμε με τη σύνταξη των ένθετων εντολών if.

Σύνταξη:

=IF(condition1, result1, IF(condition2, result2, IF(condition3, result3, result4)))

Επιχειρήματα:

  • Condition1, Condition2, Condition3: These are the conditions you want to test. Each condition is evaluated in order, starting with Condition1.
  • Result1: This is the value returned if Condition1 is TRUE.
  • Result2: This value is returned if Condition1 is FALSE and Condition2 is TRUE. It's important to note that Result2 is only evaluated if Condition1 is FALSE.
  • Result3: This value is returned if both Condition1 and Condition2 are FALSE, and Condition3 is TRUE. Essentially, for Result3 to be evaluated, the previous conditions (Condition1 and Condition2) must both be FALSE.
  • Result4: This result is returned if all the conditions (Condition1, Condition2, and Condition3) are FALSE.
    In short, this expression can be interpreted as follows:
    Test condition1, if TRUE, return result1, if FALSE,
    test condition2, if TRUE, return result2, if FALSE,
    test condition3, if TRUE, return result3, if FALSE,
    return result4

Θυμηθείτε, σε μια ένθετη δομή IF, κάθε επόμενη συνθήκη αξιολογείται μόνο εάν όλες οι προηγούμενες συνθήκες είναι FALSE. Αυτός ο διαδοχικός έλεγχος είναι κρίσιμος για την κατανόηση του τρόπου λειτουργίας των ένθετων IF.

Πρακτικά παραδείγματα ένθετων IF

Τώρα, ας βουτήξουμε στη χρήση του ένθετου IF με δύο πρακτικά παραδείγματα.

Παράδειγμα 1: Σύστημα βαθμολόγησης

Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, ας υποθέσουμε ότι έχετε μια λίστα με τις βαθμολογίες των μαθητών και θέλετε να εκχωρήσετε βαθμούς με βάση αυτές τις βαθμολογίες. Μπορείτε να χρησιμοποιήσετε το ένθετο IF για να ολοκληρώσετε αυτήν την εργασία.

Note: Τα επίπεδα βαθμολόγησης και τα αντίστοιχα εύρη βαθμολογίας παρατίθενται στο εύρος E2:F6.

Επιλέξτε ένα κενό κελί (C2 σε αυτήν την περίπτωση), εισαγάγετε τον ακόλουθο τύπο και πατήστε εισάγετε για να βγει το αποτέλεσμα. Στη συνέχεια σύρετε το Γεμίστε τη λαβή κάτω για να λάβετε τα υπόλοιπα αποτελέσματα.

=IF(B2>=90,$F$2,IF(B2>=80,$F$3,IF(B2>=70,$F$4,IF(B2>=60,$F$5,$F$6))))
Notes:
  • Μπορείτε να καθορίσετε απευθείας το επίπεδο βαθμού στον τύπο, ώστε ο τύπος να μπορεί να αλλάξει σε:
    =IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))
  • Αυτός ο τύπος χρησιμοποιείται για την εκχώρηση βαθμού (A, B, C, D ή F) με βάση μια βαθμολογία στο κελί A2, χρησιμοποιώντας τυπικά όρια βαθμολόγησης. Είναι μια τυπική περίπτωση χρήσης για ένθετες δηλώσεις IF σε ακαδημαϊκά συστήματα βαθμολόγησης.
  • Επεξήγηση του τύπου:
    1. Α2>=90: Αυτή είναι η πρώτη συνθήκη που ελέγχει ο τύπος. Εάν η βαθμολογία στο κελί A2 είναι μεγαλύτερη ή ίση με 90, ο τύπος επιστρέφει "A".
    2. Α2>=80: Εάν η πρώτη συνθήκη είναι ψευδής (η βαθμολογία είναι μικρότερη από 90), ελέγχει εάν το A2 είναι μεγαλύτερο ή ίσο με 80. Εάν είναι αληθές, επιστρέφει "Β".
    3. Α2>=70: Ομοίως, εάν η βαθμολογία είναι μικρότερη από 80, ελέγχει αν είναι μεγαλύτερη ή ίση με 70. Αν αληθεύει, επιστρέφει "C".
    4. Α2>=60: Εάν η βαθμολογία είναι μικρότερη από 70, ο τύπος ελέγχει εάν είναι μεγαλύτερος ή ίσος με 60. Εάν είναι αληθής, επιστρέφει "D".
    5. "F": Τέλος, εάν δεν πληρούται καμία από τις παραπάνω προϋποθέσεις (που σημαίνει ότι η βαθμολογία είναι μικρότερη από 60), ο τύπος επιστρέφει "F".
Παράδειγμα 2: Υπολογισμός προμήθειας πωλήσεων

Φανταστείτε ένα σενάριο όπου οι αντιπρόσωποι πωλήσεων λαμβάνουν διαφορετικά ποσοστά προμήθειας με βάση τα επιτεύγματά τους στις πωλήσεις. Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, θέλετε να υπολογίσετε την προμήθεια ενός πωλητή με βάση αυτά τα διαφορετικά όρια πωλήσεων και οι ένθετες δηλώσεις IF μπορούν να σας βοηθήσουν σε αυτό.

Note: Τα ποσοστά προμήθειας και τα αντίστοιχα εύρη πωλήσεών τους παρατίθενται στο εύρος E2:F4.
  • 20% για πωλήσεις άνω των 20,000 $
  • 15% για πωλήσεις μεταξύ 10,000 $ και 20,000 $
  • 10% για πωλήσεις κάτω των 10,000 $

Επιλέξτε ένα κενό κελί (C2 σε αυτήν την περίπτωση), εισαγάγετε τον ακόλουθο τύπο και πατήστε εισάγετε για να βγει το αποτέλεσμα. Στη συνέχεια σύρετε το Γεμίστε τη λαβή κάτω για να λάβετε τα υπόλοιπα αποτελέσματα.

=B2*IF(B2>20000,$F$2,IF(B2>=10000,$F$3,$F$4))

Notes:
  • Μπορείτε να καθορίσετε απευθείας το ποσοστό προμήθειας στον τύπο, ώστε ο τύπος να μπορεί να αλλάξει σε:
    =B2*IF(B2>20000, 20%, IF(B2>=10000, 15%, 10%))
  • Ο τύπος που παρέχεται χρησιμοποιείται για τον υπολογισμό της προμήθειας ενός πωλητή με βάση το ποσό των πωλήσεών του, εφαρμόζοντας διαφορετικά ποσοστά προμήθειας για διαφορετικά όρια πωλήσεων.
  • Επεξήγηση του τύπου:
    1. B2: Αυτό αντιπροσωπεύει το ποσό πωλήσεων για τον πωλητή, το οποίο χρησιμοποιείται ως βάση για τον υπολογισμό της προμήθειας.
    2. IF(B2>20000, "20%", ...): Αυτή είναι η πρώτη συνθήκη που ελέγχεται. Ελέγχει εάν το ποσό πωλήσεων στο Β2 είναι μεγαλύτερο από 20,000. Εάν είναι, ο τύπος χρησιμοποιεί ποσοστό προμήθειας 20%.
    3. IF(B2>=10000, "15%", "10%"): Εάν η πρώτη συνθήκη είναι ψευδής (οι πωλήσεις δεν είναι μεγαλύτερες από 20,000), ο τύπος ελέγχει εάν οι πωλήσεις είναι ίσες ή υπερβαίνουν τις 10,000. Εάν είναι αληθές, εφαρμόζεται ποσοστό προμήθειας 15%. Εάν το ποσό των πωλήσεων είναι μικρότερο από 10,000, ο τύπος προκαθορίζει το ποσοστό προμήθειας 10%.

Ένθετο εάν με συνθήκη AND / OR

Σε αυτήν την ενότητα, τροποποιώ το παραπάνω πρώτο παράδειγμα "το σύστημα βαθμολόγησης" για να δείξω πώς να συνδυάσετε το ένθετο IF με τη συνθήκη AND ή OR στο Excel. Στο αναθεωρημένο παράδειγμα βαθμολόγησης, εισήγαγα μια πρόσθετη προϋπόθεση με βάση το "Ποσοστό συμμετοχής".

Χρησιμοποιώντας ένθετο εάν με συνθήκη AND

Εάν ένας μαθητής πληροί τόσο τη βαθμολογία όσο και τα κριτήρια παρακολούθησης, θα λάβει βαθμολογική ενίσχυση. Για παράδειγμα, ένας μαθητής του οποίου η βαθμολογία είναι 60 ή υψηλότερη και του οποίου το ποσοστό παρακολούθησης είναι 95% ή περισσότερο θα αναβαθμιστεί ο βαθμός του κατά ένα επίπεδο, όπως από Α σε Α+, Β σε Β+ και ούτω καθεξής. Ωστόσο, εάν το ποσοστό συμμετοχής είναι κάτω από 95%, η βαθμολόγηση θα ακολουθεί τα αρχικά κριτήρια βάσει βαθμολογίας. Σε τέτοιες περιπτώσεις, πρέπει να χρησιμοποιήσουμε μια ένθετη πρόταση IF με μια συνθήκη AND.

Επιλέξτε ένα κενό κελί (D2 σε αυτήν την περίπτωση), εισαγάγετε τον ακόλουθο τύπο και πατήστε εισάγετε για να βγει το αποτέλεσμα. Στη συνέχεια σύρετε το Γεμίστε τη λαβή κάτω για να λάβετε τα υπόλοιπα αποτελέσματα.

=IF(AND(B2>=60, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

Notes: Ακολουθεί μια εξήγηση για το πώς λειτουργεί αυτός ο τύπος:
  1. ΚΑΙ έλεγχος κατάστασης:
    AND(B2>=60, C2>=95%): Η συνθήκη ΚΑΙ ελέγχει πρώτα αν πληρούνται και οι δύο προϋποθέσεις — η βαθμολογία του μαθητή είναι 60 ή υψηλότερη και το ποσοστό συμμετοχής είναι 95% ή περισσότερο.
  2. Ανάθεση νέας βαθμίδας:
    IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", "D+"))): Εάν και οι δύο συνθήκες στη δήλωση AND ισχύουν, ο τύπος ελέγχει τη βαθμολογία του μαθητή και αυξάνει τον βαθμό του κατά ένα επίπεδο.
    • Β2>=90: Εάν η βαθμολογία είναι 90 και άνω, ο βαθμός είναι «Α+«.Ανάθεση νέας βαθμίδας:
    • Β2>=80: Εάν η βαθμολογία είναι 80 ή μεγαλύτερη (αλλά μικρότερη από 90), ο βαθμός είναι «Β+".
    • Β2>=70: Εάν η βαθμολογία είναι 70 ή μεγαλύτερη (αλλά μικρότερη από 80), ο βαθμός είναι "C+".
    • B2>=60: Εάν η βαθμολογία είναι 60 ή μεγαλύτερη (αλλά μικρότερη από 70), ο βαθμός είναι "D+".
  3. Τακτική Βαθμολογική Ανάθεση:
    IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))) ): Εάν η συνθήκη ΚΑΙ δεν πληρούται (είτε η βαθμολογία είναι κάτω από 80 είτε η συμμετοχή είναι κάτω από 95%), ο τύπος εκχωρεί τυπικούς βαθμούς.
    • Β2>=90: Η βαθμολογία 90 ή παραπάνω παίρνει ένα "A".
    • Β2>=80: Η βαθμολογία 80 ή παραπάνω (αλλά λιγότερο από 90) παίρνει ένα "B".
    • Β2>=70: Η βαθμολογία 70 ή παραπάνω (αλλά λιγότερο από 80) παίρνει "C".
    • Β2>=60: Η βαθμολογία 60 ή παραπάνω (αλλά λιγότερο από 70) παίρνει "D".
    • Οι βαθμολογίες κάτω από 60 παίρνουν ένα "F".
Χρησιμοποιώντας ένθετο εάν με συνθήκη OR

Σε αυτήν την περίπτωση, ο βαθμός ενός μαθητή θα αυξηθεί κατά ένα επίπεδο εάν η βαθμολογία του είναι 95 ή υψηλότερη ή εάν το ποσοστό παρακολούθησης είναι 95% ή περισσότερο. Δείτε πώς μπορούμε να το πετύχουμε χρησιμοποιώντας ένθετες συνθήκες IF και OR.

Επιλέξτε ένα κενό κελί (D2 σε αυτήν την περίπτωση), εισαγάγετε τον ακόλουθο τύπο και πατήστε εισάγετε για να βγει το αποτέλεσμα. Στη συνέχεια σύρετε το Γεμίστε τη λαβή κάτω για να λάβετε τα υπόλοιπα αποτελέσματα.

=IF(OR(B2>=95, C2>=95%),IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+")))),IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))))

Notes: Ακολουθεί μια ανάλυση του τρόπου λειτουργίας του τύπου:
  1. Ή Έλεγχος κατάστασης:
    OR(B2>=95, C2>=95%): Ο τύπος ελέγχει πρώτα αν ισχύει κάποια από τις προϋποθέσεις — η βαθμολογία του μαθητή είναι 95 ή υψηλότερη ή το ποσοστό παρακολούθησης είναι 95% ή υψηλότερο.
  2. Βαθμολογική εργασία με μπόνους:
    IF(B2>=90, "A+", IF(B2>=80, "B+", IF(B2>=70, "C+", IF(B2>=60, "D+", "F+"))) ): Εάν οποιαδήποτε συνθήκη στη δήλωση OR είναι αληθής, ο βαθμός του μαθητή θα αυξηθεί κατά ένα επίπεδο.
    • Β2>=90: Εάν η βαθμολογία είναι 90 και άνω, ο βαθμός είναι "A+".
    • Β2>=80: Εάν η βαθμολογία είναι 80 ή μεγαλύτερη (αλλά μικρότερη από 90), ο βαθμός είναι "Β+".
    • Β2>=70: Εάν η βαθμολογία είναι 70 ή μεγαλύτερη (αλλά μικρότερη από 80), ο βαθμός είναι "C+".
    • Β2>=60: Εάν η βαθμολογία είναι 60 ή μεγαλύτερη (αλλά μικρότερη από 70), ο βαθμός είναι "D+".
    • Διαφορετικά, ο βαθμός είναι "F+".
  3. Τακτική Βαθμολογική Ανάθεση:
    IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F")))): Εάν καμία από τις προϋποθέσεις OR δεν πληρούται (η βαθμολογία είναι κάτω από 95 και η συμμετοχή είναι κάτω από 95%), ο τύπος εκχωρεί τυπικούς βαθμούς.
    • Β2>=90: Η βαθμολογία 90 ή παραπάνω παίρνει ένα "A".
    • Β2>=80: Η βαθμολογία 80 ή παραπάνω (αλλά λιγότερο από 90) παίρνει ένα "B".
    • Β2>=70: Η βαθμολογία 70 ή παραπάνω (αλλά λιγότερο από 80) παίρνει "C".
    • Β2>=60: Η βαθμολογία 60 ή παραπάνω (αλλά λιγότερο από 70) παίρνει "D".
    • Οι βαθμολογίες κάτω από 60 παίρνουν ένα "F".

Συμβουλές και κόλπα για το ένθετο IF

Αυτή η ενότητα καλύπτει τέσσερις χρήσιμες συμβουλές και κόλπα για το ένθετο IF.

Κάνοντας το ένθετο IF εύκολο στην ανάγνωση

Μια τυπική ένθετη δήλωση IF μπορεί να φαίνεται συμπαγής, αλλά μπορεί να είναι δύσκολο να αποκρυπτογραφηθεί.

Στον παρακάτω τύπο, είναι δύσκολο να προσδιορίσετε γρήγορα πού τελειώνει μια συνθήκη και πού αρχίζει μια άλλη, ειδικά καθώς αυξάνεται η πολυπλοκότητα.

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))
Λύση: Προσθήκη σπασίματος γραμμής και εσοχής

Για να κάνετε το ένθετο IF εύκολο στην ανάγνωση, μπορείτε να σπάσετε τον τύπο σε πολλές γραμμές με κάθε ένθετο IF σε μια νέα γραμμή. Στον τύπο, απλώς τοποθετήστε τον κέρσορα πριν από το IF και πατήστε τα πλήκτρα Alt + Enter.

Αφού σπάσουμε τον παραπάνω τύπο, θα εμφανιστεί ως εξής:

=IF(A2>=90, "A",
      IF(A2>=80, "B",
          IF(A2>=70, "C",
              IF(A2>=60, "D", "F")))
)

Αυτή η μορφή καθιστά σαφέστερο πού βρίσκεται κάθε συνθήκη και η αντίστοιχη έξοδος, βελτιώνοντας την αναγνωσιμότητα του τύπου.

Η σειρά των ένθετων συναρτήσεων IF

Η σειρά των λογικών συνθηκών σε έναν ένθετο τύπο IF είναι ζωτικής σημασίας επειδή καθορίζει τον τρόπο με τον οποίο το Excel αξιολογεί αυτές τις συνθήκες και επομένως επηρεάζει το τελικό αποτέλεσμα του τύπου.

Σωστή φόρμουλα

Στο παράδειγμα του συστήματος βαθμολόγησης, χρησιμοποιούμε τον ακόλουθο τύπο για να εκχωρήσουμε βαθμούς με βάση τις βαθμολογίες.

=IF(B2>=90, "A", IF(B2>=80, "B", IF(B2>=70, "C", IF(B2>=60, "D", "F"))))

Το Excel αξιολογεί τις συνθήκες σε έναν ένθετο τύπο IF διαδοχικά, από την πρώτη συνθήκη έως την τελευταία. Αυτός ο τύπος ελέγχει πρώτα το υψηλότερο όριο βαθμολογίας (>=90 για ένα "A") και μετά μετακινείται στα χαμηλότερα όρια. Διασφαλίζει ότι μια βαθμολογία συγκρίνεται με τον υψηλότερο βαθμό για τον οποίο πληροί τις προϋποθέσεις. Εάν η πρώτη συνθήκη είναι αληθής (A2>=90), επιστρέφει "A" και δεν αξιολογεί άλλες συνθήκες.

Λανθασμένος τύπος παραγγελίας

Εάν η σειρά των συνθηκών αντιστραφεί, ξεκινώντας από το χαμηλότερο όριο, θα επέστρεφε εσφαλμένα αποτελέσματα.

=IF(B2>=60, "D", IF(B2>=70, "C", IF(B2>=80, "B", IF(B2>=90, "A", "F"))))

Σε αυτόν τον εσφαλμένο τύπο, μια βαθμολογία 95 θα πληρούσε αμέσως την πρώτη συνθήκη B2>=60 και θα της απονεμηθεί λανθασμένα ο βαθμός "D".

Οι αριθμοί και το κείμενο πρέπει να αντιμετωπίζονται διαφορετικά

Αυτή η ενότητα θα σας δείξει πώς οι αριθμοί και το κείμενο αντιμετωπίζονται διαφορετικά στις ένθετες δηλώσεις IF.

Αριθμοί

Οι αριθμοί χρησιμοποιούνται για αριθμητικές συγκρίσεις και υπολογισμούς. Στις ένθετες δηλώσεις IF, μπορείτε να συγκρίνετε απευθείας αριθμούς χρησιμοποιώντας τελεστές όπως >, <, =, >= και <=.

Κείμενο

Στις ένθετες δηλώσεις IF, το κείμενο πρέπει να είναι περικλείεται σε διπλά εισαγωγικά. Δείτε τα A, B, C, D και F στον ακόλουθο τύπο:

=IF(A2>=90, "A", IF(A2>=80, "B", IF(A2>=70, "C", IF(A2>=60, "D", "F"))))

Περιορισμοί ένθετων IF

Αυτή η ενότητα παραθέτει αρκετούς περιορισμούς και μειονεκτήματα του ένθετου IF.

Πολυπλοκότητα και αναγνωσιμότητα:

Παρόλο που το Excel σάς επιτρέπει να τοποθετήσετε έως και 64 διαφορετικές λειτουργίες IF, δεν είναι καθόλου σκόπιμο να το κάνετε. Όσο περισσότερα επίπεδα φωλιάς, τόσο πιο περίπλοκος γίνεται ο τύπος. Αυτό μπορεί να οδηγήσει σε τύπους που είναι δύσκολο να διαβαστούν, να κατανοηθούν και να διατηρηθούν.

Επιρρεπής σε λάθη:

Επιπλέον, οι σύνθετες ένθετες δηλώσεις IF μπορεί να γίνουν επιρρεπείς σε σφάλματα και να είναι δύσκολο να εντοπιστούν σφάλματα ή να τροποποιηθούν.

Δύσκολο να επεκταθεί ή να κλιμακωθεί:

Εάν αλλάξει η λογική σας ή χρειάζεται να προσθέσετε περισσότερες συνθήκες, τα βαθιά ένθετα IF μπορεί να είναι δύσκολο να τροποποιηθούν ή να επεκταθούν.

Η κατανόηση αυτών των περιορισμών είναι το κλειδί για την αποτελεσματική χρήση ένθετων δηλώσεων IF στο Excel. Συχνά, ο συνδυασμός ένθετων IF με άλλες λειτουργίες ή η αναζήτηση εναλλακτικών προσεγγίσεων μπορεί να οδηγήσει σε πιο αποτελεσματικές και διατηρήσιμες λύσεις.

Εναλλακτικές λύσεις για το Nested IF

Αυτή η ενότητα παραθέτει πολλές συναρτήσεις στο Excel που μπορούν να χρησιμοποιηθούν ως εναλλακτικές σε ένθετες δηλώσεις IF.

Χρησιμοποιώντας το VLOOKUP

Μπορείτε να χρησιμοποιήσετε τη συνάρτηση VLOOKUP αντί για ένθετες εντολές IF για να ολοκληρώσετε τα δύο παραπάνω πρακτικά παραδείγματα. Δείτε πώς μπορείτε να το κάνετε:

Παράδειγμα 1: Σύστημα βαθμολόγησης με VLOOKUP

Εδώ θα δείξω πώς να χρησιμοποιήσετε το VLOOKUP για να εκχωρήσετε βαθμούς με βάση τις βαθμολογίες.

Βήμα 1: Δημιουργήστε έναν πίνακα αναζήτησης για βαθμούς

Αρχικά, πρέπει να δημιουργήσετε έναν πίνακα αναζήτησης (όπως E1:F6 σε αυτήν την περίπτωση) για το εύρος βαθμολογίας και τους αντίστοιχους βαθμούς. Note: Οι βαθμολογίες στην πρώτη στήλη του πίνακα πρέπει να ταξινομηθούν με αύξουσα σειρά.

Βήμα 2: Εφαρμόστε τη συνάρτηση VLOOKUP για να εκχωρήσετε βαθμούς

Επιλέξτε ένα κενό κελί (C2 σε αυτήν την περίπτωση), εισαγάγετε τον ακόλουθο τύπο και πατήστε το εισάγετε κλειδί για να πάρεις την πρώτη τάξη. Επιλέξτε αυτό το κελί τύπου και σύρετέ το Γεμίστε τη λαβή κάτω για να πάρει τους υπόλοιπους βαθμούς.

=VLOOKUP(B2,$E$2:$F$6,2,TRUE)

Notes:
  • Η τιμή 95 στο κελί B2 είναι αυτή που αναζητά το VLOOKUP στην πρώτη στήλη του πίνακα αναζήτησης ($E$2:$F$6). Εάν βρεθεί, επιστρέφει τον αντίστοιχο βαθμό από τη δεύτερη στήλη του πίνακα, που βρίσκεται στην ίδια σειρά με την τιμή που αντιστοιχεί.
  • Θυμηθείτε να κάνετε την αναφορά του πίνακα αναζήτησης απόλυτη (προσθέστε τα σύμβολα του δολαρίου ($) πριν από τις αναφορές), πράγμα που σημαίνει ότι η αναφορά δεν θα αλλάξει εάν ο τύπος αντιγραφεί σε άλλο κελί.
  • Για να μάθετε περισσότερα σχετικά με τη λειτουργία VLOOKUP, επισκεφθείτε αυτή τη σελίδα.
Παράδειγμα 2: Υπολογισμός προμήθειας πωλήσεων με VLOOKUP

Μπορείτε επίσης να χρησιμοποιήσετε το VLOOKUP για να ολοκληρώσετε τον υπολογισμό της προμήθειας πωλήσεων στο Excel. Παρακαλώ κάντε τα εξής.

Βήμα 1: Δημιουργήστε έναν πίνακα αναζήτησης για βαθμούς

Αρχικά, πρέπει να δημιουργήσετε έναν πίνακα αναζήτησης για τις πωλήσεις και το αντίστοιχο ποσοστό προμήθειας, όπως E2:F4 σε αυτήν την περίπτωση. Note: Οι πωλήσεις στην πρώτη στήλη του πίνακα πρέπει να ταξινομηθούν με αύξουσα σειρά.

Βήμα 2: Εφαρμόστε τη συνάρτηση VLOOKUP για να εκχωρήσετε βαθμούς

Επιλέξτε ένα κενό κελί (C2 σε αυτήν την περίπτωση), εισαγάγετε τον ακόλουθο τύπο και πατήστε το πλήκτρο Enter για να λάβετε την πρώτη προμήθεια. Επιλέξτε αυτό το κελί τύπου και σύρετε τη λαβή γεμίσματος προς τα κάτω για να λάβετε τα υπόλοιπα αποτελέσματα.

=B2*VLOOKUP(B2,$E$2:$F$4,2,TRUE)

Notes:
  • Και στα δύο παραδείγματα, το VLOOKUP χρησιμοποιείται για την εύρεση μιας τιμής σε έναν πίνακα με βάση μια τιμή αναζήτησης (βαθμολογία ή ποσό πωλήσεων) και επιστρέφει μια τιμή στην ίδια σειρά από μια καθορισμένη στήλη (βαθμός ή ποσοστό προμήθειας). Η τέταρτη παράμετρος TRUE υποδεικνύει μια κατά προσέγγιση αντιστοίχιση, η οποία είναι κατάλληλη για αυτά τα σενάρια όπου η ακριβής τιμή αναζήτησης ενδέχεται να μην υπάρχει στον πίνακα.
  • Για να μάθετε περισσότερα σχετικά με τη λειτουργία VLOOKUP, επισκεφθείτε αυτή τη σελίδα.

Χρήση IFS

Η Λειτουργία IFS απλοποιεί τη διαδικασία εξαλείφοντας την ανάγκη για ένθεση και διευκολύνει την ανάγνωση και τη διαχείριση των τύπων. Βελτιώνει την αναγνωσιμότητα και απλοποιεί τον χειρισμό πολλαπλών ελέγχων υπό όρους. Για να χρησιμοποιήσετε τη λειτουργία IFS, βεβαιωθείτε ότι χρησιμοποιείτε Excel 2019 ή μεταγενέστερη έκδοση ή ότι έχετε συνδρομή στο Office 365. Ας δούμε πώς μπορεί να εφαρμοστεί σε πρακτικά παραδείγματα.

Παράδειγμα 1: Σύστημα βαθμολόγησης με IFS

Υποθέτοντας τα ίδια κριτήρια βαθμολόγησης όπως πριν, η συνάρτηση IFS μπορεί να χρησιμοποιηθεί ως εξής:

Επιλέξτε ένα κενό κελί, όπως το C2, εισαγάγετε τον ακόλουθο τύπο και πατήστε εισάγετε για να βγει το πρώτο αποτέλεσμα. Επιλέξτε αυτό το κελί αποτελέσματος και σύρετέ το Γεμίστε τη λαβή κάτω για να λάβετε τα υπόλοιπα αποτελέσματα.

=IFS(B2>=90,"A",B2>=80,"B",B2>=70,"C",B2>=60,"D",B2<60,"F")

Notes:
  • Κάθε συνθήκη αξιολογείται με τη σειρά. Μόλις πληρούται μια συνθήκη, επιστρέφεται το αντίστοιχο αποτέλεσμα και ο τύπος σταματά να ελέγχει περαιτέρω συνθήκες. Σε αυτήν την περίπτωση, ο τύπος χρησιμοποιείται για την εκχώρηση βαθμών με βάση τη βαθμολογία στο Β2, ακολουθώντας μια τυπική κλίμακα βαθμολόγησης όπου υψηλότερη βαθμολογία αντιστοιχεί σε καλύτερο βαθμό.
  • Για να μάθετε περισσότερα σχετικά με τη λειτουργία IFS, επισκεφθείτε αυτή τη σελίδα.
Παράδειγμα 2: Υπολογισμός προμήθειας πωλήσεων με IFS

Για το σενάριο υπολογισμού της προμήθειας πωλήσεων, η συνάρτηση IFS εφαρμόζεται ως εξής:

Επιλέξτε ένα κενό κελί, όπως το C2, εισαγάγετε τον ακόλουθο τύπο και πατήστε εισάγετε για να βγει το πρώτο αποτέλεσμα. Επιλέξτε αυτό το κελί αποτελέσματος και σύρετέ το Γεμίστε τη λαβή κάτω για να λάβετε τα υπόλοιπα αποτελέσματα.

=B2*IFS(B2>20000,20%,B2>=10000,15%,TRUE,10%)

Χρήση CHOOSE και MATCH

Η προσέγγιση CHOOSE and MATCH μπορεί να είναι πιο αποτελεσματική και πιο εύκολη στη διαχείριση σε σύγκριση με τις ένθετες δηλώσεις IF. Αυτή η μέθοδος απλοποιεί τον τύπο και κάνει τις ενημερώσεις ή τις αλλαγές πιο απλές. Παρακάτω θα δείξω πώς να χρησιμοποιήσετε έναν συνδυασμό των συναρτήσεων CHOOSE και MATCH για να χειριστείτε τα δύο πρακτικά παραδείγματα σε αυτό το άρθρο.

Παράδειγμα 1: Σύστημα βαθμολόγησης με CHOOSE και MATCH

Μπορείτε να χρησιμοποιήσετε το συνδυασμό των συναρτήσεων CHOOSE και MATCH για να εκχωρήσετε βαθμούς με βάση διαφορετικές βαθμολογίες.

Βήμα 1: Δημιουργήστε έναν πίνακα αναζήτησης με τιμές αναζήτησης

Αρχικά, πρέπει να δημιουργήσετε μια σειρά κελιών που να περιέχουν τις τιμές κατωφλίου στις οποίες θα πραγματοποιηθεί αναζήτηση MATCH, όπως $E$2:$E$6 σε αυτήν την περίπτωση. Note: Οι αριθμοί σε αυτό το εύρος πρέπει να ταξινομηθούν με αύξουσα σειρά για να λειτουργεί σωστά η συνάρτηση MATCH όταν χρησιμοποιείται κατά προσέγγιση τύπος αντιστοίχισης.

Βήμα 2: Εφαρμόστε CHOOSE and MATCH για να εκχωρήσετε βαθμούς

Επιλέξτε ένα κενό κελί (C2 σε αυτήν την περίπτωση), εισαγάγετε τον ακόλουθο τύπο και πατήστε το εισάγετε κλειδί για να πάρεις την πρώτη τάξη. Επιλέξτε αυτό το κελί τύπου και σύρετέ το Γεμίστε τη λαβή κάτω για να λάβετε τα υπόλοιπα αποτελέσματα.

=CHOOSE(MATCH(B2, $E$2:$E$6, 1), "F", "D", "C", "B", "A")

Notes:
  • ΑΓΩΝΑΣ (B2, $E$2:$E$6, 1): Αυτό το μέρος του τύπου αναζητά τη βαθμολογία (95) στο κελί B2 εντός του εύρους $E$2:$E$6. Το 1 υποδεικνύει ότι το MATCH θα πρέπει να βρει μια κατά προσέγγιση αντιστοίχιση, πράγμα που σημαίνει ότι βρίσκει τη μεγαλύτερη τιμή στο εύρος που είναι μικρότερη ή ίση με B2.
  • ΕΠΙΛΟΓΗ (..., "F", "D", "C", "B", "A"): Με βάση τη θέση που επιστρέφεται από τη συνάρτηση MATCH, το CHOOSE επιλέγει έναν αντίστοιχο βαθμό.
  • Για να μάθετε περισσότερα για το Συνάρτηση MATCH, επισκεφθείτε αυτή τη σελίδα.
  • Για να μάθετε περισσότερα για το ΕΠΙΛΟΓΗ λειτουργίας, επισκεφθείτε αυτή τη σελίδα.
Παράδειγμα 2: Υπολογισμός προμήθειας πωλήσεων με IFS

Η χρήση του συνδυασμού CHOOSE και MATCH για έναν υπολογισμό της προμήθειας πωλήσεων μπορεί επίσης να είναι αποτελεσματική, ειδικά όταν τα ποσοστά προμήθειας βασίζονται σε καθορισμένα όρια πωλήσεων. Ας δούμε πώς μπορούμε να κάνουμε.

Βήμα 1: Δημιουργήστε έναν πίνακα αναζήτησης με τιμές αναζήτησης

Αρχικά, πρέπει να δημιουργήσετε μια σειρά κελιών που να περιέχουν τις τιμές κατωφλίου στις οποίες θα πραγματοποιηθεί αναζήτηση MATCH, όπως $E$2:$E$4 σε αυτήν την περίπτωση. Note: Οι αριθμοί σε αυτό το εύρος πρέπει να ταξινομηθούν με αύξουσα σειρά για να λειτουργεί σωστά η συνάρτηση MATCH όταν χρησιμοποιείται κατά προσέγγιση τύπος αντιστοίχισης.

Βήμα 2: Εφαρμόστε το CHOOSE and MATCH για να λάβετε τα αποτελέσματα

Επιλέξτε ένα κενό κελί (C2 σε αυτήν την περίπτωση), εισαγάγετε τον ακόλουθο τύπο και πατήστε το εισάγετε κλειδί για να πάρεις την πρώτη τάξη. Επιλέξτε αυτό το κελί τύπου και σύρετέ το Γεμίστε τη λαβή κάτω για να λάβετε τα υπόλοιπα αποτελέσματα.

=B2*CHOOSE(MATCH(B2, $E$2:$E$4, 1), 10%, 15%, 20%)

Notes:

Συμπερασματικά, η κυριαρχία των ένθετων εντολών IF στο Excel είναι μια πολύτιμη δεξιότητα που ενισχύει την ικανότητά σας να χειρίζεστε πολύπλοκα λογικά σενάρια στις διαδικασίες ανάλυσης δεδομένων και λήψης αποφάσεων. Ενώ τα ένθετα IF είναι ισχυρά για πολύπλοκες λογικές λειτουργίες, είναι σημαντικό να προσέχετε τους περιορισμούς τους. Πιο απλές εναλλακτικές λύσεις όπως το VLOOKUP, το IFS και το CHOOSE with MATCH μπορούν να παρέχουν πιο βελτιωμένες λύσεις σε ορισμένα σενάρια. Οπλισμένοι με αυτές τις πληροφορίες, μπορείτε τώρα να εφαρμόσετε με σιγουριά τις πιο κατάλληλες τεχνικές του Excel στις εργασίες ανάλυσης δεδομένων σας, διασφαλίζοντας τη σαφήνεια, την ακρίβεια και την αποτελεσματικότητα στα υπολογιστικά φύλλα σας. Για όσους επιθυμούν να εμβαθύνουν στις δυνατότητες του Excel, ο ιστότοπός μας μπορεί να υπερηφανεύεται για πληθώρα οδηγών. Ανακαλύψτε περισσότερες συμβουλές και κόλπα για το Excel εδώ.

Τα καλύτερα εργαλεία παραγωγικότητας γραφείου

🤖 Kutools AI Aide: Επανάσταση στην ανάλυση δεδομένων με βάση: Ευφυής Εκτέλεση   |  Δημιουργία κώδικα  |  Δημιουργία προσαρμοσμένων τύπων  |  Αναλύστε δεδομένα και δημιουργήστε γραφήματα  |  Επίκληση Λειτουργιών Kutools...
Δημοφιλή χαρακτηριστικά: Εύρεση, επισήμανση ή αναγνώριση διπλότυπων   |  Διαγραφή κενών γραμμών   |  Συνδυάστε στήλες ή κελιά χωρίς απώλεια δεδομένων   |   Γύρος χωρίς φόρμουλα ...
Σούπερ Αναζήτηση: VLookup πολλαπλών κριτηρίων  |   VLookup πολλαπλών τιμών  |   VLookup σε πολλά φύλλα   |   Ασαφής αναζήτηση ....
Σύνθετη αναπτυσσόμενη λίστα: Γρήγορη δημιουργία αναπτυσσόμενης λίστας   |  Εξαρτημένη αναπτυσσόμενη λίστα   |  Πολλαπλή αναπτυσσόμενη λίστα ....
Διαχειριστής στήλης: Προσθέστε έναν συγκεκριμένο αριθμό στηλών  |  Μετακίνηση στηλών  |  Εναλλαγή κατάστασης ορατότητας κρυφών στηλών  |  Συγκρίνετε εύρη και στήλες ...
Επιλεγμένα Χαρακτηριστικά: Εστίαση πλέγματος   |  Προβολή σχεδίου   |   Μεγάλη Formula Bar   |  Διαχείριση βιβλίου εργασίας & φύλλου   |  Βιβλιοθήκη πόρων (Αυτόματο κείμενο)   |  Επιλογή ημερομηνίας   |  Συνδυάστε φύλλα εργασίας   |  Κρυπτογράφηση/Αποκρυπτογράφηση κελιών   |  Αποστολή email ανά λίστα   |  Σούπερ φίλτρο   |   Ειδικό φίλτρο (φίλτρο με έντονη γραφή/πλάγια γραφή/διαγραφή...) ...
Κορυφαία 15 σύνολα εργαλείων:  12 Κείμενο Εργαλεία (Προσθήκη κειμένου, Κατάργηση χαρακτήρων, ...)   |   50 + Διάγραμμα Τύποι (Gantt διάγραμμα, ...)   |   40+ Πρακτικό ΜΑΘΗΜΑΤΙΚΟΙ τυποι (Υπολογίστε την ηλικία με βάση τα γενέθλια, ...)   |   19 Εισαγωγή Εργαλεία (Εισαγωγή κωδικού QR, Εισαγωγή εικόνας από το μονοπάτι, ...)   |   12 Μετατροπή Εργαλεία (Αριθμοί σε λέξεις, Μετατροπή Συναλλάγματος, ...)   |   7 Συγχώνευση & διαχωρισμός Εργαλεία (Σύνθετες σειρές συνδυασμού, Διαίρεση κελιών, ...)   |   ... κι αλλα

Αυξήστε τις δεξιότητές σας στο Excel με τα Kutools για Excel και απολαύστε την αποτελεσματικότητα όπως ποτέ πριν. Το Kutools για Excel προσφέρει πάνω από 300 προηγμένες δυνατότητες για την ενίσχυση της παραγωγικότητας και την εξοικονόμηση χρόνου.  Κάντε κλικ εδώ για να αποκτήσετε τη δυνατότητα που χρειάζεστε περισσότερο...

Περιγραφή

Το Office Tab φέρνει τη διεπαφή με καρτέλες στο Office και κάνει την εργασία σας πολύ πιο εύκολη

  • Ενεργοποίηση επεξεργασίας και ανάγνωσης καρτελών σε Word, Excel, PowerPoint, Publisher, Access, Visio και Project.
  • Ανοίξτε και δημιουργήστε πολλά έγγραφα σε νέες καρτέλες του ίδιου παραθύρου και όχι σε νέα παράθυρα.
  • Αυξάνει την παραγωγικότητά σας κατά 50% και μειώνει εκατοντάδες κλικ του ποντικιού για εσάς κάθε μέρα!
Comments (0)
No ratings yet. Be the first to rate!
There are no comments posted here yet
Please leave your comments in English
Guest
Posting as Guest
×
Rate this post:
Reset
0   Characters
Suggested Locations