Πώς να μετρήσετε τους αριθμούς σελίδων των αρχείων Pdf στο Excel;

Εάν υπάρχουν πολλά αρχεία Pdf σε έναν συγκεκριμένο φάκελο, τώρα, θέλετε να εμφανίσετε όλα αυτά τα ονόματα αρχείων σε ένα φύλλο εργασίας και να λάβετε τους αριθμούς σελίδων κάθε αρχείου. Πώς θα μπορούσατε να αντιμετωπίσετε αυτήν την εργασία στο Excel γρήγορα και εύκολα;

Μετρήστε τους αριθμούς σελίδων των αρχείων Pdf από ένα φάκελο στο φύλλο εργασίας με τον κώδικα VBA

Μετρήστε τους αριθμούς σελίδων των αρχείων Pdf από ένα φάκελο στο φύλλο εργασίας με τον κώδικα VBA

Ίσως ο ακόλουθος κωδικός VBA μπορεί να σας βοηθήσει να εμφανίσετε όλα τα ονόματα αρχείων Pdf και τους αριθμούς κάθε σελίδας τους σε ένα φύλλο εργασίας, κάντε το ως εξής:

1. Ανοίξτε ένα φύλλο εργασίας όπου θέλετε να λάβετε τα αρχεία Pdf και τους αριθμούς σελίδας.

2. Κρατήστε πατημένο το ALT + F11 και ανοίγει το Microsoft Visual Basic για εφαρμογές παράθυρο.

3. Κλίκ Κύριο θέμα > Μονάδα μέτρησηςκαι επικολλήστε την ακόλουθη μακροεντολή στο Μονάδα μέτρησης Παράθυρο.

Κωδικός VBA: Λίστα όλων των ονομάτων αρχείων και αριθμών σελίδων Pdf στο φύλλο εργασίας:

Sub Test()
    Dim I As Long
    Dim xRg As Range
    Dim xStr As String
    Dim xFd As FileDialog
    Dim xFdItem As Variant
    Dim xFileName As String
    Dim xFileNum As Long
    Dim RegExp As Object
    Set xFd = Application.FileDialog(msoFileDialogFolderPicker)
    If xFd.Show = -1 Then
        xFdItem = xFd.SelectedItems(1) & Application.PathSeparator
        xFileName = Dir(xFdItem & "*.pdf", vbDirectory)
        Set xRg = Range("A1")
        Range("A:B").ClearContents
        Range("A1:B1").Font.Bold = True
        xRg = "File Name"
        xRg.Offset(0, 1) = "Pages"
        I = 2
        xStr = ""
        Do While xFileName <> ""
            Cells(I, 1) = xFileName
            Set RegExp = CreateObject("VBscript.RegExp")
            RegExp.Global = True
            RegExp.Pattern = "/Type\s*/Page[^s]"
            xFileNum = FreeFile
            Open (xFdItem & xFileName) For Binary As #xFileNum
                xStr = Space(LOF(xFileNum))
                Get #xFileNum, , xStr
            Close #xFileNum
            Cells(I, 2) = RegExp.Execute(xStr).Count
            I = I + 1
            xFileName = Dir
        Loop
        Columns("A:B").AutoFit
    End If
End Sub

4. Αφού επικολλήσετε τον κωδικό και, στη συνέχεια, πατήστε F5 κλειδί για την εκτέλεση αυτού του κώδικα, και a Αναζήτηση το παράθυρο έχει αναδυθεί, επιλέξτε το φάκελο που περιέχει τα αρχεία Pdf που θέλετε να απαριθμήσετε και να μετρήσετε τους αριθμούς σελίδων, δείτε το στιγμιότυπο οθόνης:

5. Και μετά, κάντε κλικ στο OK κουμπί, όλα τα ονόματα αρχείων Pdf και οι αριθμοί σελίδων παρατίθενται στο τρέχον φύλλο εργασίας, δείτε το στιγμιότυπο οθόνης: