Πώς να απαντήσετε κανονικά στο φάκελο απεσταλμένων στοιχείων από το Outlook; 

Κανονικά, όταν κάνετε κλικ στη λειτουργία Απάντηση στο φάκελο Απεσταλμένα στοιχεία για την αποστολή άλλου επιπλέον μηνύματος για τα άτομα που έχετε στείλει, η δική σας διεύθυνση email θα εμφανίζεται στο πεδίο Προς, όπως φαίνεται το παρακάτω στιγμιότυπο οθόνης. Αυτό μπορεί να είναι ενοχλητικό για την αλλαγή της διεύθυνσης κάθε φορά. Πώς θα μπορούσε το Outlook να χρησιμοποιήσει τη διεύθυνση του αρχικού παραλήπτη και όχι τη δική σας;

Απαντήστε κανονικά στο φάκελο Απεσταλμένα από το Outlook με τη δυνατότητα Απάντηση σε όλα

Απαντήστε κανονικά στο φάκελο Απεσταλμένα από το Outlook με κωδικό VBA

---

Απαντήστε κανονικά στο φάκελο Απεσταλμένα από το Outlook με τη δυνατότητα Απάντηση σε όλα

Στο Outlook, το Απάντηση σε όλους Η δυνατότητα μπορεί να σας βοηθήσει να λύσετε αυτό το πρόβλημα, κάντε το ως εξής:

Όταν πρέπει να απαντήσετε το απεσταλμένο email για αποστολή ξανά για να διατηρήσετε τη διεύθυνση του αρχικού παραλήπτη, κάντε κλικ Απάντηση σε όλους κουμπί και η διεύθυνση του αρχικού παραλήπτη βρίσκεται στο Προς την πεδίο όπως φαίνεται το ακόλουθο στιγμιότυπο οθόνης:

---

Απαντήστε κανονικά στο φάκελο Απεσταλμένα από το Outlook με κωδικό VBA

Κάποια στιγμή, μπορεί να ξεχάσετε το Απάντηση σε όλους χαρακτηριστικό κατά την απάντηση του απεσταλμένου μηνύματος, οπότε ο παρακάτω κώδικας VBA μπορεί να σας βοηθήσει να απαντήσετε κανονικά στο φάκελο Απεσταλμένα χρησιμοποιώντας τη λειτουργία Απάντηση. Κάντε τα παρακάτω βήματα:

1. Κρατήστε πατημένο το ALT + F11 για να ανοίξετε το Microsoft Visual Basic για εφαρμογές παράθυρο.

2. Στην Microsoft Visual Basic για εφαρμογές παράθυρο, κάντε διπλό κλικ Αυτό το OutlookSession από το Έργο1 (VbaProject.OTM) παράθυρο για να ανοίξετε τη λειτουργία και, στη συνέχεια, αντιγράψτε και επικολλήστε τον ακόλουθο κώδικα στην κενή μονάδα.

Κωδικός VBA: Απαντήστε κανονικά στο φάκελο Απεσταλμένα στοιχεία από το Outlook:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. Στη συνέχεια, αποθηκεύστε τον κώδικα και επανεκκινήστε το Outlook για να λάβετε το εφέ κώδικα, τώρα, όταν κάνετε κλικ απάντηση για να στείλετε ξανά ένα email στο Απεσταλμένα στοιχεία φάκελο, η διεύθυνση του αρχικού παραλήπτη εμφανίζεται στο πεδίο Προς, όπως χρειάζεστε.