Πώς να αποθηκεύσετε ένα φύλλο εργασίας ως αρχείο PDF και να το στείλετε μέσω ηλεκτρονικού ταχυδρομείου ως συνημμένο μέσω του Outlook;

Σε ορισμένες περιπτώσεις, ίσως χρειαστεί να στείλετε ένα φύλλο εργασίας ως αρχείο PDF μέσω του Outlook. Συνήθως, πρέπει να αποθηκεύσετε με μη αυτόματο τρόπο το φύλλο εργασίας ως αρχείο PDF και, στη συνέχεια, να δημιουργήσετε ένα νέο μήνυμα ηλεκτρονικού ταχυδρομείου με αυτό το αρχείο PDF ως συνημμένο στο Outlook και τελικά να το στείλετε. Είναι χρονοβόρο για την επίτευξή του χειροκίνητα βήμα προς βήμα. Σε αυτό το άρθρο, θα σας δείξουμε πώς να αποθηκεύσετε γρήγορα ένα φύλλο εργασίας ως αρχείο PDF και να το στείλετε αυτόματα ως συνημμένο μέσω του Outlook στο Excel.

Αποθηκεύστε ένα φύλλο εργασίας ως αρχείο PDF και στείλτε το μέσω ηλεκτρονικού ταχυδρομείου ως συνημμένο με κώδικα VBA

Αποθηκεύστε ένα φύλλο εργασίας ως αρχείο PDF και στείλτε το μέσω ηλεκτρονικού ταχυδρομείου ως συνημμένο με κώδικα VBA

Μπορείτε να εκτελέσετε τον παρακάτω κώδικα VBA για να αποθηκεύσετε αυτόματα το ενεργό φύλλο εργασίας ως αρχείο PDF και, στη συνέχεια, να το στείλετε μέσω ηλεκτρονικού ταχυδρομείου ως συνημμένο μέσω του Outlook. Κάντε τα εξής:

1. Ανοίξτε το φύλλο εργασίας που θα αποθηκεύσετε ως PDF και θα στείλετε και, στη συνέχεια, πατήστε το άλλος + F11 ταυτόχρονα για να ανοίξετε το Microsoft Visual Basic για εφαρμογές παράθυρο.

2. Στο Microsoft Visual Basic για εφαρμογές παράθυρο, κάντε κλικ στην επιλογή Κύριο θέμα > Μονάδα μέτρησης. Στη συνέχεια, αντιγράψτε και επικολλήστε τον παρακάτω κώδικα VBA στο Κώδικας παράθυρο. Δείτε το στιγμιότυπο οθόνης:

Κωδικός VBA: Αποθηκεύστε ένα φύλλο εργασίας ως αρχείο PDF και στείλτε το ως συνημμένο

Sub Saveaspdfandsend()
Dim xSht As Worksheet
Dim xFileDlg As FileDialog
Dim xFolder As String
Dim xYesorNo As Integer
Dim xOutlookObj As Object
Dim xEmailObj As Object
Dim xUsedRng As Range

Set xSht = ActiveSheet
Set xFileDlg = Application.FileDialog(msoFileDialogFolderPicker)

If xFileDlg.Show = True Then
   xFolder = xFileDlg.SelectedItems(1)
Else
   MsgBox "You must specify a folder to save the PDF into." & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Must Specify Destination Folder"
   Exit Sub
End If
xFolder = xFolder + "\" + xSht.Name + ".pdf"

'Check if file already exist
If Len(Dir(xFolder)) > 0 Then
    xYesorNo = MsgBox(xFolder & " already exists." & vbCrLf & vbCrLf & "Do you want to overwrite it?", _
                      vbYesNo + vbQuestion, "File Exists")
    On Error Resume Next
    If xYesorNo = vbYes Then
        Kill xFolder
    Else
        MsgBox "if you don't overwrite the existing PDF, I can't continue." _
                    & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Exiting Macro"
        Exit Sub
    End If
    If Err.Number <> 0 Then
        MsgBox "Unable to delete existing file.  Please make sure the file is not open or write protected." _
                    & vbCrLf & vbCrLf & "Press OK to exit this macro.", vbCritical, "Unable to Delete File"
        Exit Sub
    End If
End If

Set xUsedRng = xSht.UsedRange
If Application.WorksheetFunction.CountA(xUsedRng.Cells) <> 0 Then
    'Save as PDF file 
    xSht.ExportAsFixedFormat Type:=xlTypePDF, Filename:=xFolder, Quality:=xlQualityStandard
    
    'Create Outlook email 
    Set xOutlookObj = CreateObject("Outlook.Application")
    Set xEmailObj = xOutlookObj.CreateItem(0)
    With xEmailObj
        .Display
        .To = ""
        .CC = ""
        .Subject = xSht.Name + ".pdf"
        .Attachments.Add xFolder
        If DisplayEmail = False Then
            '.Send
        End If
    End With
Else
  MsgBox "The active worksheet cannot be blank"
  Exit Sub
End If
End Sub

3. Πάτα το F5 κλειδί για την εκτέλεση του κώδικα. Στο Αναζήτηση πλαίσιο διαλόγου, επιλέξτε έναν φάκελο για να αποθηκεύσετε αυτό το αρχείο PDF και, στη συνέχεια, κάντε κλικ στο OK κουμπί.

Σημειώσεις:

Σχετικά Άρθρα:

• Πώς να αποθηκεύσετε ένα όνομα αρχείου Excel με χρονική σήμανση;
• Πώς να χρησιμοποιήσετε τη λειτουργία Αποθήκευση ως για αυτόματη αντικατάσταση υπάρχοντος αρχείου στο Excel;
• Πώς να αποθηκεύσετε, να εξαγάγετε πολλά / όλα τα φύλλα για να διαχωρίσετε αρχεία csv ή κειμένου στο Excel;
• Πώς να απενεργοποιήσετε ή να μην επιτρέψετε τις επιλογές Save & Save As στο Excel;
• Πώς να απενεργοποιήσετε την αποθήκευση βιβλίου εργασίας, αλλά επιτρέψτε την αποθήκευση μόνο στο Excel;