Πώς να στείλετε / να στείλετε email μέσω κυττάρων μέσω προοπτικών από το Excel;

Είχατε ποτέ πρόβλημα με το ότι αφού ολοκληρώσετε μια αναφορά σε ένα φύλλο εργασίας και πρέπει να στείλετε σε μια σειρά κελιών σε αυτό το φύλλο εργασίας που περιέχουν ορισμένα σημαντικά δεδομένα στον συγκεκριμένο παραλήπτη σας. Υπάρχουν γρήγοροι τρόποι για να στείλετε μέσω ηλεκτρονικού ταχυδρομείου αυτό το εύρος από το Excel χωρίς να ανοίξετε το Outlook;

Αποστολή εύρους κελιών ως συνημμένο από το Excel με κώδικα VBA

Αποστολή εύρους κελιών ως σώμα από το Excel με κωδικό VBA

Αποστολή εύρους κελιών ως συνημμένο από το Excel με κώδικα VBA

Ο ακόλουθος κώδικας VBA μπορεί να σας βοηθήσει να στείλετε το επιλεγμένο εύρος ως συνημμένο στο Excel. Κάντε το ως εξής:

1. Ανοίξτε το βιβλίο εργασίας σας και στη συνέχεια κρατήστε πατημένο το ALT + F11 για να ανοίξετε το Παράθυρο Microsoft Visual Basic for Applications.

2. Κλίκ Κύριο θέμα > Μονάδα μέτρησηςκαι επικολλήστε τον ακόλουθο κώδικα στο Παράθυρο ενότητας.

Κωδικός VBA: αποστολή εύρους κελιών ως συνημμένο από το Excel

Sub SendRange()
'Update 20131209
Dim xFile As String
Dim xFormat As Long
Dim Wb As Workbook
Dim Wb2 As Workbook
Dim Ws As Worksheet
Dim FilePath As String
Dim FileName As String
Dim OutlookApp As Object
Dim OutlookMail As Object
Dim WorkRng As Range
xTitleId = "KutoolsforExcel"
Set WorkRng = Application.Selection
Set WorkRng = Application.InputBox("Range", xTitleId, WorkRng.Address, Type:=8)
Application.ScreenUpdating = False
Application.DisplayAlerts = False
Set Wb = Application.ActiveWorkbook
Wb.Worksheets.Add
Set Ws = Application.ActiveSheet
WorkRng.Copy Ws.Cells(1, 1)
Ws.Copy
Set Wb2 = Application.ActiveWorkbook
Select Case Wb.FileFormat
Case xlOpenXMLWorkbook:
    xFile = ".xlsx"
    xFormat = xlOpenXMLWorkbook
Case xlOpenXMLWorkbookMacroEnabled:
    If Wb2.HasVBProject Then
        xFile = ".xlsm"
        xFormat = xlOpenXMLWorkbookMacroEnabled
    Else
        xFile = ".xlsx"
        xFormat = xlOpenXMLWorkbook
    End If
Case Excel8:
    xFile = ".xls"
    xFormat = Excel8
Case xlExcel12:
    xFile = ".xlsb"
    xFormat = xlExcel12
End Select
FilePath = Environ$("temp") & "\"
FileName = Wb.Name & Format(Now, "dd-mmm-yy h-mm-ss")
Set OutlookApp = CreateObject("Outlook.Application")
Set OutlookMail = OutlookApp.CreateItem(0)
Wb2.SaveAs FilePath & FileName & xFile, FileFormat:=xFormat
With OutlookMail
    .To = "skyyang@extendoffice.com"
    .CC = ""
    .BCC = ""
    .Subject = "information of kte"
    .Body = "hello, please check and read this document. "
    .Attachments.Add Wb2.FullName
    .Send
End With
Wb2.Close
Kill FilePath & FileName & xFile
Set OutlookMail = Nothing
Set OutlookApp = Nothing
Ws.Delete
Application.DisplayAlerts = True
Application.ScreenUpdating = True
End Sub

Note: Στον παραπάνω κώδικα, μπορείτε να αλλάξετε τις ακόλουθες πληροφορίες ανάλογα με τις ανάγκες σας.

• .Το = "skyyang @extendoffice.com "
• .CC = ""
• .BCC = ""
• .Θέμα = "πληροφορίες του kte"
• .Body = "γεια, παρακαλώ ελέγξτε και διαβάστε αυτό το έγγραφο."

3. Στη συνέχεια κάντε κλικ στο κουμπί F5 για να εκτελέσετε αυτόν τον κωδικό και θα εμφανιστεί ένα πλαίσιο προτροπής για να σας υπενθυμίσει ότι επιλέγετε ένα εύρος που θέλετε να στείλετε. Δείτε το στιγμιότυπο οθόνης:

4. Στη συνέχεια κάντε κλικ στο κουμπί OKκαι θα εμφανιστεί ένα πλαίσιο προτροπής, αφού ολοκληρωθεί η γραμμή προόδου, κάντε κλικ στο Επιτρέψτεκαι στη συνέχεια το συγκεκριμένο εύρος κελιών έχει σταλεί στον παραλήπτη σας ως συνημμένο.

Αποστολή εύρους κελιών ως σώμα από το Excel με κωδικό VBA

Εάν θέλετε να στείλετε ένα συγκεκριμένο εύρος ως μέρος του σώματος μηνυμάτων από το Excel, μπορείτε επίσης να εφαρμόσετε τον ακόλουθο κώδικα VBA για να το λύσετε.

1. Ενεργοποιήστε το φύλλο εργασίας σας και κρατήστε πατημένο το ALT + F11 για να ανοίξετε το Παράθυρο Microsoft Visual Basic for Applications.

2. Κλίκ Κύριο θέμα > Μονάδα μέτρησηςκαι επικολλήστε τον ακόλουθο κώδικα στο Παράθυρο ενότητας.

Κωδικός VBA: αποστολή εύρους κελιών ως σώμα από το Excel

Sub EmailRange()
'Update 20131209
Dim WorkRng As Range
On Error Resume Next
xTitleId = "KutoolsforExcel"
Set WorkRng = Application.Selection
Set WorkRng = Application.InputBox("Range", xTitleId, WorkRng.Address, Type:=8)
Application.ScreenUpdating = False
WorkRng.Select
ActiveWorkbook.EnvelopeVisible = True
With ActiveSheet.MailEnvelope
    .Introduction = "Please read this email."
    .Item.To = "skyyang@extendoffice.com"
    .Item.Subject = "information of kte"
    .Item.Send
End With
Application.ScreenUpdating = True
End Sub

Σημείωση: Στον παραπάνω κώδικα, μπορείτε να αλλάξετε τις ακόλουθες πληροφορίες ανάλογα με τις ανάγκες σας.

• . Εισαγωγή = "Διαβάστε αυτό το μήνυμα ηλεκτρονικού ταχυδρομείου."
• .Item.To = "skyyang @extendoffice.com "
• .Item.Subject = "πληροφορίες του kte"

3. Στη συνέχεια κάντε κλικ στο κουμπί F5 για να εκτελέσετε αυτόν τον κώδικα και θα εμφανιστεί ένα πλαίσιο προτροπής για να σας υπενθυμίσει ότι επιλέγετε ένα εύρος που θέλετε να στείλετε.

4. Στη συνέχεια κάντε κλικ στο κουμπί OKκαι θα εμφανιστεί ένα πλαίσιο προτροπής, αφού ολοκληρωθεί η γραμμή προόδου, κάντε κλικ στο Επιτρέψτεκαι στη συνέχεια το συγκεκριμένο εύρος κελιών έχει σταλεί στον παραλήπτη σας ως σώμα μηνυμάτων.

:

1. Αυτοί οι κωδικοί είναι διαθέσιμοι μόνο όταν το Outlook ως πρόγραμμα αλληλογραφίας σας.

2. Μετά την αποστολή του τρέχοντος φύλλου εργασίας, μπορείτε να μεταβείτε στο Outlook για να βεβαιωθείτε ότι το μήνυμα ηλεκτρονικού ταχυδρομείου έχει σταλεί επιτυχώς.

Σχετικά άρθρα:

Πώς να στείλετε φύλλο εργασίας μόνο μέσω του Outlook από το Excel;

