Πώς να εξαγάγετε την αναφορά κυττάρων από τύπους στο Excel;

Ας υποθέσουμε ότι έχετε κάποιους μεγάλους τύπους και τώρα, θέλετε να εξαγάγετε όλες τις αναφορές κελιού από τους τύπους όπως φαίνεται στο παρακάτω στιγμιότυπο οθόνης. Πώς θα μπορούσατε να εξαγάγετε τις αναφορές κυττάρων από τύπους όσο πιο γρήγορα μπορείτε;

Εξαγάγετε αναφορές κελιού από τύπους με συνάρτηση καθορισμένη από το χρήστη

Εξαγάγετε αναφορές κελιού από τύπους με συνάρτηση καθορισμένη από το χρήστη

Για να εξαγάγετε τις αναφορές κελιών από τους τύπους, ο παρακάτω κώδικας VBA μπορεί να σας βοηθήσει. Κάντε τα εξής:

1. Κρατήστε πατημένο το ALT + F11 για να ανοίξετε το Microsoft Visual Basic για εφαρμογές παράθυρο.

2. Κλίκ Κύριο θέμα > Μονάδα μέτρησηςκαι επικολλήστε τον ακόλουθο κώδικα στο Μονάδα μέτρησης Παράθυρο.

Κωδικός VBA: Εξαγωγή αναφορών κελιών από τους τύπους:

Function ExtractCellRefs(Rg As Range) As String
'Updateby Extendoffice
    Dim xRetList As Object
    Dim xRegEx As Object
    Dim I As Long
    Dim xRet As String
    Application.Volatile
    Set xRegEx = CreateObject("VBSCRIPT.REGEXP")
    With xRegEx
        .Pattern = "('?[a-zA-Z0-9\s\[\]\.]{1,99})?'?!?\$?[A-Z]{1,3}\$?[0-9]{1,7}(:\$?[A-Z]{1,3}\$?[0-9]{1,7})?"
        .Global = True
        .MultiLine = True
        .IgnoreCase = False
    End With
    Set xRetList = xRegEx.Execute(Rg.Formula)
    If xRetList.Count > 0 Then
        For I = 0 To xRetList.Count - 1
            xRet = xRet & xRetList.Item(I) & ", "
        Next
        ExtractCellRefs = Left(xRet, Len(xRet) - 2)
    Else
        ExtractCellRefs = "No Matches"
    End If
End Function

3. Αφού επικολλήσετε τον κώδικα, αποθηκεύστε τον κώδικα και επιστρέψτε στο φύλλο εργασίας και εισαγάγετε αυτόν τον τύπο: = extractcellrefs (G2) (G2 είναι το κελί που περιέχει τον τύπο που θέλετε να εξαγάγετε τις αναφορές κελιού) σε ένα κελί όπου θέλετε να λάβετε το αποτέλεσμα και, στη συνέχεια, πατήστε εισάγετε κλειδί, όλες οι αναφορές κελιού έχουν εξαχθεί από τον τύπο, δείτε το στιγμιότυπο οθόνης: