Πώς να εισαγάγετε άνω και κάτω τελεία μεταξύ αριθμών για να τους κάνετε αυτόματα ως μορφή ώρας στο Excel;

Όταν εισάγετε τη μορφή ώρας σε κελιά φύλλου εργασίας, έχετε ενοχληθεί ποτέ με την πληκτρολόγηση των τελών κάθε φορά; Σε αυτό το άρθρο, θα μιλήσω για το πώς να εισαγάγετε άνω και κάτω τελεία όταν εισάγετε αριθμούς για να τους κάνετε αυτόματα ως μορφή ώρας στο Excel.

Εισαγάγετε άνω και κάτω τελεία μεταξύ αριθμών για να τους κάνετε ως μορφή ώρας με τύπους

Αυτόματη ρύθμιση των αριθμών σε ώρα κατά την εισαγωγή τους με κωδικό VBA

Εισαγάγετε άνω και κάτω τελεία μεταξύ αριθμών για να τους κάνετε ως μορφή ώρας με τύπους

Ας υποθέσουμε ότι έχετε μια λίστα αριθμών, για να εισαγάγετε τα άνω και κάτω τελεία και να τα κάνετε ως μορφή ώρας, οι ακόλουθοι τύποι μπορούν να σας βοηθήσουν.

Εάν οι αριθμοί είναι πάντα 3 ή 4 ψηφία, μπορείτε να χρησιμοποιήσετε αυτόν τον τύπο:

=TIME(LEFT(A1,LEN(A1)-2),RIGHT(A1,2),0)και, στη συνέχεια, σύρετε τη λαβή πλήρωσης προς τα κάτω στα κελιά που θέλετε να περιέχει αυτόν τον τύπο και θα λάβετε το ακόλουθο αποτέλεσμα όπως χρειάζεστε:

Εάν οι αριθμοί είναι 5 ή 6 ψηφία, εφαρμόστε αυτόν τον τύπο:

=(INT(A1/10000)&":"&INT(MOD(A1,10000)/100)&":"&MOD(A1,100))+0και σύρετε τη λαβή πλήρωσης προς τα κάτω στα κελιά που θέλετε να περιέχει αυτόν τον τύπο και θα λάβετε ακολουθία αριθμών όπως φαίνεται το ακόλουθο στιγμιότυπο οθόνης:

Στη συνέχεια, πρέπει να μορφοποιήσετε τους αριθμούς ως μορφή ώρας κάνοντας κλικ Χρόνος από το Γενικός αναπτυσσόμενη λίστα κάτω από το Αρχική καρτέλα, δείτε το στιγμιότυπο οθόνης:

Αυτόματη ρύθμιση των αριθμών σε ώρα κατά την εισαγωγή τους με κωδικό VBA

Ο ακόλουθος κωδικός VBA μπορεί επίσης να σας βοηθήσει να μετατρέψετε αυτόματα τους αριθμούς σε μορφή ώρας κατά την εισαγωγή τους, κάντε το ως εξής:

1. Μεταβείτε στο φύλλο εργασίας που θέλετε να εισαγάγετε αυτόματα άνω και κάτω τελεία σε αριθμούς.

2. Κάντε δεξί κλικ στην καρτέλα φύλλων και επιλέξτε Προβολή κωδικού από το μενού περιβάλλοντος, στο αναδυόμενο Microsoft Visual Basic για εφαρμογές παράθυρο, αντιγράψτε και επικολλήστε τον ακόλουθο κώδικα στο κενό Μονάδα μέτρησης παράθυρο, δείτε το στιγμιότυπο οθόνης:

Κωδικός VBA: Αυτόματη ρύθμιση αριθμών σε ώρα:

Private Sub Worksheet_Change(ByVal Target As Excel.Range)
'Updateby Extendoffice 20160606
    Dim xStr As String
    Dim xVal As String
    On Error GoTo EndMacro
    If Application.Intersect(Target, Range("A1:A20")) Is Nothing Then Exit Sub
    If Target.Count > 1 Then Exit Sub
    If Target.Value = "" Then Exit Sub
    Application.EnableEvents = False
    With Target
        If Not .HasFormula Then
            xVal = .Value
            Select Case Len(xVal)
                Case 1 ' e.g., 1 = 00:01 AM
                    xStr = "00:0" & xVal
                Case 2 ' e.g., 12 = 00:12 AM
                    xStr = "00:" & xVal
                Case 3 ' e.g., 735 = 7:35 AM
                    xStr = Left(xVal, 1) & ":" & Right(xVal, 2)
                Case 4 ' e.g., 1234 = 12:34
                    xStr = Left(xVal, 2) & ":" & Right(xVal, 2)
                Case 5 ' e.g., 12345 = 1:23:45 NOT 12:03:45
                    xStr = Left(xVal, 1) & ":" & Mid(xVal, 2, 2) & ":" & Right(xVal, 2)
                Case 6 ' e.g., 123456 = 12:34:56
                    xStr = Left(xVal, 2) & ":" & Mid(xVal, 3, 2) & ":" & Right(xVal, 2)
                Case Else
                    Err.Raise 0
            End Select
            .Value = TimeValue(xStr)
        End If
    End With
    Application.EnableEvents = True
    Exit Sub
EndMacro:
    MsgBox "You did not enter a valid time"
    Application.EnableEvents = True
End Sub

Σημείωση: Στον παραπάνω κώδικα, A1: A20 είναι τα κελιά που θέλετε να εισαγάγετε αργότερα και μπορείτε να αλλάξετε την αναφορά κελιού ανάλογα με τις ανάγκες σας.

3. Και τώρα, όταν εισαγάγετε αριθμούς όπως 102319 στην περιοχή κελιών A1: A20 και, στη συνέχεια, πατήστε εισάγετε κλειδί, ο αριθμός θα διαμορφωθεί ως 10:23:19 π.μ. μορφή ώρας αυτόματα όπως χρειάζεστε.