Πώς να εκτυπώσετε εργασίες βάσει κατηγορίας στο Outlook;

Ας υποθέσουμε ότι υπάρχουν διάφορες κατηγορίες χρωμάτων στις εργασίες σας στο Outlook και τώρα, θέλετε να εκτυπώσετε τις λίστες εργασιών με βάση τις κατηγορίες σε διαφορετικές σελίδες. Πώς θα μπορούσατε να λύσετε αυτήν την εργασία στο Outlook;

Εκτύπωση εργασιών βάσει κατηγοριών σε διαφορετικές σελίδες χειροκίνητα μία προς μία

Εκτυπώστε εργασίες βάσει κατηγοριών σε διαφορετικές σελίδες με κώδικα VBA

Εκτύπωση εργασιών βάσει κατηγοριών σε διαφορετικές σελίδες χειροκίνητα μία προς μία

Στο Outlook, μπορείτε να εκτυπώσετε με μη αυτόματο τρόπο τις εργασίες με βάση τις διαφορετικές κατηγορίες σε διαφορετικές σελίδες μία προς μία, κάντε ως εξής:

1. Εκκινήστε το Outlook και μεταβείτε στο παράθυρο εργασιών και επιλέξτε το φάκελο εργασιών που θέλετε να εκτυπώσετε και, στη συνέχεια, πατήστε Ctrl + E για να ενεργοποιήσετε το Αναζήτηση κουτί και μετά κάτω από το Αναζήτηση κάντε κλικ στην καρτέλα Κατηγοριοποίηση και επιλέξτε μια κατηγορία χρώματος που θέλετε να εκτυπώσετε, δείτε στιγμιότυπο οθόνης:

εργασίες εκτύπωσης εγγράφων ανά κατηγορία 1

2. Στη συνέχεια, όλες οι εργασίες με τη συγκεκριμένη κατηγορία χρωμάτων παρατίθενται ταυτόχρονα, δείτε στιγμιότυπο οθόνης:

εργασίες εκτύπωσης εγγράφων ανά κατηγορία 2

3. Στη συνέχεια, συνεχίστε κάνοντας κλικ Αρχεία > για να εκτυπώσετε αυτήν τη λίστα εργασιών όπως εμφανίζεται το ακόλουθο στιγμιότυπο οθόνης:

εργασίες εκτύπωσης εγγράφων ανά κατηγορία 3

4. Επαναλάβετε τα παραπάνω βήματα για να εκτυπώσετε τις λίστες εργασιών με τις άλλες κατηγορίες χρωμάτων μία προς μία με μη αυτόματο τρόπο.

Εκτυπώστε εργασίες βάσει κατηγοριών σε διαφορετικές σελίδες με κώδικα VBA

Ακολουθεί ένας κώδικας VBA που μπορεί να σας βοηθήσει να εκτυπώσετε τις εργασίες με βάση την κατηγορία σε διαφορετικές σελίδες ταυτόχρονα, ακολουθήστε τα παρακάτω βήματα:

1. μεταβείτε στο Έργο παράθυρο και επιλέξτε το φάκελο εργασιών που θέλετε να εκτυπώσετε.

2. Στη συνέχεια, κρατήστε πατημένο το ALT + F11 για να ανοίξετε το Microsoft Visual Basic για εφαρμογές παράθυρο.

3. Και μετά, κάντε κλικ στο Κύριο θέμα > Μονάδα μέτρησης, αντιγράψτε και επικολλήστε τον παρακάτω κώδικα στην κενή κενή ενότητα:

Κώδικας VBA: Εκτύπωση εργασιών βάσει κατηγοριών σε διαφορετικές σελίδες:

Sub PrintTaskList_SpecificColorCategory()
    Dim xTaskItems As Outlook.Items
    Dim xTask As Outlook.TaskItem
    Dim xDictionary As Scripting.Dictionary
    Dim xCategoryArr As Variant, xCategory As Variant
    Dim xExcelApp As Excel.Application
    Dim xExcelWorkbook As Excel.Workbook
    Dim xExcelWorksheet As Excel.Worksheet
    Dim xSheet As Excel.Worksheet
    Dim xKey As Variant
    Dim xKeyStr As String
    Dim i As Long, xLastRow As Integer
    On Error Resume Next
    If Application.ActiveExplorer.CurrentFolder.DefaultItemType <> olTaskItem Then Exit Sub
    Set xTaskItems = Application.ActiveExplorer.CurrentFolder.Items
    Set xDictionary = New Scripting.Dictionary
    For Each xTask In xTaskItems
        xCategoryArr = Split(xTask.Categories, ",")
        For Each xCategory In xCategoryArr
            If xDictionary.Exists(Trim(xCategory)) = False Then
               xDictionary.Add Trim(xCategory), 0
            End If
        Next
    Next
    If xDictionary.Count = 0 Then
        MsgBox "The current Task doesn’t have any category", vbOKOnly + vbInformation, "Kutools for Outlook"
        Exit Sub
    End If
    Set xExcelApp = New Excel.Application
    Set xExcelWorkbook = xExcelApp.Workbooks.Add
    xExcelApp.Visible = True
    i = 0
    If xDictionary.Count > xExcelWorkbook.Sheets.Count Then
        xExcelWorkbook.Sheets.Add Count:=xDictionary.Count - xExcelWorkbook.Sheets.Count
    End If
    For Each xKey In xDictionary.Keys
        xKeyStr = CStr(xKey)
        i = i + 1
        Set xExcelWorksheet = xExcelWorkbook.Sheets(i)
        xExcelWorksheet.Name = xKeyStr
        With xExcelWorksheet
             .Range("A1") = xKeyStr
             .Range("A1").Font.Bold = True
             .Range("A1").Font.Size = 18
             .Range("A1", "C1").HorizontalAlignment = xlCenter
             .Range("A1", "C1").VerticalAlignment = xlCenter
             .Range("A1", "C1").Merge
             .Range("A2") = "Subject"
             .Range("A2").Font.Bold = True
             .Range("B2") = "Start Date"
             .Range("B2").Font.Bold = True
             .Range("C2") = "Due Date"
             .Range("C2").Font.Bold = True
        End With
        For Each xTask In xTaskItems
            If InStr(xTask.Categories, xKeyStr) > 0 Then
               xLastRow = xExcelWorksheet.UsedRange.Rows.Count + 1
               With xExcelWorksheet
                    .Range("A" & xLastRow) = xTask.Subject
                    .Range("B" & xLastRow) = xTask.StartDate
                    .Range("C" & xLastRow) = xTask.DueDate
               End With
            End If
        Next
        xExcelWorksheet.Columns("A:C").AutoFit
    Next
    For Each xSheet In xExcelWorkbook.Sheets
        xSheet.PrintOut
    Next
    xExcelWorkbook.Close False
    xExcelApp.Quit
End Sub

4. Στη συνέχεια κάντε κλικ στο κουμπί Εργαλεία > αναφορές στο Microsoft Visual Basic για εφαρμογές παράθυρο, στο αναδυόμενο Αναφορές-Έργο 1 πλαίσιο διαλόγου, επιλέξτε Βιβλιοθήκη αντικειμένων του Microsoft Excel και Χρόνος εκτέλεσης δέσμης ενεργειών Microsoft επιλογές από το Διαθέσιμες αναφορές πλαίσιο λίστας, δείτε το στιγμιότυπο οθόνης:

εργασίες εκτύπωσης εγγράφων ανά κατηγορία 4

5. Και μετά, κάντε κλικ στο OK κουμπί, τώρα, πατήστε F5 κλειδί για την εκτέλεση αυτού του κώδικα, αφού ολοκληρώσετε τον κώδικα, οι λίστες εργασιών με διαφορετικές κατηγορίες θα εκτυπωθούν σε διαφορετικές σελίδες.