Εκμάθηση Excel – εξαγωγή κειμένου ή αριθμού ανά συγκεκριμένη θέση
Σε πολλές περιπτώσεις, μπορεί να χρειαστεί να εξαγάγετε μόνο το χρήσιμο περιεχόμενο από μια πρόταση ή μια συμβολοσειρά κειμένου σε ένα κελί, όπως η εξαγωγή της επαρχίας από τη διεύθυνση, η εξαγωγή της διεύθυνσης email από μια πρόταση, η εξαγωγή του αριθμού λογαριασμού ταχυμεταφοράς από μια συνομιλία, και ούτω καθεξής. Αυτό το σεμινάριο περιορίζει την εξαγωγή σε μια συγκεκριμένη θέση σε ένα κελί και συλλέγει διαφορετικές μεθόδους για να βοηθήσει στην εξαγωγή κειμένου ή αριθμών από ένα κελί ανά συγκεκριμένη θέση στο Excel.
Περιεχόμενα: [ Κρύβω ]
Εξαγωγή κειμένου ανά θέση
Αυτή η ενότητα συγκεντρώνει κοινές θέσεις όπου ένα κείμενο μπορεί να εξαχθεί από ένα κελί και παρέχει αντίστοιχες μεθόδους για να τις χειριστείτε βήμα προς βήμα. Μπορείτε να περιηγηθείτε για περισσότερες λεπτομέρειες.
1. Εξάγετε τον αριθμό των χαρακτήρων από αριστερά ή δεξιά
Για να εξαγάγετε τον αριθμό των χαρακτήρων από την αριστερή ή τη δεξιά πλευρά μιας συμβολοσειράς, μπορείτε να δοκιμάσετε μία από τις παρακάτω μεθόδους.
1.1 Εξάγετε τους πρώτους ή τους τελευταίους N χαρακτήρες με τύπους
Υποθέτοντας ότι έχετε μια λίστα συμβολοσειρών κειμένου στη στήλη Β όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, για να εξαγάγετε τους 2 πρώτους χαρακτήρες και τους τελευταίους 2 χαρακτήρες από κάθε συμβολοσειρά, μπορείτε να εφαρμόσετε τους ακόλουθους τύπους.
Εξάγετε τους πρώτους N χαρακτήρες από μια συμβολοσειρά κειμένου
Η συνάρτηση LEFT μπορεί να βοηθήσει στην εύκολη εξαγωγή των πρώτων N χαρακτήρων από μια συμβολοσειρά κειμένου στο Excel.
Γενική φόρμουλα
=LEFT(text_string,[num_chars])
Επιχειρήματα
Τώρα μπορείτε να εφαρμόσετε αυτόν τον τύπο για να εξαγάγετε τους 2 πρώτους χαρακτήρες από τα κελιά της στήλης Β.
1. Επιλέξτε ένα κενό κελί, αντιγράψτε ή εισαγάγετε τον παρακάτω τύπο και πατήστε το εισάγετε κλειδί για να πάρετε το πρώτο αποτέλεσμα. Επιλέξτε το κελί του αποτελέσματος και σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να εφαρμόσετε τον τύπο σε άλλα κελιά.
=LEFT(B5,2)
Τώρα έχουν εξαχθεί οι 2 πρώτοι χαρακτήρες σε κάθε κελί του εύρους B5:B10.
Εξάγετε τους τελευταίους N χαρακτήρες από μια συμβολοσειρά κειμένου
Εδώ εφαρμόζουμε τη συνάρτηση RIGHT για να εξαγάγουμε τους τελευταίους N χαρακτήρες από μια συμβολοσειρά κειμένου στο Excel.
Γενική φόρμουλα
=RIGHT(text_string,[num_chars])
Επιχειρήματα
Επιλέξτε ένα κενό κελί, αντιγράψτε ή εισαγάγετε τον παρακάτω τύπο και πατήστε το εισάγετε κλειδί για το αποτέλεσμα. Στη συνέχεια, επιλέξτε αυτό το κελί αποτελέσματος και σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να λάβετε άλλα αποτελέσματα.
=RIGHT(B5,2)
1.2 Εξάγετε τον πρώτο ή τον τελευταίο N χαρακτήρες με ένα καταπληκτικό εργαλείο
Αν και οι παραπάνω τύποι είναι απλοί, για να εξαγάγετε τον πρώτο ή τον τελευταίο n χαρακτήρες από μια μακρά λίστα συμβολοσειράς κειμένου, πρέπει να σύρετε τη λαβή Αυτόματης Συμπλήρωσης από πάνω προς τα κάτω, κάτι που ίσως είναι λίγο χρονοβόρο. Εδώ προτείνει Kutools για Excel'S Εξαγωγή κειμένου βοηθητικό πρόγραμμα που βοηθά στην εξαγωγή του πρώτου ή του τελευταίου N χαρακτήρων από μια λίστα συμβολοσειράς κειμένου μαζικά.
1. Επιλέξτε εκ των προτέρων τη λίστα συμβολοσειρών κειμένου από την οποία θέλετε να εξαγάγετε κείμενο και κάντε κλικ Kutools > Κείμενο > Εξαγωγή κειμένου.
2. Στο αναδυόμενο παράθυρο Εξαγωγή κειμένου πλαίσιο διαλόγου, πρέπει να διαμορφώσετε ως εξής.
Note: Για να κάνετε το αποτέλεσμα δυναμικό όταν αλλάζει η συμβολοσειρά κειμένου, μπορείτε να ελέγξετε το Εισαγωγή ως τύπος κουτί.
3. Στο επόμενο αναδυόμενο παράθυρο Εξαγωγή κειμένου στο παράθυρο διαλόγου, επιλέξτε ένα κελί για την έξοδο των χαρακτήρων που έχουν εξαχθεί και, στη συνέχεια, κάντε κλικ OK.
Στη συνέχεια, οι καθορισμένοι πρώτοι ή τελευταίοι N χαρακτήρες εξάγονται από επιλεγμένα κελιά μαζικά.
Κάντε κλικ για να μάθετε περισσότερα σχετικά με αυτήν τη δυνατότητα.
Εάν θέλετε να έχετε μια δωρεάν δοκιμή (30-ημερών) αυτού του βοηθητικού προγράμματος, κάντε κλικ για να το κατεβάσετεκαι μετά πηγαίνετε για να εφαρμόσετε τη λειτουργία σύμφωνα με τα παραπάνω βήματα.
2. Εξαγωγή κειμένου πριν ή μετά από έναν συγκεκριμένο χαρακτήρα/λέξη
Για να εξαγάγετε κείμενο πριν ή μετά από έναν συγκεκριμένο χαρακτήρα ή λέξη, τα διαφορετικά σενάρια σε αυτήν την ενότητα θα καλύψουν τις ανάγκες σας.
2.1 Εξαγωγή κειμένου πριν ή μετά τον πρώτο οριοθέτη (ένα χαρακτήρα)
Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, για να εξαγάγετε κείμενο πριν ή μετά τον πρώτο οριοθέτη από κάθε κελί στην περιοχή B4:B10, μπορείτε να εφαρμόσετε μία από τις παρακάτω μεθόδους.
2.1.1 Εξαγωγή κειμένου πριν από τον πρώτο οριοθέτη με τύπο
Η εφαρμογή ενός τύπου που βασίζεται στις συναρτήσεις LEFT και FIND μπορεί να βοηθήσει στην εξαγωγή κειμένου πριν από τον πρώτο οριοθέτη από ένα κελί. Μπορείτε να ακολουθήσετε τα παρακάτω βήματα για να το κάνετε.
Γενική φόρμουλα
=LEFT(text_string,FIND("delimiter",text_string,1)-1)
Επιχειρήματα
Επιλέξτε ένα κενό κελί, αντιγράψτε ή εισαγάγετε τον παρακάτω τύπο σε αυτό και πατήστε το εισάγετε κλειδί για να πάρετε το πρώτο αποτέλεσμα. Επιλέξτε το πρώτο κελί αποτελέσματος και σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να λάβετε τα κείμενα πριν από τον πρώτο οριοθέτη άλλων κελιών.
=LEFT(B5,FIND("-",B5,1)-1)
2.1.2 Εξαγωγή κειμένου μετά τον πρώτο οριοθέτη με τύπο
Ο παρακάτω τύπος βοηθά στην εξαγωγή κειμένου μετά τον πρώτο οριοθέτη από ένα κελί στο Excel.
Γενική φόρμουλα
=MID(text_string,FIND("delimiter",text_string)+1,LEN(text_string))
Επιχειρήματα
=MID(B5,FIND("-",B5)+1,LEN(B5))
2.1.3 Εξαγωγή κειμένου πριν ή μετά τον πρώτο οριοθέτη με ένα καταπληκτικό εργαλείο
Εδώ συνιστά ανεπιφύλακτα το Εξαγωγή κειμένου χρησιμότητα του Kutools για το Excel. Με αυτήν τη δυνατότητα, μπορείτε εύκολα να εξαγάγετε κείμενα πριν ή μετά τον πρώτο οριοθέτη από μια σειρά κελιών μαζικά.
1. Επιλέξτε την περιοχή των κελιών όπου θέλετε να εξαγάγετε το κείμενο και, στη συνέχεια, κάντε κλικ Kutools > Κείμενο > Εξαγωγή κειμένου.
2. Στο Εξαγωγή κειμένου πλαίσιο διαλόγου, πρέπει να διαμορφώσετε ως εξής.
Σημείωση: Για να κάνετε το αποτέλεσμα δυναμικό όταν αλλάζει η συμβολοσειρά κειμένου, μπορείτε να επιλέξετε το πλαίσιο Εισαγωγή ως τύπος.
3. Τότε άλλο Εξαγωγή κειμένου Εμφανίζεται το παράθυρο διαλόγου, επιλέξτε ένα κελί για την έξοδο των αποτελεσμάτων και κάντε κλικ Εντάξει.
Στη συνέχεια, τα κείμενα πριν ή μετά τον πρώτο οριοθέτη εξάγονται από επιλεγμένα κελιά ταυτόχρονα.
Για να μάθετε περισσότερα σχετικά με αυτήν τη δυνατότητα, επισκεφτείτε: Γρήγορη εξαγωγή ορισμένου κειμένου από κελιά στο Excel.
Εάν θέλετε να έχετε μια δωρεάν δοκιμή (30-ημερών) αυτού του βοηθητικού προγράμματος, κάντε κλικ για να το κατεβάσετεκαι μετά πηγαίνετε για να εφαρμόσετε τη λειτουργία σύμφωνα με τα παραπάνω βήματα.
2.2 Εξαγωγή κειμένου πριν ή μετά τον τελευταίο οριοθέτη (έναν χαρακτήρα)
Στα παραπάνω βήματα μάθαμε τις μεθόδους εξαγωγής κειμένου πριν ή μετά τον πρώτο οριοθέτη από ένα κελί. Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, αυτή η ενότητα θα σας δείξει δύο τύπους για την εξαγωγή κειμένου πριν ή μετά τον τελευταίο οριοθέτη από ένα κελί. Μπορείτε να ακολουθήσετε τα παρακάτω βήματα για να το κάνετε.
2.2.1 Εξαγωγή κειμένου πριν από τον τελευταίο οριοθέτη με τύπο
Για να εξαγάγετε κείμενο πριν από τον τελευταίο οριοθέτη από ένα κελί, μπορείτε να χρησιμοποιήσετε τις συναρτήσεις SEARCH, LEN και SUBSTITUTE μέσα στη συνάρτηση LEFT.
Γενική φόρμουλα
=LEFT(text_string,SEARCH("#",SUBSTITUTE(text_string,"delimiter","#",LEN(text_string)-LEN(SUBSTITUTE(text_string,"delimiter",""))))-1)
Επιχειρήματα
Επιλέξτε ένα κελί, εισαγάγετε τον παρακάτω τύπο και πατήστε το εισάγετε κλειδί για το αποτέλεσμα. Επιλέξτε αυτό το κελί αποτελέσματος και σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να εξαγάγετε τα κείμενα από άλλες συμβολοσειρές κειμένου στην ίδια στήλη.
=LEFT(B5,SEARCH("#",SUBSTITUTE(B5,"-","#",LEN(B5)-LEN(SUBSTITUTE(B5,"-",""))))-1)
2.2.2 Εξαγωγή κειμένου μετά τον τελευταίο οριοθέτη με τύπο
Μετά την εξαγωγή κειμένου πριν από τον τελευταίο οριοθέτη από ένα κελί, μπορείτε να εφαρμόσετε τον παρακάτω τύπο για να εξαγάγετε το κείμενο μετά τον τελευταίο οριοθέτη όπως χρειάζεστε.
Γενική φόρμουλα
=RIGHT(text_string,LEN(text_string)-SEARCH("#",SUBSTITUTE(text_string,"delimiter","#",LEN(text_string)-LEN(SUBSTITUTE(text_string,"delimiter","")))))
Επιχειρήματα
Επιλέξτε ένα κελί, εισαγάγετε τον παρακάτω τύπο και πατήστε το εισάγετε κλειδί για το αποτέλεσμα. Επιλέξτε αυτό το κελί αποτελέσματος και σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να εξαγάγετε τα κείμενα από άλλες συμβολοσειρές κειμένου στην ίδια στήλη.
=RIGHT(B5,LEN(B5)-SEARCH("#",SUBSTITUTE(B5,"-","#",LEN(B5)-LEN(SUBSTITUTE(B5,"-","")))))
2.3 Εξαγωγή κειμένου μετά τον ν ο χαρακτήρας
Κοιτάξτε το παρακάτω παράδειγμα, υπάρχει μια λίστα με συμβολοσειρά κειμένου στην περιοχή B4:B10, για να εξαγάγετε το κείμενο μετά τον τρίτο χαρακτήρα από κάθε κελί, μπορείτε να εφαρμόσετε έναν τύπο που βασίζεται στη συνάρτηση MID και τη συνάρτηση LEN.
Γενική φόρμουλα
=MID(text_string,nth_char+1,LEN(text_string))
Επιχειρήματα
Επιλέξτε ένα κενό κελί, αντιγράψτε ή εισαγάγετε τον παρακάτω τύπο σε αυτό και πατήστε το εισάγετε κλειδί για το αποτέλεσμα. Επιλέξτε αυτό το κελί αποτελέσματος και σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να λάβετε άλλα αποτελέσματα.
=MID(B5,3+1,LEN(B5))
2.4 Εξαγωγή της νης λέξης από μια συμβολοσειρά κειμένου
Αν υποθέσουμε ότι έχετε μια λίστα με συμβολοσειρά κειμένου όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης και θέλετε να εξαγάγετε μόνο την ένατη λέξη από τη συμβολοσειρά κειμένου, αυτή η ενότητα παρέχει τρεις μεθόδους για να το κάνετε.
2.4.1 Εξαγωγή της νης λέξης με τον τύπο
Μπορείτε να συνδυάσετε τις συναρτήσεις TRIM, MID, SUBSTITUTE, REPT και LEN για να εξαγάγετε την ντη λέξη από μια συμβολοσειρά κειμένου σε ένα κελί.
Γενική φόρμουλα
=TRIM(MID(SUBSTITUTE(text_string," ",REPT(" ",LEN((text_string))), (N-1)*LEN((text_string)+1, LEN((text_string)))
Επιχειρήματα
Σε αυτήν την περίπτωση, το εύρος B5:B10 περιέχει τις συμβολοσειρές κειμένου, το D5:D10 περιέχει τους αριθμούς που αντιπροσωπεύουν την ντη λέξη, ας εφαρμόσουμε αυτόν τον τύπο για να εξαγάγουμε την nη λέξη από τη συμβολοσειρά κειμένου.
Επιλέξτε ένα κενό κελί, αντιγράψτε ή εισαγάγετε τον παρακάτω τύπο σε αυτό και πατήστε το εισάγετε κλειδί για να πάρετε το πρώτο αποτέλεσμα. Επιλέξτε αυτό το κελί αποτελέσματος και σύρετε τη λαβή Αυτόματης Συμπλήρωσης προς τα κάτω για να λάβετε την nη λέξη των άλλων κελιών.
=TRIM(MID(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))), (D5-1)*LEN(B5)+1, LEN(B5)))
Σημείωση: Μπορείτε να πληκτρολογήσετε απευθείας τον ντον αριθμό στον τύπο ως εξής.
=TRIM(MID(SUBSTITUTE(B5," ",REPT(" ",LEN(B5))), (2-1)*LEN(B5)+1, LEN(B5)))
2.4.2 Εξαγωγή της νης λέξης με συνάρτηση που ορίζεται από το χρήστη
Εκτός από τον παραπάνω τύπο, μπορείτε επίσης να εφαρμόσετε μια συνάρτηση που ορίζεται από το χρήστη για να εξαγάγετε την nη λέξη από ένα κελί στο Excel.
1. Πάτα το άλλος + F11 για να ανοίξετε το Microsoft Visual Basic για εφαρμογές παράθυρο.
2. Στο Microsoft Visual Basic για εφαρμογές παράθυρο, κάντε κλικ στην επιλογή Κύριο θέμα > Μονάδα μέτρησης, και μετά αντιγράψτε το VBA παρακάτω στο παράθυρο Κώδικας.
Κώδικας VBA: Εξαγωγή της νης λέξης από μια συμβολοσειρά κειμένου σε ένα κελί
Function ExtractTheNthWord(Source As String, Position As Integer)
'Update by Extendoffice 20211202
Dim arr() As String
arr = VBA.Split(Source, " ")
xCount = UBound(arr)
If xCount < 1 Or (Position - 1) > xCount Or Position < 0 Then
FindWord = ""
Else
FindWord = arr(Position - 1)
End If
End Function
3. Πάτα το άλλος + Q πλήκτρα για να κλείσετε το Microsoft Visual Basic για εφαρμογές παράθυρο.
4. Επιστρέψτε στο φύλλο εργασίας που περιέχει τις συμβολοσειρές κειμένου από τις οποίες θέλετε να εξαγάγετε την nη λέξη. Επιλέξτε ένα κενό κελί, αντιγράψτε ή εισαγάγετε τον παρακάτω τύπο σε αυτό και πατήστε το εισάγετε κλειδί για να πάρετε την ντη λέξη.
=FindWord(B5,D5)
Or
=FindWord(B5,2)
Σημείωση: στον τύπο, το D5 είναι το κελί που περιέχει έναν αριθμό που αντιπροσωπεύει την ντη λέξη. Εναλλακτικά, μπορείτε να αντικαταστήσετε απευθείας την αναφορά κελιού με έναν αριθμό.
5. Επιλέξτε το κελί του αποτελέσματος και σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να εξαγάγετε την nη λέξη από τις συμβολοσειρές κειμένου άλλων κελιών.
2.4.3 Εξαγωγή της νης λέξης με ένα καταπληκτικό εργαλείο
Εάν δεν θέλετε να εφαρμόσετε με μη αυτόματο τρόπο έναν τύπο ή μια συνάρτηση που ορίζεται από το χρήστη που παρέχεται παραπάνω, εδώ προτείνουμε τα Kutools για το Excel Εξαγάγετε την nth λέξη στο κελί χρησιμότητα. Με αυτήν τη δυνατότητα, μπορείτε εύκολα να εξαγάγετε την nη λέξη από μια συμβολοσειρά κειμένου σε ένα κελί με λίγα μόνο κλικ.
1. Επιλέξτε ένα κελί για να τοποθετήσετε το αποτέλεσμα και κάντε κλικ Kutools > Βοηθός τύπου > Κείμενο > Εκχύλισμα η ντη λέξη στο κελί. Δείτε το στιγμιότυπο οθόνης:
2. Στο Βοηθός τύπων πλαίσιο διαλόγου, πρέπει να διαμορφώσετε ως εξής.
3. Στη συνέχεια εξάγεται η ντη (δεύτερη) λέξη από τη συμβολοσειρά κειμένου στο κελί B5 και μπορείτε να δείτε ότι δημιουργείται ένας τύπος ταυτόχρονα. Επιλέξτε αυτό το κελί αποτελέσματος και σύρετε τη λαβή Αυτόματης Συμπλήρωσης προς τα κάτω για να λάβετε την nη λέξη από άλλες συμβολοσειρές κειμένου.
Κάντε κλικ για να μάθετε περισσότερα σχετικά με αυτήν τη δυνατότητα.
Εάν θέλετε να έχετε μια δωρεάν δοκιμή (30-ημερών) αυτού του βοηθητικού προγράμματος, κάντε κλικ για να το κατεβάσετεκαι μετά πηγαίνετε για να εφαρμόσετε τη λειτουργία σύμφωνα με τα παραπάνω βήματα.
2.5 Εξαγωγή κειμένου πριν ή μετά την ένατη εμφάνιση ενός οριοθέτη
Ας υποθέσουμε ότι έχετε μια λίστα με συμβολοσειρές κειμένου όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης. Για να εξαγάγετε το κείμενο πριν ή μετά τη δεύτερη εμφάνιση ενός διαστήματος, αυτή η ενότητα παρέχει δύο τύπους που θα σας βοηθήσουν να το ολοκληρώσετε.
2.5.1 Εξαγωγή κειμένου πριν από την ένατη εμφάνιση ενός οριοθέτη
Μπορείτε να χρησιμοποιήσετε τη συνάρτηση LEFT μαζί με τις συναρτήσεις SUBSTITUTE και FIND για να εξαγάγετε κείμενο πριν από την nη εμφάνιση ενός οριοθέτη από ένα κελί στο Excel.
Γενική φόρμουλα
=LEFT(SUBSTITUTE(text_string,"delimiter",CHAR(9),n),FIND(CHAR(9),SUBSTITUTE(text_string,"delimiter",CHAR(9),n),1)-1)
Επιχειρήματα
Επιλέξτε ένα κελί, αντιγράψτε ή εισαγάγετε τον παρακάτω τύπο και πατήστε το εισάγετε κλειδί για το αποτέλεσμα. Επιλέξτε αυτό το κελί αποτελέσματος και σύρετέ το Χειρισμός Αυτόματης Συμπλήρωσης προς τα κάτω για να λάβετε άλλα αποτελέσματα στη λίστα.
=LEFT(SUBSTITUTE(B5," ",CHAR(9),2),FIND(CHAR(9),SUBSTITUTE(B5," ",CHAR(9),2),1)-1)
Σημείωση: Στον τύπο, το B5 είναι το κελί που περιέχει τη συμβολοσειρά κειμένου από την οποία θέλετε να εξαγάγετε το κείμενο. Το " " εδώ αντιπροσωπεύει ένα διάστημα και ο αριθμός 2 αντιπροσωπεύει τη δεύτερη εμφάνιση ενός διαστήματος. Μπορείτε να τα αλλάξετε ανάλογα με τις ανάγκες σας.
2.5.2 Εξαγωγή κειμένου μετά την ένατη εμφάνιση ενός οριοθέτη
Για να εξαγάγετε κείμενο μετά την ντη εμφάνιση ενός οριοθέτη, μπορείτε να εφαρμόσετε τη συνάρτηση RIGHT με τις συναρτήσεις SUBSTITUTE, LEN και FIND.
Γενική φόρμουλα
=RIGHT(SUBSTITUTE(text_string, "delimiter", CHAR(9), n), LEN(text_string)- FIND(CHAR(9), SUBSTITUTE(text_string, "delimiter", CHAR(9), n), 1) + 1)
Επιχειρήματα
Τώρα μπορείτε να εφαρμόσετε αυτόν τον τύπο για να εξαγάγετε το κείμενο μετά τη δεύτερη εμφάνιση του χώρου από κάθε κελί στην περιοχή B5:B10 ως εξής.
Επιλέξτε ένα κελί, εισαγάγετε τον παρακάτω τύπο και πατήστε το εισάγετε κλειδί για το αποτέλεσμα. Επιλέξτε αυτό το κελί αποτελέσματος και σύρετέ το Χειρισμός Αυτόματης Συμπλήρωσης προς τα κάτω για να λάβετε άλλα αποτελέσματα.
=RIGHT(SUBSTITUTE(B5, " ", CHAR(9), 2), LEN(B5)- FIND(CHAR(9), SUBSTITUTE(B5, " ", CHAR(9), 2), 1) + 1)
2.6 Εξαγωγή κειμένου πριν ή μετά την αλλαγή γραμμής
Ας υποθέσουμε ότι έχετε μια λίστα παραγγελιών στη στήλη Β και θέλετε να εξαγάγετε μόνο το τμήμα ημερομηνίας και το τμήμα Αρ. προϊόντος από κάθε κελί. Μπορείτε να χρησιμοποιήσετε τους παρακάτω τύπους Excel για να το κάνετε.
2.6.1 Εξαγωγή κειμένου πριν από την πρώτη αλλαγή γραμμής με τύπο
Όπως μπορείτε να δείτε στο παραπάνω στιγμιότυπο οθόνης, το τμήμα ημερομηνίας εντοπίζεται πριν από την πρώτη αλλαγή γραμμής μέσα στο κελί. Αυτή η ενότητα θα δείξει μια συνάρτηση ΑΡΙΣΤΕΡΑ μαζί με τη συνάρτηση SEARCH για να σας βοηθήσει να εξαγάγετε το κείμενο πριν από την πρώτη αλλαγή γραμμής σε ένα κελί.
Γενική φόρμουλα
=LEFT(cell, SEARCH(CHAR(10), cell)-1)
Επιχειρήματα
Επιλέξτε ένα κενό κελί, αντιγράψτε ή εισαγάγετε τον παρακάτω τύπο σε αυτό και πατήστε το εισάγετε κλειδί για το αποτέλεσμα. Επιλέξτε αυτό το κελί αποτελέσματος και, στη συνέχεια, σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να εφαρμόσετε αυτόν τον τύπο σε άλλα κελιά.
=LEFT(B5, SEARCH(CHAR(10), B5)-1)
Στη συνέχεια, μπορείτε να δείτε το κείμενο πριν από την εξαγωγή της πρώτης αλλαγής γραμμής σε κάθε κελί στην περιοχή B5:B8, όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης.
Σημείωση: Στον τύπο, το CHAR(10) αντιπροσωπεύει μια αλλαγή γραμμής στα Windows.
2.6.2 Εξαγωγή κειμένου μετά την τελευταία αλλαγή γραμμής με τον τύπο
Στο προηγούμενο βήμα, μιλήσαμε για τον τρόπο εξαγωγής κειμένου πριν από την πρώτη αλλαγή γραμμής σε ένα κελί. Και αυτό το μέρος θα σας καθοδηγήσει πώς να εξαγάγετε κείμενο μετά την τελευταία αλλαγή γραμμής σε ένα κελί με διαφορετικό τύπο.
Γενική φόρμουλα
=TRIM(RIGHT(SUBSTITUTE(cell,CHAR(10),REPT(" ",200)),200))
Επιχειρήματα
Επιλέξτε ένα κενό κελί, εισαγάγετε τον παρακάτω τύπο και πατήστε το εισάγετε κλειδί για το αποτέλεσμα. Επιλέξτε αυτό το κελί αποτελέσματος και, στη συνέχεια, σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να εφαρμόσετε τον τύπο σε άλλα κελιά.
=TRIM(RIGHT(SUBSTITUTE(B5,CHAR(10),REPT(" ",200)),200))
Στη συνέχεια το προϊόν αρ. μέρος κάθε κελιού στη λίστα εξάγεται όπως φαίνεται στο παραπάνω στιγμιότυπο οθόνης.
Σημείωση: Στον τύπο, το CHAR(10) αντιπροσωπεύει μια αλλαγή γραμμής στα Windows.
2.7 Εξαγωγή κειμένου πριν ή μετά από μια λέξη
Στα προηγούμενα μέρη, μάθαμε πώς να εξάγουμε κείμενο πριν ή μετά από έναν χαρακτήρα ή οριοθέτη. Τι πρέπει να κάνετε για να εξαγάγετε κείμενο πριν ή μετά από μια ολόκληρη λέξη; Αυτή η ενότητα θα παρουσιάσει τρεις μεθόδους που θα σας βοηθήσουν να ολοκληρώσετε αυτήν την εργασία.
2.7.1 Εξαγωγή κειμένου πριν από μια συγκεκριμένη λέξη με τύπο
Ο ακόλουθος τύπος σάς βοηθά να εξαγάγετε κείμενο πριν από μια συγκεκριμένη λέξη σε ένα κελί στο Excel.
Γενική φόρμουλα
=IFERROR(LEFT(cell,FIND(word,cell)-1),cell)
Επιχειρήματα
Επιλέξτε ένα κενό κελί, εισαγάγετε τον παρακάτω τύπο και πατήστε το εισάγετε κλειδί για το αποτέλεσμα. Επιλέξτε αυτό το κελί αποτελέσματος και, στη συνέχεια, σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να εφαρμόσετε αυτόν τον τύπο σε άλλα κελιά.
Σε αυτό το παράδειγμα, πρόκειται να εξαγάγουμε όλα τα κείμενα πριν από τη λέξη "Excel", επομένως πληκτρολογούμε απευθείας τη λέξη στον τύπο και την περικλείουμε σε διπλά εισαγωγικά. Ή μπορείτε να αναφερθείτε σε ένα κελί που περιέχει τη λέξη "Excel".
=IFERROR(LEFT(B5,FIND("Excel",B5)-1),B5)
:
2.7.2 Εξαγωγή κειμένου μετά από μια συγκεκριμένη λέξη με τύπο
Για να εξαγάγετε κείμενο μετά από μια συγκεκριμένη λέξη, μπορείτε να εφαρμόσετε τον ακόλουθο τύπο για να το κάνετε.
Γενική φόρμουλα
=TRIM(MID(cell,SEARCH(word,cell)+LEN(word),255))
Επιχειρήματα
Επιλέξτε ένα κελί, εισαγάγετε τον παρακάτω τύπο και πατήστε το εισάγετε κλειδί για να πάρετε το αποτέλεσμα. Επιλέξτε το κελί του αποτελέσματος και, στη συνέχεια, σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να εφαρμόσετε αυτόν τον τύπο σε άλλα κελιά.
=TRIM(MID(B5,SEARCH("Excel",B5)+LEN("Excel"),255))
Στη συνέχεια, μπορείτε να δείτε όλα τα κείμενα μετά την εξαγωγή της λέξης "Excel" σε κάθε κελί, όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης.
:
2.7.3 Εξαγωγή κειμένου πριν ή μετά από μια συγκεκριμένη λέξη με ένα καταπληκτικό εργαλείο
Εάν πιστεύετε ότι η χρήση της φόρμουλας μπορεί να προκαλέσει μεγάλη ταλαιπωρία, σας προτείνουμε ανεπιφύλακτα το Εξαγωγή κειμένου χρησιμότητα του Kutools για Excel. Αυτή η δυνατότητα βοηθά στην αυτοματοποίηση της εργασίας εξαγωγής στο Excel με λίγα μόνο κλικ.
1. κλικ Kutools > Κείμενο > Εξαγωγή κειμένου για να ενεργοποιήσετε αυτήν τη λειτουργία.
2. Στο Εξαγωγή κειμένου πλαίσιο διαλόγου, κάντε τις ακόλουθες ρυθμίσεις.
: Εάν θέλετε να δημιουργήσετε δυναμικά αποτελέσματα, ελέγξτε το Εισαγωγή ως τύπος κουτί. Στη συνέχεια, τα αποτελέσματα θα ενημερωθούν αυτόματα όταν αλλάξουν τα δεδομένα στο εύρος.
3. Στη συνέχεια ένα Εξαγωγή κειμένου εμφανίζεται το παράθυρο διαλόγου, πρέπει να επιλέξετε ένα κελί για την έξοδο του αποτελέσματος και, στη συνέχεια, να κάνετε κλικ στο OK κουμπί.
Στη συνέχεια, τα κείμενα πριν ή μετά από μια συγκεκριμένη λέξη σε κάθε κελί στην επιλεγμένη περιοχή εξάγονται αμέσως.
Σημείωση: Αυτή η δυνατότητα είναι διάκριση πεζών-κεφαλαίων.
Κάντε κλικ για να μάθετε περισσότερα σχετικά με αυτήν τη δυνατότητα.
Εάν θέλετε να έχετε μια δωρεάν δοκιμή (30-ημερών) αυτού του βοηθητικού προγράμματος, κάντε κλικ για να το κατεβάσετεκαι μετά πηγαίνετε για να εφαρμόσετε τη λειτουργία σύμφωνα με τα παραπάνω βήματα.
3. Εξαγωγή μεταξύ χαρακτήρων/λέξεων
Εάν θέλετε να εξαγάγετε κείμενο μεταξύ συγκεκριμένων χαρακτήρων ή λέξεων, δοκιμάστε τις ακόλουθες μεθόδους.
3.1 Εξαγωγή κειμένου μεταξύ δύο χαρακτήρων
Για να εξαγάγετε κείμενο μεταξύ δύο χαρακτήρων, οι οποίοι μπορεί να είναι ίδιοι ή διαφορετικοί χαρακτήρες. Αυτή η ενότητα παρέχει διάφορες μεθόδους και μπορείτε να επιλέξετε μία από αυτές ανάλογα με τις ανάγκες σας.
3.1.1 Εξαγωγή κειμένου μεταξύ δύο ίδιων χαρακτήρων με τύπο
Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, υπάρχει μια λίστα με συμβολοσειρές κειμένου στη στήλη Β και θέλετε να εξαγάγετε το αριθμητικό τμήμα μεταξύ των χαρακτήρων "/" από κάθε κελί της περιοχής, ο ακόλουθος τύπος μπορεί να σας κάνει τη χάρη.
Επιλέξτε ένα κενό κελί, αντιγράψτε ή εισαγάγετε τον παρακάτω τύπο και πατήστε το εισάγετε κλειδί για να πάρετε το αποτέλεσμα. Επιλέξτε το κελί του αποτελέσματος και, στη συνέχεια, σύρετέ το AutoFill Handle προς τα κάτω για να λάβετε αποτελέσματα άλλων κελιών στη λίστα.
=SUBSTITUTE(MID(SUBSTITUTE("/" & B5&REPT(" ",6),"/",REPT(",",255)),2*255,255),",","")
Στη συνέχεια, το κείμενο μεταξύ δύο ίδιων χαρακτήρων "/" εξάγεται από κάθε κελί της περιοχής. Δείτε στιγμιότυπο οθόνης:
Σημείωση:
3.1.2 Εξαγωγή κειμένου μεταξύ δύο διαφορετικών χαρακτήρων με τύπο
Αφού μάθουμε πώς να εξάγετε κείμενο μεταξύ δύο ίδιων χαρακτήρων σε ένα κελί, εδώ θα παρουσιάσουμε έναν τύπο για την εξαγωγή κειμένου μεταξύ δύο διαφορετικών χαρακτήρων. Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, για να εξαγάγετε μόνο τη διεύθυνση email μεταξύ των "<" και ">" από κάθε κελί στη στήλη Β, μπορείτε να κάνετε τα εξής.
Γενική φόρμουλα
=MID(LEFT(cel,FIND("end_char",cell)-1),FIND("start_char",cell)+1,LEN(cell))
Επιχειρήματα
Επιλέξτε ένα κενό κελί, αντιγράψτε ή εισαγάγετε τον παρακάτω τύπο και πατήστε το εισάγετε κλειδί για το αποτέλεσμα. Επιλέξτε αυτό το κελί αποτελέσματος και, στη συνέχεια, σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να εφαρμόσετε αυτόν τον τύπο σε άλλα κελιά.
=MID(LEFT(B5,FIND(">",B5)-1),FIND("<",B5)+1,LEN(B5))
Μπορείτε να δείτε ότι εξάγεται μόνο το κείμενο μεταξύ των καθορισμένων χαρακτήρων όπως φαίνεται στο παραπάνω στιγμιότυπο οθόνης.
3.1.3 Εξαγωγή κειμένου μεταξύ δύο χαρακτήρων με ένα καταπληκτικό εργαλείο
Εδώ συνιστά ανεπιφύλακτα το Εξαγωγή συμβολοσειρών μεταξύ καθορισμένου κειμένου χαρακτηριστικό του Kutools για Excel για να σας βοηθήσει να εξάγετε εύκολα κείμενο μεταξύ δύο ίδιων ή διαφορετικών χαρακτήρων σε ένα κελί στο Excel.
1. Επιλέξτε ένα κενό κελί για έξοδο του αποτελέσματος και, στη συνέχεια, κάντε κλικ στο Kutools > Βοηθός τύπου > Βοηθός τύπου.
2. Στο Βοηθός τύπων πλαίσιο διαλόγου, κάντε τις ακόλουθες ρυθμίσεις.
3. Στη συνέχεια εξάγεται μόνο το κείμενο μεταξύ "<" και ">" μέσα στο κελί B5. Εν τω μεταξύ, έχει δημιουργηθεί ένας τύπος, μπορείτε να επιλέξετε αυτό το κελί αποτελέσματος και στη συνέχεια να σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να εξαγάγετε κείμενα από άλλα κελιά της ίδιας λίστας.
Κάντε κλικ για να μάθετε περισσότερα σχετικά με αυτήν τη δυνατότητα.
Εάν θέλετε να έχετε μια δωρεάν δοκιμή (30-ημερών) αυτού του βοηθητικού προγράμματος, κάντε κλικ για να το κατεβάσετεκαι μετά πηγαίνετε για να εφαρμόσετε τη λειτουργία σύμφωνα με τα παραπάνω βήματα.
3.1.4 Εξαγωγή κειμένου μεταξύ δύο χαρακτήρων (συμπεριλαμβανομένων των χαρακτήρων) κατά κανόνα
Εάν θέλετε να διατηρήσετε τους δύο χαρακτήρες μετά την εξαγωγή, προσπαθήστε να εφαρμόσετε έναν κανόνα στη δυνατότητα εξαγωγής κειμένου του Kutools για Excel.
1. κλικ Kutools > Κείμενο > Εξαγωγή κειμένου.
2. Στο Εξαγωγή κειμένου πλαίσιο διαλόγου, κάντε τις ακόλουθες ρυθμίσεις.
3. Ένα άλλο Εξαγωγή κειμένου εμφανίζεται το παράθυρο διαλόγου, επιλέξτε ένα κελί για την έξοδο του αποτελέσματος και, στη συνέχεια, κάντε κλικ στο OK κουμπί.
Στη συνέχεια, το κείμενο μεταξύ καθορισμένων χαρακτήρων (συμπεριλαμβανομένων των χαρακτήρων) εξάγεται μαζικά από κάθε κελί στην επιλεγμένη περιοχή.
Εάν θέλετε να έχετε μια δωρεάν δοκιμή (30-ημερών) αυτού του βοηθητικού προγράμματος, κάντε κλικ για να το κατεβάσετεκαι μετά πηγαίνετε για να εφαρμόσετε τη λειτουργία σύμφωνα με τα παραπάνω βήματα.
3.2 Εξαγωγή κειμένου μεταξύ δύο λέξεων
Εκτός από την εξαγωγή κειμένου μεταξύ δύο χαρακτήρων, μπορεί επίσης να χρειαστεί να εξαγάγετε κείμενο μεταξύ δύο λέξεων. Για παράδειγμα, εξαγάγετε όλες τις συμβολοσειρές κειμένου μεταξύ δύο λέξεων "KTE" και "feature" από κάθε κελί της στήλης Β όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης. Μπορείτε να δοκιμάσετε μία από τις παρακάτω μεθόδους για να το κάνετε.
3.2.1 Εξαγωγή κειμένου μεταξύ δύο λέξεων με τύπο
Μπορείτε να χρησιμοποιήσετε έναν τύπο που βασίζεται στη συνάρτηση MID και στη συνάρτηση SEARCH για να εξαγάγετε όλες τις συμβολοσειρές κειμένου μεταξύ δύο λέξεων σε ένα κελί.
Γενική φόρμουλα
=MID(cell,SEARCH("start_word",cell)+3,SEARCH("end_word",cell)-SEARCH("start_word",cell)-4)
Επιχειρήματα
Επιλέξτε ένα κενό κελί, αντιγράψτε ή εισαγάγετε τον παρακάτω τύπο και πατήστε το εισάγετε κλειδί για το αποτέλεσμα. Επιλέξτε αυτό το κελί αποτελέσματος και, στη συνέχεια, σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να εφαρμόσετε αυτόν τον τύπο σε άλλα κελιά.
=MID(B5,SEARCH("KTE",B5)+3,SEARCH("feature",B5)-SEARCH("KTE",B5)-4)
Note: Στον τύπο, ο αριθμός 3 αντιπροσωπεύει το μήκος χαρακτήρων της λέξης "KTE". ο αριθμός 4 αντιπροσωπεύει το μήκος χαρακτήρων της λέξης "KTE" συν 1.
Μπορείτε να δείτε ότι όλες οι συμβολοσειρές κειμένου μεταξύ των δύο καθορισμένων λέξεων εξάγονται από κάθε κελί στη στήλη Β.
3.2.2 Εξαγωγή κειμένου μεταξύ δύο λέξεων με ένα καταπληκτικό εργαλείο
Για πολλούς χρήστες του Excel, οι τύποι μπορεί να είναι δύσκολο να θυμούνται και να χειρίζονται. Εδώ, με το Εξαγωγή συμβολοσειρών μεταξύ καθορισμένου κειμένου χαρακτηριστικό του Kutools για Excel, μπορείτε εύκολα να εξαγάγετε κείμενο μεταξύ δύο λέξεων με λίγα μόνο κλικ.
1. Επιλέξτε ένα κελί για την έξοδο του αποτελέσματος και, στη συνέχεια, κάντε κλικ Kutools > Βοηθός τύπου > Βοηθός τύπου.
2. Στο Βοηθός τύπου πλαίσιο διαλόγου, πρέπει να διαμορφώσετε ως εξής.
3. Στη συνέχεια εξάγονται όλες οι συμβολοσειρές κειμένου μεταξύ δύο λέξεων "KTE" και "feature" μέσα στο κελί B5. Εν τω μεταξύ, έχει δημιουργηθεί ένας τύπος, μπορείτε να επιλέξετε αυτό το κελί αποτελέσματος και, στη συνέχεια, να σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να εξαγάγετε κείμενα από άλλα κελιά της ίδιας λίστας.
Εάν θέλετε να έχετε μια δωρεάν δοκιμή (30-ημερών) αυτού του βοηθητικού προγράμματος, κάντε κλικ για να το κατεβάσετεκαι μετά πηγαίνετε για να εφαρμόσετε τη λειτουργία σύμφωνα με τα παραπάνω βήματα.
Εξαγωγή αριθμών ανά θέση
Για μια λίστα αλφαριθμητικών συμβολοσειρών, μπορεί να υπάρχουν τρεις περιπτώσεις:
- Ο αριθμός βρίσκεται στην αρχή του κειμένου;
- Ο αριθμός βρίσκεται στο τέλος του κειμένου;
- Ο αριθμός μπορεί να είναι οπουδήποτε στο κείμενο.
Σε αυτήν την ενότητα, θα παρέχουμε διαφορετικές μεθόδους που μπορούν να χρησιμοποιηθούν για την εξαγωγή των αριθμών σε κάθε περίπτωση που αναφέρθηκε παραπάνω.
1 Εξαγωγή αριθμού από τα αριστερά μιας συμβολοσειράς
Αυτό το μέρος θα εισάγει έναν τύπο που θα σας βοηθήσει να εξαγάγετε μόνο αριθμούς που εμφανίζονται πριν από το κείμενο σε ένα κελί.
Γενική φόρμουλα
=LEFT(cell, MATCH(FALSE, ISNUMBER(MID(cell, ROW(INDIRECT("1:"&LEN(cell)+1)), 1) *1), 0) -1)
Επιχειρήματα
Σημείωση:
Επιλέξτε ένα κενό κελί, εισαγάγετε τον παρακάτω τύπο και πατήστε Ctrl + αλλαγή + εισάγετε or εισάγετε κλειδί για το αποτέλεσμα. Επιλέξτε αυτό το κελί αποτελέσματος και, στη συνέχεια, σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να λάβετε αριθμούς άλλων κελιών.
=LEFT(B5, MATCH(FALSE, ISNUMBER(MID(B5, ROW(INDIRECT("1:"&LEN(B5)+1)), 1) *1), 0) -1)
:
2 Εξαγωγή αριθμού από τα δεξιά μιας συμβολοσειράς
Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, για να εξαγάγετε μόνο τους αριθμούς που εμφανίζονται μετά το κείμενο σε ένα κελί, δοκιμάστε τον ακόλουθο τύπο.
Γενική φόρμουλα
=RIGHT(cell, LEN(cell) - MAX(IF(ISNUMBER(MID(cell, ROW(INDIRECT("1:"&LEN(cell))), 1) *1)=FALSE, ROW(INDIRECT("1:"&LEN(cell))), 0)))
Επιχειρήματα
Σημείωση:
Επιλέξτε ένα κενό κελί, εισαγάγετε τον παρακάτω τύπο και πατήστε Ctrl + αλλαγή + εισάγετε or εισάγετε κλειδί για το αποτέλεσμα. Επιλέξτε αυτό το κελί αποτελέσματος και, στη συνέχεια, σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να λάβετε αριθμούς άλλων κελιών.
=RIGHT(B5, LEN(B5) - MAX(IF(ISNUMBER(MID(B5, ROW(INDIRECT("1:"&LEN(B5))), 1) *1)=FALSE, ROW(INDIRECT("1:"&LEN(B5))), 0)))
:
3. Εξάγετε όλους τους αριθμούς από οποιαδήποτε θέση σε μια συμβολοσειρά κειμένου
Οι παραπάνω μέθοδοι βοηθούν στην εξαγωγή αριθμού μόνο από τα αριστερά ή τα δεξιά μιας συμβολοσειράς κειμένου. Εάν θέλετε να εξαγάγετε όλους τους αριθμούς από οπουδήποτε σε μια συμβολοσειρά κειμένου, εδώ παρέχουμε τρεις μεθόδους για να το κάνετε.
3.1 Εξαγωγή όλων των αριθμών από οπουδήποτε σε μια συμβολοσειρά με τύπο
Μπορείτε να εφαρμόσετε τον ακόλουθο τύπο για να εξαγάγετε όλους τους αριθμούς από οπουδήποτε σε μια συμβολοσειρά κειμένου στο Excel.
1. Επιλέξτε ένα κενό κελί, αντιγράψτε ή εισαγάγετε τον παρακάτω τύπο και πατήστε το εισάγετε κλειδί για να λάβετε όλους τους αριθμούς από το κελί B5.
=SUMPRODUCT(MID(0&B5, LARGE(INDEX(ISNUMBER(--MID(B5, ROW(INDIRECT("1:"&LEN(B5))), 1)) * ROW(INDIRECT("1:"&LEN(B5))), 0), ROW(INDIRECT("1:"&LEN(B5))))+1, 1) * 10^ROW(INDIRECT("1:"&LEN(B5)))/10)
2. Επιλέξτε το κελί του αποτελέσματος και, στη συνέχεια, σύρετε τη λαβή Αυτόματης Συμπλήρωσης προς τα κάτω για να λάβετε όλους τους αριθμούς των άλλων κελιών.
3.2 Εξαγωγή όλων των αριθμών από οπουδήποτε σε μια συμβολοσειρά με VBA
Ο παραπάνω τύπος είναι πολύ μεγάλος και περίπλοκος για πολλούς χρήστες του Excel. Στην πραγματικότητα, μπορείτε να εκτελέσετε μια δέσμη ενεργειών VBA για να αυτοματοποιήσετε την εργασία στο Excel. Μπορείτε να κάνετε ως εξής.
1. Πάτα το άλλος + F11 για να ανοίξετε το Microsoft Visual Basic για εφαρμογές παράθυρο.
2. Στο άνοιγμα Microsoft Visual Basic για εφαρμογές παράθυρο, κάντε κλικ στην επιλογή Κύριο θέμα > Μονάδα μέτρησης. Στη συνέχεια, αντιγράψτε το VBA παρακάτω στο παράθυρο κώδικα μονάδας.
Κώδικας VBA: Εξαγωγή όλων των αριθμών από οπουδήποτε σε μια συμβολοσειρά κειμένου
Sub ExtrNumbersFromRange()
'Updated by Extendoffice 20220106
Dim xRg As Range
Dim xDRg As Range
Dim xRRg As Range
Dim nCellLength As Integer
Dim xNumber As Integer
Dim strNumber As String
Dim xTitleId As String
Dim xI As Integer
xTitleId = "KutoolsforExcel"
Set xDRg = Application.InputBox("Please select text strings:", xTitleId, "", Type:=8)
If TypeName(xDRg) = "Nothing" Then Exit Sub
Set xRRg = Application.InputBox("Please select output cell:", xTitleId, "", Type:=8)
If TypeName(xRRg) = "Nothing" Then Exit Sub
xI = 0
strNumber = ""
For Each xRg In xDRg
xI = xI + 1
nCellLength = Len(xRg)
For xNumber = 1 To nCellLength
If IsNumeric(Mid(xRg, xNumber, 1)) Then
strNumber = strNumber & Mid(xRg, xNumber, 1)
End If
Next xNumber
xRRg.Item(xI) = strNumber
strNumber = ""
Next xRg
End Sub
3. Πάτα το F5 κλειδί για την εκτέλεση του κώδικα. Στο άνοιγμα KutoolsforExcel στο παράθυρο διαλόγου, επιλέξτε την περιοχή των κελιών όπου θέλετε να εξαγάγετε όλους τους αριθμούς από κάθε κελί και, στη συνέχεια, κάντε κλικ στο OK κουμπί.
4. Τότε άλλο KutoolsforExcel εμφανίζεται το παράθυρο διαλόγου. Σε αυτό το παράθυρο διαλόγου, επιλέξτε ένα κελί προορισμού και κάντε κλικ Εντάξει.
Στη συνέχεια, όλοι οι αριθμοί εξάγονται μαζικά από κάθε κελί στην επιλεγμένη περιοχή.
4. Εξαγωγή αριθμών μετά από συγκεκριμένο κείμενο
Όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης, για να εξαγάγετε τυχόν αριθμούς μετά το συγκεκριμένο κείμενο "No.", αυτή η ενότητα παρέχει δύο μεθόδους που θα σας βοηθήσουν να το κάνετε.
4.1 Εξαγωγή αριθμών μετά από συγκεκριμένο κείμενο με τύπο
Μπορείτε να εφαρμόσετε τον ακόλουθο τύπο για την εξαγωγή αριθμών μετά από ένα συγκεκριμένο κείμενο σε ένα κελί στο Excel.
Γενικός τύπος:
=LOOKUP(10^6,1*MID(cell,MIN(FIND({0,1,2,3,4,5,6,7,8,9},cell&"0123456789",FIND("text"," "&cell&" "))),{2,3,4,5,6}))
Επιχειρήματα
Επιλέξτε ένα κενό κελί, αντιγράψτε ή εισαγάγετε τον παρακάτω τύπο και πατήστε το εισάγετε κλειδί για το αποτέλεσμα. Επιλέξτε αυτό το κελί αποτελέσματος και, στη συνέχεια, σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να εφαρμόσετε αυτόν τον τύπο σε άλλα κελιά.
=LOOKUP(10^6,1*MID(B5,MIN(FIND({0,1,2,3,4,5,6,7,8,9},B5&"0123456789",FIND("No."," "&B5&" "))),{2,3,4,5,6}))
:
4.2 Εξαγωγή αριθμών μετά από ένα συγκεκριμένο κείμενο με λειτουργία που καθορίζεται από το χρήστη
Η ακόλουθη συνάρτηση που ορίζεται από το χρήστη μπορεί επίσης να βοηθήσει στην εξαγωγή αριθμών μετά από ένα συγκεκριμένο κείμενο σε ένα κελί. Παρακαλώ κάντε τα εξής.
1. Πάτα το άλλος + F11 για να ανοίξετε το Microsoft Visual Basic για εφαρμογές παράθυρο.
2. Στο Microsoft Visual Basic για εφαρμογές παράθυρο, κάντε κλικ στην επιλογή Κύριο θέμα > Μονάδα μέτρησης, και, στη συνέχεια, αντιγράψτε τον παρακάτω κώδικα VBA στο παράθυρο κώδικα μονάδας.
Κωδικός VBA: εξαγωγή αριθμών μετά από ένα συγκεκριμένο κείμενο σε ένα κελί
Function GetNumberAfterTheChar(Rng As Range, Char As String)
'Updated by Extendoffice 20220106
Dim xValue As String
Dim xRntString As String
Dim xStart As Integer
Dim xC
xValue = Rng.Text
xStart = InStr(1, xValue, Char, vbTextCompare)
If IsEmpty(xStart) Then
GetNumberAfterTheChar = ""
Exit Function
End If
If xStart < 1 Then
GetNumberAfterTheChar = ""
Exit Function
End If
xStart = xStart - 1 + Len(Char)
If xStart < 1 Then
GetNumberAfterTheChar = ""
Exit Function
End If
xValue = Mid(xValue, xStart + 1)
xRntString = ""
For xI = 1 To Len(xValue)
xC = Mid(xValue, xI, 1)
Select Case Asc(xC)
Case 48 To 57
xRntString = xRntString & xC
Case Else
Exit For
End Select
Next
GetNumberAfterTheChar = xRntString
End Function
3. Πάτα το άλλος + Q πλήκτρα για να κλείσετε το Microsoft Visual Basic για εφαρμογές παράθυρο.
4. Επιλέξτε ένα κελί, εισαγάγετε τον παρακάτω τύπο και πατήστε το εισάγετε κλειδί. Επιλέξτε αυτό το κελί αποτελέσματος και, στη συνέχεια, σύρετε τη λαβή αυτόματης συμπλήρωσης προς τα κάτω για να εφαρμόσετε αυτόν τον τύπο σε άλλα κελιά.
=GetNumberAfterTheChar(B5,"No. ")
:
Σχετικά άρθρα:
Εκμάθηση Excel: Διαχωρισμός κελιών κειμένου, αριθμού και ημερομηνίας (διαχωρισμός σε πολλές στήλες)
Αυτό το σεμινάριο χωρίζεται σε τρία μέρη: διαίρεση κελιών κειμένου, διαχωρισμό κελιών αριθμού και διαχωρισμό κελιών ημερομηνίας. Κάθε τμήμα παρέχει διαφορετικά παραδείγματα για να σας βοηθήσει να μάθετε πώς να χειρίζεστε την εργασία διαχωρισμού όταν αντιμετωπίζετε το ίδιο πρόβλημα.
Κάντε κλικ για να μάθετε περισσότερα ...
Excel Προσθήκη κειμένου και αριθμού σε καθορισμένη θέση κελιού
Στο Excel, η προσθήκη κειμένων ή αριθμών σε κελιά είναι μια πολύ συνηθισμένη εργασία. Όπως η προσθήκη διαστήματος μεταξύ των ονομάτων, η προσθήκη προθέματος ή επιθήματος σε κελιά, η προσθήκη παύλων σε αριθμούς κοινωνικής δικτύωσης. Εδώ σε αυτό το σεμινάριο, παραθέτει σχεδόν όλα τα σενάρια προσθήκης στο Excel και παρέχει τις αντίστοιχες μεθόδους για εσάς.
Κάντε κλικ για να μάθετε περισσότερα ...
Το Excel Αφαιρεί χαρακτήρες, λέξεις, αριθμούς από συμβολοσειρές κειμένου
Ας υποθέσουμε ότι έχετε μια μακρά λίστα συμβολοσειρών κειμένου που περιέχουν χαρακτήρες, αριθμούς ή άλλα συγκεκριμένα σύμβολα. Σε ορισμένες περιπτώσεις, μπορεί να χρειαστεί να αφαιρέσετε ορισμένους χαρακτήρες με βάση τη θέση, όπως από δεξιά, αριστερά ή στη μέση από τις συμβολοσειρές κειμένου ή να διαγράψετε ορισμένους ανεπιθύμητους χαρακτήρες, αριθμούς από τη λίστα συμβολοσειρών. Η εύρεση των λύσεων μία προς μία θα σας προκαλέσει πονοκέφαλο, αυτό το σεμινάριο συλλέγει όλα τα είδη μεθόδων για την αφαίρεση χαρακτήρων, λέξεων ή αριθμών στο Excel.
Κάντε κλικ για να μάθετε περισσότερα ...
Τα καλύτερα εργαλεία παραγωγικότητας γραφείου
Αυξήστε τις δεξιότητές σας στο Excel με τα Kutools για Excel και απολαύστε την αποτελεσματικότητα όπως ποτέ πριν. Το Kutools για Excel προσφέρει πάνω από 300 προηγμένες δυνατότητες για την ενίσχυση της παραγωγικότητας και την εξοικονόμηση χρόνου. Κάντε κλικ εδώ για να αποκτήσετε τη δυνατότητα που χρειάζεστε περισσότερο...
Το Office Tab φέρνει τη διεπαφή με καρτέλες στο Office και κάνει την εργασία σας πολύ πιο εύκολη
- Ενεργοποίηση επεξεργασίας και ανάγνωσης καρτελών σε Word, Excel, PowerPoint, Publisher, Access, Visio και Project.
- Ανοίξτε και δημιουργήστε πολλά έγγραφα σε νέες καρτέλες του ίδιου παραθύρου και όχι σε νέα παράθυρα.
- Αυξάνει την παραγωγικότητά σας κατά 50% και μειώνει εκατοντάδες κλικ του ποντικιού για εσάς κάθε μέρα!