Πώς να εξαγάγετε μεμονωμένα ή όλα τα γραφήματα από φύλλα εργασίας του Excel στο PowerPoint;

Μερικές φορές, ίσως χρειαστεί να εξαγάγετε ένα γράφημα ή όλα τα γραφήματα από το Excel στο PowerPoint για κάποιο σκοπό. Αυτό το άρθρο μιλά για τον τρόπο επίτευξής του.

Εξαγωγή ενός γραφήματος ή όλων των γραφημάτων από το φύλλο εργασίας του Excel στο PowerPoint με κώδικα VBA

Εξαγωγή ενός γραφήματος ή όλων των γραφημάτων από το φύλλο εργασίας του Excel στο PowerPoint με κώδικα VBA

Αυτή η ενότητα θα εισαγάγει κωδικούς VBA για εξαγωγή ενός μόνο γραφήματος ή όλων των γραφημάτων από το βιβλίο εργασίας στο PowerPoint. Κάντε τα εξής.

1. Πάτα το άλλος + F11 κλειδιά για να ανοίξετε το Microsoft Visual Basic για εφαρμογές παράθυρο.

2. Στο Microsoft Visual Basic για εφαρμογές παράθυρο, κάντε κλικ στην επιλογή Εργαλεία > αναφορές όπως φαίνεται παρακάτω.

3. Στο Αναφορές - VBAProject πλαίσιο διαλόγου, μετακινηθείτε προς τα κάτω για να βρείτε και να ελέγξετε το Βιβλιοθήκη αντικειμένων Microsoft PowerPoint και στη συνέχεια κάντε κλικ στο OK κουμπί. Δείτε το στιγμιότυπο οθόνης:

4. Στη συνέχεια κάντε κλικ στο κουμπί Κύριο θέμα > Μονάδα μέτρησης.

5. Εάν θέλετε να εξαγάγετε ένα μόνο γράφημα στο PowerPoint, μεταβείτε για να επιλέξετε το γράφημα στο φύλλο εργασίας και, στη συνέχεια, επιστρέψτε στο Microsoft Visual Basic για εφαρμογές παράθυρο, αντιγράψτε και επικολλήστε τον παρακάτω κώδικα VBA στο παράθυρο Module.

Κωδικός VBA: Εξαγωγή ενός γραφήματος από το φύλλο εργασίας του Excel στο PowerPoint

Sub SingleActiveChartToPowerPoint_EarlyBinding1()
'Updated by Extendoffice 2017/9/15
  Dim pptApp As PowerPoint.Application
  Dim pptPres As PowerPoint.Presentation
  Dim pptSlide As PowerPoint.Slide
  Dim pptShape As PowerPoint.Shape
  Dim pptShpRng As PowerPoint.ShapeRange
  Dim xActiveSlideNow As Long
  On Error Resume Next
  If ActiveChart Is Nothing Then
    MsgBox "Select a chart and try again!", vbExclamation, "KuTools For Excel"
    Exit Sub
  End If
  Set pptApp = GetObject(, "PowerPoint.Application")
  If pptApp Is Nothing Then
    Set pptApp = CreateObject("PowerPoint.Application")
    Set pptPres = pptApp.Presentations.Add
    Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
  Else
    If pptApp.Presentations.Count > 0 Then
      Set pptPres = pptApp.ActivePresentation
      If pptPres.Slides.Count > 0 Then
        xActiveSlideNow = pptApp.ActiveWindow.View.Slide.SlideIndex
        Set pptSlide = pptPres.Slides(xActiveSlideNow)
      Else
        Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
      End If
    Else
      Set pptPres = pptApp.Presentations.Add
      Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
    End If
  End If
  ActiveChart.ChartArea.Copy
  With pptSlide
    .Shapes.Paste
    Set pptShape = .Shapes(.Shapes.Count)
    Set pptShpRng = .Shapes.Range(pptShape.Name)
  End With
  With pptShpRng
    .Align msoAlignCenters, True
    .Align msoAlignMiddles, True
  End With
  pptShpRng.Select
End Sub

Εάν θέλετε να εξαγάγετε όλα τα γραφήματα από το βιβλίο εργασίας, αντιγράψτε και επικολλήστε τον παρακάτω κώδικα VBA στο παράθυρο Module.

Κωδικός VBA: Εξαγωγή όλων των γραφημάτων από φύλλα εργασίας του Excel στο PowerPoint

Option Explicit
'Updated by Extendoffice 2017/9/15
Dim pptApp As PowerPoint.Application
Dim pptPres As PowerPoint.Presentation
Dim pptSlide As PowerPoint.Slide
Dim pptSlideCount As Integer
Sub ChartsToPowerPoint()
    Dim xSheet As Worksheet
    Dim xChartsCount As Integer
    Dim xChart As Object
    Dim xActiveSlideNow As Integer
    On Error Resume Next
    For Each xSheet In ActiveWorkbook.Worksheets
        xChartsCount = xChartsCount + xSheet.ChartObjects.Count
    Next xSheet
    If xChartsCount = 0 Then
        MsgBox "Sorry, there are no charts to export!", vbCritical, "Ops"
        Exit Sub
    End If
    Set pptApp = GetObject(, "PowerPoint.Application")
    If pptApp Is Nothing Then
      Set pptApp = CreateObject("PowerPoint.Application")
      Set pptPres = pptApp.Presentations.Add
      Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
    Else
        If pptApp.Presentations.Count > 0 Then
          Set pptPres = pptApp.ActivePresentation
          If pptPres.Slides.Count > 0 Then
            xActiveSlideNow = pptApp.ActiveWindow.View.Slide.SlideIndex
            Set pptSlide = pptPres.Slides(xActiveSlideNow)
          Else
            Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
          End If
        Else
          Set pptPres = pptApp.Presentations.Add
          Set pptSlide = pptPres.Slides.Add(1, ppLayoutBlank)
        End If
    End If
    For Each xSheet In ActiveWorkbook.Worksheets
        For Each xChart In xSheet.ChartObjects
            Call pptFormat(xChart.Chart)
        Next xChart
    Next xSheet
    For Each xChart In ActiveWorkbook.Charts
        Call pptFormat(xChart)
    Next xChart
    
    Set pptSlide = Nothing
    Set pptPres = Nothing
    Set pptApp = Nothing
    MsgBox "The charts were copied successfully to the new presentation!", vbInformation, "KuTools For Excel"
End Sub
Private Sub pptFormat(xChart As Chart)
    Dim xCharTiTle As String
    Dim I As Integer
    On Error Resume Next
    xCharTiTle = xChart.ChartTitle.Text
    xChart.ChartArea.Copy
    pptSlideCount = pptPres.Slides.Count
    Set pptSlide = pptPres.Slides.Add(pptSlideCount + 1, ppLayoutBlank)
    pptSlide.Select
    pptSlide.Shapes.PasteSpecial ppPasteJPG
    If xCharTiTle <> "" Then
        pptSlide.Shapes.AddTextbox msoTextOrientationHorizontal, 12.5, 20, 694.75, 55.25
    End If
    For I = 1 To pptSlide.Shapes.Count
        With pptSlide.Shapes(I)
            Select Case .Type
                Case msoPicture:
                    .Top = 87.84976
                    .left = 33.98417
                    .Height = 422.7964
                    .Width = 646.5262
                Case msoTextBox:
                    With .TextFrame.TextRange
                        .ParagraphFormat.Alignment = ppAlignCenter
                        .Text = xCharTiTle
                        .Font.Name = "Tahoma (Headings)"
                        .Font.Size = 28
                        .Font.Bold = msoTrue
                    End With
                End Select
        End With
    Next I
End Sub

6. Πάτα το F5 ή κάντε κλικ στο κουμπί Εκτέλεση για να εκτελέσετε τον κωδικό. Στη συνέχεια, θα ανοίξει ένα νέο PowerPoint με το επιλεγμένο γράφημα ή όλα τα γραφήματα που εισάγονται. Και θα πάρετε ένα Kutools για Excel παράθυρο διαλόγου όπως φαίνεται παρακάτω, κάντε κλικ στο OK κουμπί.

Σχετικά άρθρα:

• Πώς να αποθηκεύσετε, να εξαγάγετε πολλά / όλα τα φύλλα για να διαχωρίσετε αρχεία csv ή κειμένου στο Excel;
• Πώς να αποθηκεύσετε την επιλογή ή ολόκληρο το βιβλίο εργασίας ως PDF στο Excel;