Πώς να στείλετε το τρέχον βιβλίο εργασίας μέσω του Outlook από το Excel;

---

Τα καλύτερα εργαλεία παραγωγικότητας του Office

Το Kutools για Excel λύνει τα περισσότερα από τα προβλήματά σας και αυξάνει την παραγωγικότητά σας κατά 80%

• Επαναχρησιμοποίηση: Εισαγάγετε γρήγορα σύνθετοι τύποι, γραφήματα και οτιδήποτε έχετε χρησιμοποιήσει στο παρελθόν. Κρυπτογράφηση κυττάρων με κωδικό πρόσβασης Δημιουργία λίστας αλληλογραφίας και στείλτε email ...
• Super Formula Bar (επεξεργαστείτε εύκολα πολλές γραμμές κειμένου και τύπου). Διάταξη ανάγνωσης (εύκολη ανάγνωση και επεξεργασία μεγάλου αριθμού κελιών). Επικόλληση σε φιλτραρισμένο εύρος...
• Συγχώνευση κελιών / σειρών / στηλών χωρίς απώλεια δεδομένων · Περιεχόμενο διαχωρισμού κελιών Συνδυάστε διπλές σειρές / στήλες... Αποτροπή διπλών κυττάρων; Συγκρίνετε τα εύρη...
• Επιλέξτε Διπλότυπο ή Μοναδικό Σειρές; Επιλέξτε Κενές σειρές (όλα τα κελιά είναι κενά). Σούπερ εύρεση και ασαφής εύρεση σε πολλά βιβλία εργασίας. Τυχαία επιλογή ...
• Ακριβές αντίγραφο Πολλαπλά κελιά χωρίς αλλαγή της αναφοράς τύπου. Αυτόματη δημιουργία αναφορών σε πολλαπλά φύλλα? Εισαγωγή κουκκίδων, Πλαίσια ελέγχου και άλλα ...
• Εξαγωγή κειμένου, Προσθήκη κειμένου, Κατάργηση κατά θέση, Αφαιρέστε το διάστημα; Δημιουργία και εκτύπωση υποσύνολων σελιδοποίησης. Μετατροπή περιεχομένου και σχολίων μεταξύ κελιών...
• Σούπερ φίλτρο (αποθηκεύστε και εφαρμόστε σχήματα φίλτρων σε άλλα φύλλα). Προηγμένη ταξινόμηση ανά μήνα / εβδομάδα / ημέρα, συχνότητα και άλλα. Ειδικό φίλτρο με έντονη, πλάγια ...
• Συνδυάστε βιβλία εργασίας και φύλλα εργασίας; Συγχώνευση πινάκων βάσει βασικών στηλών. Διαχωρίστε τα δεδομένα σε πολλά φύλλα; Μαζική μετατροπή xls, xlsx και PDF...
• Περισσότερα από 300 ισχυρά χαρακτηριστικά. Υποστηρίζει Office / Excel 2007-2021 και 365. Υποστηρίζει όλες τις γλώσσες. Εύκολη ανάπτυξη στην επιχείρηση ή τον οργανισμό σας. Πλήρεις δυνατότητες δωρεάν δοκιμής 30 ημερών. Εγγύηση επιστροφής χρημάτων 60 ημερών.

Διαβάστε περισσότερα ... ΔΩΡΕΑΝ Λήψη... Αγορά... 

---

Το Office Tab φέρνει τη διεπαφή με καρτέλες στο Office και κάνει την εργασία σας πολύ πιο εύκολη

• Ενεργοποίηση επεξεργασίας και ανάγνωσης καρτελών σε Word, Excel, PowerPoint, Publisher, Access, Visio και Project.
• Ανοίξτε και δημιουργήστε πολλά έγγραφα σε νέες καρτέλες του ίδιου παραθύρου και όχι σε νέα παράθυρα.
• Αυξάνει την παραγωγικότητά σας κατά 50% και μειώνει εκατοντάδες κλικ του ποντικιού για εσάς κάθε μέρα!

Διαβάστε περισσότερα ... ΔΩΡΕΑΝ Λήψη... Αγορά...