Πώς να αλλάξετε την προεπιλεγμένη ώρα για καθυστέρηση παράδοσης στο Outlook;

Όταν ενεργοποιείτε την επιλογή καθυστέρησης παράδοσης (το Μην παραδώσετε πριν επιλογή στο ακόλουθο στιγμιότυπο οθόνης) για ένα email στο Outlook, η ώρα αποστολής έχει οριστεί στις 5:00 μ.μ. από προεπιλογή. Ας υποθέσουμε ότι εργάζεστε αργά το βράδυ και δεν θέλετε να ξέρουν οι άλλοι ότι εργάζεστε υπερωρίες. Πρέπει να ενεργοποιήσετε την επιλογή καθυστέρησης παράδοσης για τα email σας πριν τα στείλετε. Αφού ενεργοποιήσετε την επιλογή, πρέπει να αλλάξετε τον προεπιλεγμένο χρόνο αποστολής με μη αυτόματο τρόπο. Διαφορετικά, το email θα σταλεί μετά τις 5:00 την επόμενη μέρα. Υπάρχει κάποιος τρόπος να αλλάξετε αυτόν τον προεπιλεγμένο χρόνο παράδοσης;

Αυτό το σεμινάριο παρέχει έναν κωδικό VBA για να σας βοηθήσει να αλλάξετε την προεπιλεγμένη ώρα για την επιλογή καθυστέρησης παράδοσης στο Outlook.

Αλλάξτε την προεπιλεγμένη ώρα για καθυστέρηση παράδοσης στο Outlook με κωδικό VBA

Μπορείτε να εφαρμόσετε τον ακόλουθο κώδικα VBA για να αλλάξετε την προεπιλεγμένη ώρα για την επιλογή καθυστέρησης παράδοσης στο Outlook.

Στον ακόλουθο κώδικα VBA:

Μπορείτε να καθορίσετε δύο φορές: το καθυστέρηση παράδοσης και το επιλογή καθυστέρησης παράδοσης που ενεργοποιεί τον χρόνο.

Για παράδειγμα, ορίζετε τον χρόνο καθυστέρησης παράδοσης στις 07:30 π.μ. και ρυθμίζετε την επιλογή καθυστέρησης παράδοσης να ενεργοποιείται αυτόματα μετά τις 5:30 μ.μ. Όταν στέλνετε ένα email κατά τις 07:30 π.μ. - 5:30 μ.μ., το email θα σταλεί απευθείας. Εάν ένα email σταλεί κατά τις 5:30 μ.μ. – 07:30 π.μ., θα έχει προγραμματιστεί να σταλεί μετά τις 07:30 π.μ. της επόμενης ημέρας.

Δοκιμάστε το σενάριο ως εξής.

1. Εκκινήστε το Outlook, πατήστε το άλλος + F11 ταυτόχρονα για να ανοίξετε το Microsoft Visual Basic για εφαρμογές παράθυρο.

2. Στο Microsoft Visual Basic για εφαρμογές παράθυρο, κάντε διπλό κλικ Project1 > Αντικείμενα του Microsoft Outlook > Αυτό το OutlookSession για να ανοίξετε το ThisOutlookSession (Κωδικός) παράθυρο και, στη συνέχεια, αντιγράψτε τον ακόλουθο κώδικα σε αυτό το παράθυρο κώδικα.

Κωδικός VBA: αλλαγή της προεπιλεγμένης ώρας για καθυστέρηση παράδοσης στο Outlook

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
'Updated by Extendoffice & EWP 20230602
  Const xDelayTime As String = "07:30:00"  'The delay delivery time of emails
  Const xCompareTime As String = "17:30:00" 'The time to enable the delay delivery option
  Dim xMail As Outlook.MailItem
  Dim xWeekday As Integer
  Dim xNowTime As String
  Dim xIsDelay As Boolean
  Dim xRet1 As Integer
  Dim xRet2 As Integer
  On Error GoTo xError
  If (Item.Class <> olMail) Then Exit Sub
  Set xMail = Item
  xWeekday = Weekday(Date, vbMonday)
  xNowTime = Format(Now, "hh:nn:ss")
  xIsDelay = False
  xRet1 = StrComp(xNowTime, xDelayTime)
  xRet2 = StrComp(xNowTime, xCompareTime)
  If xRet1 = xRet2 Then
    xIsDelay = True
  End If
  If (xRet1 = -1) And (xRet2 = -1) Then
    xMail.DeferredDeliveryTime = Date & " " & xDelayTime
  Else
    If ((xWeekday = 5) And xIsDelay) Or (xWeekday = 6) Or (xWeekday = 7) Then
      xMail.DeferredDeliveryTime = (Date + (5 - xWeekday + 3)) & " " & xDelayTime
    ElseIf xIsDelay Then
      xMail.DeferredDeliveryTime = (Date + 1) & " " & xDelayTime
    End If
  End If
Exit Sub
xError:
  MsgBox "ItemSend: " & Err.Description, , "Kutools for Outlook"
End Sub

:

3. Αποθηκεύστε τον κωδικό και πατήστε το άλλος + Q πλήκτρα για να κλείσετε το Microsoft Visual Basic για εφαρμογές παράθυρο.

Από εδώ και στο εξής, όταν στέλνετε ένα email κατά τις 07:30 π.μ. - 5:30 μ.μ., το email θα αποστέλλεται απευθείας. Εάν ένα email σταλεί κατά τις 5:30 μ.μ. – 07:30 π.μ., θα έχει προγραμματιστεί να σταλεί μετά τις 07:30 π.μ. της επόμενης εργάσιμης ημέρας.

Σχετικά Άρθρα